locals {
  lambda_handle_metadata_success = "${var.service_name}-handle-metadata-success"
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/lambda-product-staging/handle-metadata-success/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = "content-creation-management"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

module "lambda_handle_metadata_success" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.2.0"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = local.lambda_handle_metadata_success

  lambda_description                             = "Handle ingestion success of metadata."
  lambda_function_timeout                        = "900"
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_max_concurrency
  use_container_image                            = true
  vpc_enabled                                    = true
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT  = var.environment
    SENTRY_DSN   = module.lambda_handle_metadata_success_sentry.sentry_key_dsn_public_output
    OA_USER      = var.oa_user
    IDENTITY_ID  = var.identity_id
    PROFILE_ID   = var.profile_id
    PROFILE_TYPE = var.profile_type
  }
}


module "lambda_handle_metadata_success_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.6"

  environment                       = var.environment
  service_name                      = local.lambda_handle_metadata_success
  lambda_invocation_monitor_enabled = false
}

module "lambda_handle_metadata_success_sentry" {
  source = "git@github.com:theorchard/terraform-sentry//?ref=4.1.2"

  service_name       = "handle-metadata-success"
  environment        = var.environment
  platform           = "python"
  application_family = var.application_family
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}