module "lambda_masters_registry_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.3.0"

  secrets      = ["${var.environment}/${var.service_name}/SNOWFLAKE_KEY"]
  action_types = ["read"]
}

resource "aws_iam_policy" "lambda_masters_registry_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-policy"
  policy = module.lambda_masters_registry_secrets_manager_policy.policy.json
}

data "aws_iam_role" "scheduler_agent_role" {
  name = "prod-jenkins-aws-task-agent"
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        data.aws_iam_role.scheduler_agent_role.arn,
      ]
    }
  }
}

resource "aws_iam_role" "lambda_masters_registry_role" {
  name = "${var.environment}-${var.service_name}-producer-role"
  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "lambda_masters_registry_role_policy_attachment" {
  role       = aws_iam_role.lambda_masters_registry_role.name
  policy_arn = aws_iam_policy.lambda_masters_registry_secrets_manager_policy.arn
}