locals {
  lambda_copy_asset = "${var.service_name}-copy-asset"
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/lambda-product-staging/copy-asset/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

provider "aws" {
  region = var.aws_region
}

data "aws_s3_bucket" "product_staging_bucket" {
  bucket = "${var.environment}-ows-product-staging"
}

data "aws_iam_policy_document" "product_staging_bucket_list" {
  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket"
    ]
    resources = [
      data.aws_s3_bucket.product_staging_bucket.arn,
    ]
  }
}

data "aws_iam_policy_document" "product_staging_bucket_objects_tags_read_access_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:GetObjectTagging"
    ]
    resources = [
      "${data.aws_s3_bucket.product_staging_bucket.arn}/*",
    ]
  }
}

resource "aws_iam_policy" "product_staging_bucket_objects_tags_read_policy" {
  name   = "S3-${data.aws_s3_bucket.product_staging_bucket.bucket}-copy-asset-objects-tags-read"
  policy = data.aws_iam_policy_document.product_staging_bucket_objects_tags_read_access_document.json
}

resource "aws_iam_policy" "product_staging_bucket_list_policy" {
  name   = "S3-${data.aws_s3_bucket.product_staging_bucket.bucket}-copy-asset-list"
  policy = data.aws_iam_policy_document.product_staging_bucket_list.json
}

data "aws_s3_bucket" "raw_asset_bucket" {
  bucket = "${var.environment}-orcd-raw-assets"
}

data "aws_iam_policy_document" "raw_asset_bucket_list" {
  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket"
    ]
    resources = [
      data.aws_s3_bucket.raw_asset_bucket.arn
    ]
  }
}

data "aws_iam_policy_document" "raw_asset_bucket_objects_tags_write_access_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:PutObject",
      "s3:PutObjectAcl",
      "s3:PutObjectTagging"
    ]
    resources = [
      "${data.aws_s3_bucket.raw_asset_bucket.arn}/*"
    ]
  }
}

resource "aws_iam_policy" "raw_asset_bucket_objects_tags_write_policy" {
  name        = "S3-${data.aws_s3_bucket.raw_asset_bucket.bucket}-copy-asset-objects-tags-write"
  policy      = data.aws_iam_policy_document.raw_asset_bucket_objects_tags_write_access_document.json
}

resource "aws_iam_policy" "raw_asset_bucket_list_policy" {
  name        = "S3-${data.aws_s3_bucket.raw_asset_bucket.bucket}-copy-asset-list"
  policy      = data.aws_iam_policy_document.raw_asset_bucket_list.json
}

module "lambda_copy_asset" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.5"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = local.lambda_copy_asset

  lambda_description                             = "Copy ingestion asset to raw assets bucket."
  lambda_function_timeout                        = "900"
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_max_concurrency
  use_container_image                            = true
  vpc_enabled                                    = true
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT  = var.environment
    SENTRY_DSN   = module.lambda_copy_asset_sentry.sentry_key_dsn_public_output
    OA_USER      = var.oa_user
    IDENTITY_ID  = var.identity_id
    PROFILE_ID   = var.profile_id
    PROFILE_TYPE = var.profile_type
    S3_BUCKET    = data.aws_s3_bucket.product_staging_bucket.id
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.product_staging_bucket_list_policy.arn,
    aws_iam_policy.product_staging_bucket_objects_tags_read_policy.arn,
    aws_iam_policy.raw_asset_bucket_list_policy.arn,
    aws_iam_policy.raw_asset_bucket_objects_tags_write_policy.arn,
  ]
}

module "lambda_copy_asset_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.12.0"

  environment                       = var.environment
  service_name                      = local.lambda_copy_asset
  lambda_invocation_monitor_enabled = false
}

module "lambda_copy_asset_sentry" {
  source = "git@github.com:theorchard/terraform-sentry//?ref=4.1.0"

  service_name       = local.lambda_copy_asset
  environment        = var.environment
  platform           = "python"
  application_family = var.application_family
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}