# Finalize Bulk Session Step Function.
data "aws_caller_identity" "current" {}

provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/sfn-finalize-bulk-session/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_s3_bucket" "product_staging_bucket" {
  bucket = "${var.environment}-ows-product-staging"
}

data "aws_lambda_function" "prepare_metadata_lambda" {
  function_name = "${var.environment}-lambda-product-staging-prepare-metadata"
}

data "aws_lambda_function" "set_nfd_lambda" {
  function_name = "${var.environment}-lambda-product-staging-set-nfd"
}

data "aws_lambda_function" "submit_product_lambda" {
  function_name = "${var.environment}-lambda-product-staging-submit-product"
}

data "aws_lambda_function" "update_session_lambda" {
  function_name = "${var.environment}-lambda-product-staging-update-session"
}

data "aws_lambda_function" "notify_ingest_success_lambda" {
  function_name = "${var.environment}-lambda-product-staging-notify-ingest-success"
}

data "aws_lambda_function" "notify_ingest_failure_lambda" {
  function_name = "${var.environment}-lambda-product-staging-notify-ingest-failure"
}

# Policy for lambda invocation initiated by state machine.
data "aws_iam_policy_document" "assume_role_for_state_machine_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.${var.aws_region}.amazonaws.com",
      ]
    }
  }
}

# States role for lambda invocation
resource "aws_iam_role" "invoke_lambdas_role_for_state_machine" {
  name               = "${var.environment}-finalize-bulk-session-invoke-lambdas-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_state_machine_policy.json
}

# Policy document that lets the state machine role invoke the lambdas
data "aws_iam_policy_document" "invoke_lambda_policy_for_state_machine" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      data.aws_lambda_function.prepare_metadata_lambda.arn,
      data.aws_lambda_function.set_nfd_lambda.arn,
      data.aws_lambda_function.submit_product_lambda.arn,
      data.aws_lambda_function.update_session_lambda.arn,
      data.aws_lambda_function.notify_ingest_success_lambda.arn,
      data.aws_lambda_function.notify_ingest_failure_lambda.arn,
    ]
  }
}

# Policy that uses the policy document
resource "aws_iam_role_policy" "invoke_lambda_role_policy" {
  name   = "${var.environment}-finalize-bulk-session-invoke-lambda-role-policy"
  role   = aws_iam_role.invoke_lambdas_role_for_state_machine.id
  policy = data.aws_iam_policy_document.invoke_lambda_policy_for_state_machine.json
}

data "template_file" "state_machine_definition" {
  template = file("${path.module}/stepfunction.asl.json")

  vars = {
    prepare_metadata_lambda_arn = data.aws_lambda_function.prepare_metadata_lambda.arn
    set_nfd_lambda_arn = data.aws_lambda_function.set_nfd_lambda.arn
    submit_product_lambda_arn = data.aws_lambda_function.submit_product_lambda.arn
    update_session_lambda_arn = data.aws_lambda_function.update_session_lambda.arn
    notify_ingest_success_lambda_arn = data.aws_lambda_function.notify_ingest_success_lambda.arn
    notify_ingest_failure_lambda_arn = data.aws_lambda_function.notify_ingest_failure_lambda.arn
  }
}

resource "aws_sfn_state_machine" "state_machine" {
  name       = "${var.environment}-${var.state_machine_name}"
  role_arn   = aws_iam_role.invoke_lambdas_role_for_state_machine.arn
  definition = data.template_file.state_machine_definition.rendered

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.state_machine_name
    terraformed        = true
  }

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }
}

# Policy document that lets other things invoke this sfn
data "aws_iam_policy_document" "invoke_sfn_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "states:StartExecution",
      "states:ListExecutions"
    ]

    resources = [
      aws_sfn_state_machine.state_machine.arn
    ]
  }
}

# Policy that uses the policy document
resource "aws_iam_policy" "invoke_sfn_policy" {
  name        = "StepFunctions-${var.environment}-${var.state_machine_name}-StartExecution"
  policy      = data.aws_iam_policy_document.invoke_sfn_policy_document.json
  description = "Policy that allows invoking the finalize bulk session sfn."
}

# Attach the policy to the assumed role
resource "aws_iam_role_policy_attachment" "invoke_sfn_policy_attachment" {
  role       = aws_iam_role.invoke_lambdas_role_for_state_machine.id
  policy_arn = aws_iam_policy.invoke_sfn_policy.arn
}

# Policy document that allows reading from s3
data "aws_iam_policy_document" "product_staging_finalize_bulk_session_bucket_read_access_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject"
    ]

    resources = [
      "${data.aws_s3_bucket.product_staging_bucket.arn}/*",
    ]
  }
}

# Policy that uses the policy document
resource "aws_iam_policy" "product_staging_finalize_bulk_session_bucket_ro_policy" {
  name   = "S3-${data.aws_s3_bucket.product_staging_bucket.bucket}-finalize-bulk-session-RO"
  policy = data.aws_iam_policy_document.product_staging_finalize_bulk_session_bucket_read_access_document.json
}

# Attach the policy to the assumed role
resource "aws_iam_role_policy_attachment" "product_staging_finalize_bulk_session_bucket_ro_policy_attachment" {
  role       = aws_iam_role.invoke_lambdas_role_for_state_machine.id
  policy_arn = aws_iam_policy.product_staging_finalize_bulk_session_bucket_ro_policy.arn
}

module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = var.state_machine_name
  application_family = var.application_family
}