locals {
  state_machine_definition = templatefile("${path.module}/state-machine-definition.json", {
    ensure_artists_lambda_arn           = module.lambda_ensure_artists.lambda_arn
    execute_content_transfer_lambda_arn = module.lambda_execute_content_transfer.lambda_arn
    update_dim_tables_lambda_arn        = module.lambda_update_dim_tables.lambda_arn
    edit_attachments_lambda_arn         = module.lambda_edit_attachments.lambda_arn
    finalize_job_lambda_arn             = module.lambda_finalize_job.lambda_arn
    handle_error_lambda_arn             = module.lambda_handle_error.lambda_arn
  })
  lambda_prefix = "arn:aws:lambda:${var.aws_region}:${data.aws_caller_identity.current.account_id}:function:${var.environment}-${var.service_name}-"
}

# Step Function (SFN) root role policy document.
data "aws_iam_policy_document" "sfn_assume_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
      ]
    }
  }
}


resource "aws_iam_role" "sfn_assume_role" {
  name               = "${var.environment}-${var.sfn_name}-state-machine-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_assume_role.json
}

# Step Function (SFN) - SFN Cloudwatch logs permission policy
data "aws_iam_policy_document" "sfn_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*",
    ]

    actions = [
      "logs:CreateLogGroup",
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
  }

  statement {
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}

resource "aws_iam_role_policy" "sfn_log_event_policy_attachment" {
  name   = "${var.environment}-${var.sfn_name}-log-event-policy"
  role   = aws_iam_role.sfn_assume_role.id
  policy = data.aws_iam_policy_document.sfn_log_event_policy_document.json
}

# State machine lambda policy that gives the state machine role permission to invoke lambdas
data "aws_iam_policy_document" "sfn_invoke_lambda_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      "${local.lambda_prefix}*"
    ]
  }
}

resource "aws_iam_role_policy" "sfn_invoke_lambda_role_policy" {
  name   = "${var.environment}-${var.sfn_name}-lambda-role-policy"
  role   = aws_iam_role.sfn_assume_role.id
  policy = data.aws_iam_policy_document.sfn_invoke_lambda_policy_document.json
}

resource "aws_cloudwatch_log_group" "sfn_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${var.sfn_name}-log-group"
  retention_in_days = 365
  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.sfn_name
    terraformed        = true
  }
}

data "aws_lambda_function" "datadog_lambda_function" {
  function_name = "DatadogLambdaFunction"
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_lambda_log_filter" {
  name            = "${var.environment}-${var.sfn_name}-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

resource "aws_sfn_state_machine" "state_machine" {

  name       = "${var.environment}-${var.sfn_name}"
  role_arn   = aws_iam_role.sfn_assume_role.arn
  definition = local.state_machine_definition
  tags       = module.default_tags.tags

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }
}

module "datadog_sfn_dashboard" {
  source             = "git@github.com:theorchard/terraform-datadog.git//modules/step-function?ref=6.18.1"
  environment        = var.environment
  service_name       = var.sfn_name
  application_family = var.application_family
  statemachine_arn   = aws_sfn_state_machine.state_machine.arn

  failed_execution_message_log_monitor = {
    enabled        = true
    log_group_name = aws_cloudwatch_log_group.sfn_log_group.name
  }
}