data "aws_iam_policy_document" "find_batch_to_close_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "sqs:GetQueueAttributes",
      "sqs:GetQueueUrl",
      "sqs:ListQueueTags",
      "sqs:TagQueue",
      "sqs:UntagQueue",
      "sqs:SendMessageBatch",
      "sqs:SendMessage"
    ]
    resources = [
      module.queue_batch_to_close.queue_arn
    ]
  }
}

resource "aws_iam_policy" "find_batch_to_close_lambda_policy" {
  name        = "${var.environment}-${var.lambda_find_batch_to_close_name}"
  description = "Find batch to close lambda policy"
  policy      = data.aws_iam_policy_document.find_batch_to_close_policy_document.json
}

module "lambda_find_batch_to_close" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"

  environment                                    = var.environment
  application_family                             = var.application_family
  use_container_image                            = true
  lambda_name                                    = "${var.service_name}-${var.lambda_find_batch_to_close_name}"
  lambda_description                             = "Sets the status of appropriate batches to ready_to_close"
  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_enabled                                    = true
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  vpc_id                                         = var.vpc_id
  cloudwatch_event_enabled                       = true
  cloudwatch_event_schedule                      = "rate(1 minute)"
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = 1
  iam_managed_policy_attachments = [
    aws_iam_policy.find_batch_to_close_lambda_policy.arn
  ]

  lambda_function_environment_variables = {
    Environment            = var.environment
    SENTRY_DSN             = module.sentry_find_batch_to_close_lambda.sentry_key_dsn_public_output
    CLOSE_BATCH_QUEUE_NAME = module.queue_batch_to_close.queue_name
    DD_MYSQL_HOST          = var.dd_mysql_host
    DD_MYSQL_PORT          = var.dd_mysql_port
    DD_MYSQL_DATABASE      = var.dd_mysql_database
    DD_API_KEY_SECRET_ARN  = data.aws_secretsmanager_secret.datadog_api.arn
  }
}