module "lambda_sr_fingerprinting_rules_migrator_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  application_family = var.application_family
  environment        = var.environment
  platform           = "python"
  service_name       = var.sr_fingerprinting_rules_migrator_function_name
  teams              = [var.environment]
}

module "lambda_sr_fingerprinting_rules_migrator_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.sr_fingerprinting_rules_migrator_function_name
}

module "lambda_sr_fingerprinting_rules_migrator" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.2.0"

  application_family       = var.application_family
  datadog_advanced_enabled = true
  environment              = var.environment
  lambda_name              = var.sr_fingerprinting_rules_migrator_function_name
  lambda_description       = "Migrate rights registry to fingerprint rules"
  lambda_function_timeout  = var.lambda_default_timeout
  use_container_image      = true
  vpc_id                   = var.vpc_id
  vpc_subnet_ids           = var.vpc_subnet_ids

  lambda_function_memory_size = 3000

  iam_managed_policy_attachments = [
    module.lambda_sr_fingerprinting_rules_migrator_owsrequest.policy_arn_output
  ]

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment,
    # Reduced from the default of 5 - the lambda has a 5 minute timeout, and one retry can take up to 1 minute.
    # This avoids infinite retries on a single message because the lambda  would hit the timeout before discarding the message.
    OWSREQUEST_MAX_RETRIES = 2
  }

  msk_event_enabled                     = true
  event_source_mapping_msk_cluster_name = var.trigger_msk_cluster_name
  event_source_mapping_msk_cluster_uuid = var.trigger_msk_cluster_uuid
  event_source_mapping_batch_size       = 20
  kafka_topics = [
    var.fingerprint_rules_msk_topic
  ]
  event_source_mapping_starting_position = "LATEST"

  lambda_function_reserved_concurrent_executions = "5"
}

locals {
  # Manually build filters for the offsetLag metric, we want the Consumer Ids for each MSK Source Event
  fingerprint_rules_consumer_group_ids = join(" OR ", [for c in module.lambda_sr_fingerprinting_rules_migrator.msk_event_source_mapping_uuid : "consumer_group:${c}"])

  sr_fp_rules_migrator_tags = flatten([
    local.env_tags,
    "service:${var.sr_fingerprinting_rules_migrator_function_name}",
    "service_name:${var.sr_fingerprinting_rules_migrator_function_name}",
    local.team_tags,
  ])
}

resource "datadog_monitor" "lambda_sr_fingerprinting_rules_migrator_offset_lag_monitor" {
  name    = "${var.environment}-${var.sr_fingerprinting_rules_migrator_function_name}-offset-lag"
  type    = "metric alert"
  message = "{{#is_alert}} The Lambda offset lag is too high {{/is_alert}} {{#is_alert_recovery}} Offset lag is recovering {{/is_alert_recovery}} in {{[aws.kafka.sum_offset_lag].topic}} \n Notify: ${var.notification_endpoints}"
  query   = "avg(last_30m):aws.kafka.sum_offset_lag{environment:${var.environment} AND ${local.fingerprint_rules_consumer_group_ids}} by {topic} > 75000"

  monitor_thresholds {
    critical = 75000
    warning  = 70000
  }

  notify_no_data      = true
  no_data_timeframe   = 60
  notify_audit        = false
  renotify_interval   = 50
  timeout_h           = 0
  require_full_window = false

  tags = local.sr_fp_rules_migrator_tags
}

module "datadog_lambda_sr_fingerprinting_rules_migrator_dashboards" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.6"
  service_name                      = var.sr_fingerprinting_rules_migrator_function_name
  environment                       = var.environment
  lambda_invocation_monitor_enabled = false
  lambda_error_monitor_enabled      = true
  notification_endpoints            = var.notification_endpoints
}