locals {
  lambda_name = var.notification_dispatcher_lambda_name
  application_name = "${var.common_prefix}-${local.lambda_name}"
}

module "notification_store_state_dynamo_table" {
  source                         = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"
  env                            = var.environment
  application_family             = var.application_family
  use_on_demand                  = true
  server_side_encryption_enabled = true
  table_name                     = var.store_state_dynamo_table_name
  hash_key                       = var.store_state_dynamo_table_hash_key

  attribute = [
    {
      name = var.store_state_dynamo_table_hash_key
      type = "N"
    }
  ]
}

module "lambda_notification_dispatcher_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git?ref=1.1.0"

  environment_name = var.environment
  service_name     = local.application_name
}

data "aws_iam_policy_document" "lambda_notification_dispatcher_dynamodb_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "dynamodb:BatchWriteItem",
      "dynamodb:BatchGetItem"
    ]
    resources = [
      module.notification_store_state_dynamo_table.aws_dynamodb_table_arn
    ]
  }
}

resource "aws_iam_policy" "lambda_notification_dispatcher_dynamodb_policy" {
  name   = "${var.environment}-dynamodb-${local.lambda_name}-lambda-policy"
  policy = data.aws_iam_policy_document.lambda_notification_dispatcher_dynamodb_policy_document.json
}

module "lambda_notification_dispatcher_sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  application_family = var.application_family
  environment        = var.environment
  platform           = "python"
  service_name       = local.lambda_name
}

module "lambda_notification_dispatcher" {
  source = "git@github.com:theorchard/terraform-lambda.git?ref=4.2.0"

  application_family           = var.application_family
  environment                  = var.environment
  use_container_image          = true
  datadog_advanced_enabled     = true
  lambda_name                  = local.lambda_name
  lambda_description           = "Poll and process latest store states."
  lambda_function_timeout      = var.lambda_timeout
  cloudwatch_event_enabled     = true
  cloudwatch_event_schedule    = var.notification_dispatcher_cloudwatch_event_schedule
  lambda_function_reserved_concurrent_executions = 1

  vpc_enabled    = true
  vpc_id         = var.vpc_id
  vpc_subnet_ids = var.vpc_subnet_ids

  iam_managed_policy_attachments = [
    module.lambda_notification_dispatcher_owsrequest.policy_arn_output,
    aws_iam_policy.lambda_notification_dispatcher_dynamodb_policy.arn
  ]
  lambda_function_environment_variables = {
    Environment            = var.environment
    SENTRY_DSN             = module.lambda_notification_dispatcher_sentry.sentry_key_dsn_public_output
    STORE_STATE_TABLE_NAME = "${var.environment}_${var.store_state_dynamo_table_name}"
  }
}