data "aws_iam_policy_document" "ready_deliveries_manager_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction"
    ]
    resources = [
      module.lambda_ready_deliveries_lambda.lambda_arn
    ]
  }
}

resource "aws_iam_policy" "ready_deliveries_manager_lambda_policy" {
  name        = "${var.environment}-${var.lambda_ready_deliveries_manager_name}"
  description = "Ready deliveries manager lambda policy"
  policy      = data.aws_iam_policy_document.ready_deliveries_manager_policy_document.json
}

module "lambda_ready_deliveries_manager_lambda" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"

  environment                 = var.environment
  application_family          = var.application_family
  lambda_name                 = "${var.service_name}-${var.lambda_ready_deliveries_manager_name}"
  lambda_description          = "The new delivery ready-deliveries manager script."
  cloudwatch_event_enabled    = true
  cloudwatch_event_schedule   = "rate(1 minute)"
  lambda_function_memory_size = 2048
  lambda_function_timeout     = 420
  vpc_id                      = var.vpc_id
  vpc_subnet_ids              = var.vpc_subnet_ids
  use_container_image         = true
  datadog_advanced_enabled    = true
  datadog_enabled             = true

  lambda_function_reserved_concurrent_executions = 1

  iam_managed_policy_attachments = [
    aws_iam_policy.ready_deliveries_manager_lambda_policy.arn
  ]

  lambda_function_environment_variables = {
    Environment       = var.environment
    DD_MYSQL_USER     = "lambda-rdy-dlvr"
    DD_MYSQL_HOST     = var.dd_mysql_host
    DD_MYSQL_PORT     = var.dd_mysql_port
    DD_MYSQL_DATABASE = var.dd_mysql_database
    SENTRY_DSN        = module.sentry_ready_deliveries_manager_lambda.sentry_key_dsn_public_output

    READY_DELIVERIES_LAMBDA_NAME = module.lambda_ready_deliveries_lambda.lambda_name
  }
}