# Scheduled Product Metadata Update Step Function.
# know which account you're in
data "aws_caller_identity" "current" {}

provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/sfn-validate-bulk-metadata/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_lambda_function" "check_guardduty_scan_status_lambda" {
  function_name = "${var.environment}-lambda-product-staging-check-guardduty-scan-status"
}

data "aws_lambda_function" "generate_report_lambda" {
  function_name = "${var.environment}-lambda-product-staging-generate-report"
}

data "aws_lambda_function" "generate_json" {
  function_name = "${var.environment}-lambda-product-staging-generate-json"
}

data "aws_lambda_function" "handle_failure_lambda" {
  function_name = "${var.environment}-lambda-product-staging-handle-failure"
}

data "aws_s3_bucket" "s3_bucket" {
  bucket = "${var.environment}-ows-product-staging"
}

# Enable S3 notifications for a bucket.
resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket      = data.aws_s3_bucket.s3_bucket.bucket
  eventbridge = true
}

# Validate bulk metadata state machine.

# Policy for lambda invocation initiated by state machine.
data "aws_iam_policy_document" "assume_role_for_state_machine_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.${var.aws_region}.amazonaws.com",
      ]
    }
  }
}

# Role for lambda invocation
resource "aws_iam_role" "invoke_lambdas_role_for_state_machine" {
  name               = "${var.environment}-validate-bulk-metadata-invoke-lambdas-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_state_machine_policy.json
}

data "aws_iam_policy_document" "invoke_lambda_policy_for_state_machine" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      data.aws_lambda_function.check_guardduty_scan_status_lambda.arn,
      data.aws_lambda_function.generate_report_lambda.arn,
      data.aws_lambda_function.generate_json.arn,
      data.aws_lambda_function.handle_failure_lambda.arn
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:RunTask",
      "ecs:StopTask",
    ]

    resources = [
      "arn:aws:ecs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-validate-spreadsheet/*",
      "arn:aws:ecs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-validate-spreadsheet"
    ]
  }
  statement {
    effect = "Allow"
    actions = [
      "iam:PassRole",
    ]
    resources = [
      "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${var.environment}-validate-spreadsheet-task-role",
      "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${var.environment}-validate-spreadsheet-task-execution-role"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "events:DescribeRule",
      "events:PutRule",
      "events:PutTargets",
    ]
    resources = [
      "arn:aws:events:${var.aws_region}:${data.aws_caller_identity.current.account_id}:rule/StepFunctionsGetEventsForECSTaskRule"
    ]
  }
}

# Policy that gives the state machine role permission to invoke lambdas
resource "aws_iam_policy" "invoke_lambda_policy_for_state_machine" {
  name   = "${var.environment}-validate-bulk-metadata-invoke-lambda-policy"
  policy = data.aws_iam_policy_document.invoke_lambda_policy_for_state_machine.json
}

# Attach the managed policy to the IAM role
resource "aws_iam_role_policy_attachment" "invoke_lambda_role_policy_attachment" {
  role       = aws_iam_role.invoke_lambdas_role_for_state_machine.id
  policy_arn = aws_iam_policy.invoke_lambda_policy_for_state_machine.arn
}

data "template_file" "state_machine_definition" {
  template = file("${path.module}/stepfunction.asl.json")

  vars = {
    # add all lambda variables here that will be used by stepfunction.asl.json.
    environment                             = var.environment
    check_guardduty_scan_status_lambda_arn  = data.aws_lambda_function.check_guardduty_scan_status_lambda.arn,
    generate_report_lambda_arn              = data.aws_lambda_function.generate_report_lambda.arn,
    generate_json_lambda_arn                = data.aws_lambda_function.generate_json.arn,
    handle_failure_lambda_arn               = data.aws_lambda_function.handle_failure_lambda.arn
    fargate_cluster_arn                     = "arn:aws:ecs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:cluster/${var.environment}-validate-spreadsheet"
    fargate_task_arn                        = "arn:aws:ecs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-validate-spreadsheet"
    subnet_id0                              = module.vpc_info.default_private_subnet_ids[0],
    subnet_id1                              = module.vpc_info.default_private_subnet_ids[1],
  }
}

resource "aws_sfn_state_machine" "state_machine" {
  name       = "${var.environment}-${var.state_machine_name}"
  role_arn   = aws_iam_role.invoke_lambdas_role_for_state_machine.arn
  definition = data.template_file.state_machine_definition.rendered

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.state_machine_name
    terraformed        = true
  }

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }
}


# CloudWatch Events rule role for starting execution.
resource "aws_iam_role" "execute_state_machine_role" {
  name               = "${var.environment}-sfn-validate-bulk-metadata"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_events_policy.json
}

data "aws_iam_policy_document" "assume_role_for_events_policy" {
  statement {
    sid     = "AllowCWEServiceToAssumeRole"
    effect  = "Allow"
    actions = ["sts:AssumeRole"]
    principals {
      type        = "Service"
      identifiers = ["events.amazonaws.com"]
    }
  }
}

# Policy for starting execution initiated by a CloudWatch Events rule.
data "aws_iam_policy_document" "start_execution_policy" {
  statement {
    effect    = "Allow"
    actions   = ["states:StartExecution"]
    resources = [aws_sfn_state_machine.state_machine.id]
  }
}

resource "aws_iam_role_policy" "start_execution_role_policy" {
  name   = "${var.environment}-${var.state_machine_name}-execute-state-machine"
  role   = aws_iam_role.execute_state_machine_role.id
  policy = data.aws_iam_policy_document.start_execution_policy.json
}

# CloudWatch Event rule and target.
resource "aws_cloudwatch_event_rule" "input_validate_bulk_metadata_rule" {
  name        = "${var.environment}-validate-bulk-metadata-input-rule"
  description = "The CloudWatch event rule for put object events on ows-product-staging bucket"

  event_pattern = jsonencode(
    {
      source      = ["aws.s3"],
      detail-type = ["Object Created"],
      detail = {
        bucket = {
          name = [data.aws_s3_bucket.s3_bucket.bucket]
        },
        object : {
          key : [{ prefix : "metadata/" }]
        }
      }
    }
  )

  role_arn = aws_iam_role.execute_state_machine_role.arn

  tags = {
    service_name       = "${var.environment}-eventbridge-s3-validate-bulk-metadata"
    environment        = var.environment
    application_family = var.application_family
    terraformed        = true
  }
}

resource "aws_cloudwatch_event_target" "state_machine_target" {
  target_id = "${var.environment}_validate_bulk_metadata_event_rule_target"
  rule      = aws_cloudwatch_event_rule.input_validate_bulk_metadata_rule.name
  arn       = aws_sfn_state_machine.state_machine.id
  role_arn  = aws_iam_role.execute_state_machine_role.arn
}