module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/marketing-data-intelligence-mcp/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "marketing_data_intelligence_mcp_fargate" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family
  container_port     = "8001"
  task_type          = "web_service"
  health_check_path  = "/health"
  desired_task_count = 2
  task_cpu           = 2048
  task_memory        = 8192
  maximum_capacity   = 4
  minimum_capacity   = 2

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  load_balancer_is_internal     = true

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    { ENVIRONMENT = var.environment },
    { APP_DEBUG = "0" },
    { BROWSER_HEADLESS = "true" },
    { BROWSER_ENGINE = "camoufox" },
    { OUTPUT_DIR = "output" },
    { AWS_REGION = var.aws_region },
    { MCP_PORT = "8001" },
    { SENTRY_DSN = module.sentry.sentry_key_dsn_public_output },
  ]

  secrets = [
    { ANTHROPIC_API_KEY = "${var.environment}/${var.service_name}/ANTHROPIC_API_KEY" },
    { PROXY_LIST = "${var.environment}/${var.service_name}/PROXY_LIST" },
  ]
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.2"

  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  critical_number_5xx               = var.critical_number_5xx
  critical_recovery_number_5xx      = var.critical_recovery_number_5xx
  warning_number_5xx                = var.warning_number_5xx
  warning_recovery_number_5xx       = var.warning_recovery_number_5xx
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
  teams                             = [var.application_family]
}