data "aws_iam_policy_document" "queue_tagger_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "sqs:GetQueueAttributes",
      "sqs:GetQueueUrl",
      "sqs:ListQueueTags",
      "sqs:ListQueues",
      "sqs:TagQueue",
      "sqs:UntagQueue"
    ]
    resources = [
      "arn:aws:sqs:${var.region}:${data.aws_caller_identity.current.account_id}:${var.environment}-delivery*_e*",
      "arn:aws:sqs:${var.region}:${data.aws_caller_identity.current.account_id}:${var.environment}-delivery*_e*/*",
      "arn:aws:sqs:${var.region}:${data.aws_caller_identity.current.account_id}:${var.environment}-encoding*_e*",
      "arn:aws:sqs:${var.region}:${data.aws_caller_identity.current.account_id}:${var.environment}-encoding*_e*/*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "sqs:GetQueueAttributes",
      "sqs:ListQueues"
    ]

    resources = [
      "arn:aws:sqs:${var.region}:${data.aws_caller_identity.current.account_id}:*"
    ]
  }
}

resource "aws_iam_policy" "queue_tagger_lambda_policy" {
  name        = "${var.environment}-${var.lambda_queue_tagger_name}"
  description = "queue-tagger lambda policy"
  policy      = data.aws_iam_policy_document.queue_tagger_policy_document.json
}

module "lambda_queue_tagger" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"

  environment                 = var.environment
  application_family          = var.application_family
  use_container_image         = true
  lambda_name                 = "${var.service_name}-${var.lambda_queue_tagger_name}"
  lambda_description          = "Parse SQS queue URLs and tags to match queue with attributes"
  lambda_function_memory_size = var.lambda_memory_size
  datadog_advanced_enabled    = true
  datadog_enabled             = true

  lambda_function_environment_variables = {
    Environment = var.environment
    SENTRY_DSN  = module.sentry_queue_tagger_lambda.sentry_key_dsn_public_output
  }

  lambda_function_timeout   = var.lambda_default_timeout
  vpc_enabled               = true
  vpc_id                    = var.vpc_id
  vpc_subnet_ids            = var.vpc_subnet_ids
  cloudwatch_event_enabled  = true
  cloudwatch_event_schedule = "rate(5 minutes)"

  iam_managed_policy_attachments = [
    aws_iam_policy.queue_tagger_lambda_policy.arn,
    module.queue_tagger_owsrequest.policy_arn_output
  ]
}