data "aws_iam_policy_document" "close_batch_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "sqs:GetQueueAttributes",
      "sqs:GetQueueUrl",
      "sqs:ListQueueTags",
      "sqs:TagQueue",
      "sqs:UntagQueue",
      "sqs:SendMessageBatch",
      "sqs:SendMessage",
      "sqs:ReceiveMessage",
      "sqs:DeleteMessage"
    ]
    resources = [
      module.queue_batch_to_close.queue_arn
    ]
  }
  statement {
    effect = "Allow"
    actions = [
      "ses:SendEmail",
      "ses:SendRawEmail"
    ]
    resources = [
      "arn:aws:ses:${var.region}:${data.aws_caller_identity.current.account_id}:identity/donotreply@theorchard.com"
    ]
  }
}

resource "aws_iam_policy" "close_batch_lambda_policy" {
  name        = "${var.environment}-${var.lambda_close_batch_name}"
  description = "Close batch lambda policy"
  policy      = data.aws_iam_policy_document.close_batch_policy_document.json
}

resource "aws_iam_policy" "close_batch_delivery_spec_secret_policy" {
  name        = "${var.environment}-close-batch-secrets"
  description = "Close batch lambda secrets policy"
  policy      = data.aws_iam_policy_document.delivery_spec_secret_policy_document.json
}

module "lambda_close_batch" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"

  environment                                    = var.environment
  application_family                             = var.application_family
  use_container_image                            = true
  lambda_name                                    = "${var.service_name}-${var.lambda_close_batch_name}"
  lambda_description                             = "Tries to close the batch"
  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_enabled                                    = true
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  vpc_id                                         = var.vpc_id
  lambda_function_memory_size                    = var.lambda_memory_size
  sqs_event_enabled                              = true
  event_source_mapping_batch_size                = var.sqs_message_batch_size
  event_source_mapping_resource_type             = "sqs"
  event_source_mapping_queue_name                = "${var.environment}-${var.event_source_mapping_queue_name}"
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  iam_managed_policy_attachments = [
    aws_iam_policy.close_batch_lambda_policy.arn,
    aws_iam_policy.close_batch_delivery_spec_secret_policy.arn
  ]

  lambda_function_environment_variables = {
    Environment                     = var.environment
    SENTRY_DSN                      = module.sentry_close_batch_lambda.sentry_key_dsn_public_output
    AR_MYSQL_HOST                   = var.ar_mysql_host
    AR_MYSQL_PORT                   = var.ar_mysql_port
    AR_MYSQL_DATABASE               = var.ar_mysql_database
    DD_MYSQL_HOST                   = var.dd_mysql_host
    DD_MYSQL_PORT                   = var.dd_mysql_port
    DD_MYSQL_DATABASE               = var.dd_mysql_database
    DD_API_KEY_SECRET_ARN           = data.aws_secretsmanager_secret.datadog_api.arn
    STORES_WITH_DISABLED_ALGORITHMS = var.stores_with_disabled_algorithms
    SEND_EMAIL_CONFIRMATION         = "false"
  }
}