# Log group to capture logs for sending to DataDog
resource "aws_cloudwatch_log_group" "sfn_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${var.state_machine_name}-log-group"
  retention_in_days = 365
  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.state_machine_name
    terraformed        = true
  }
}

# Datadog Lambda Function definition
data "aws_lambda_function" "datadog_lambda_function" {
  function_name = "DatadogLambdaFunction"
}

# Subscribe DataDog lambda to CloudWatch Logs
resource "aws_cloudwatch_log_subscription_filter" "datadog_lambda_log_filter" {
  name            = "${var.environment}-${var.state_machine_name}-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

# Step Function (SFN) - SFN Cloudwatch logs permission policy

data "aws_iam_policy_document" "sfn_log_event_policy_document" {
  # checkov:skip=CKV_AWS_111:not all Cloudwatch API actions support resources types
  statement {
    effect = "Allow"
    resources = [
      aws_cloudwatch_log_group.sfn_log_group.arn,
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    ]

    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
  }

  statement {
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
      "logs:DeleteLogGroup",
      "logs:DeleteLogStream"
    ]
  }
}

resource "aws_iam_policy" "sfn_log_event_policy" {
  name        = "${var.environment}-${var.state_machine_name}-log-event-policy"
  description = "Policy for Step Function to write logs to CloudWatch"
  policy = data.aws_iam_policy_document.sfn_log_event_policy_document.json
}

resource "aws_iam_role_policy_attachment" "sfn_log_event_policy_attachment" {
  role       = aws_iam_role.invoke_lambdas_role_for_state_machine.name
  policy_arn = aws_iam_policy.sfn_log_event_policy.arn
}

module "datadog_sfn_dashboard" {
  source             = "git@github.com:theorchard/terraform-datadog.git//modules/step-function?ref=6.13.2"
  environment        = var.environment
  service_name       = var.state_machine_name
  application_family = var.application_family
  statemachine_arn   = aws_sfn_state_machine.state_machine.arn

  failed_execution_message_log_monitor = {
    enabled        = true
    log_group_name = aws_cloudwatch_log_group.sfn_log_group.name
  }
  notification_endpoints            = var.notification_endpoints
}