module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/marketing-data-intelligence/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "marketing_data_intelligence_fargate" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family
  commit_sha         = "latest"
  container_port     = "8080"
  task_type          = "web_service"
  desired_task_count = 1
  task_cpu           = 2048
  task_memory        = 8192
  maximum_capacity   = 2
  minimum_capacity   = 1

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled         = false
  blocking_waf_enabled          = false

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    "arn:aws:iam::aws:policy/AmazonBedrockFullAccess",
  ]

  secrets = [
    { ANTHROPIC_API_KEY = "${var.environment}/${var.service_name}/ANTHROPIC_API_KEY" },
    { PROXY_LIST = "${var.environment}/${var.service_name}/PROXY_LIST" },
  ]

  environment_variables = [
    { ENVIRONMENT = var.environment },
    { APP_DEBUG = "0" },
    { AGENT_BACKEND = "bedrock" },
    { BEDROCK_MODEL_ID = "us.anthropic.claude-sonnet-4-6-20250514-v1:0" },
    { BEDROCK_WATCH_MODEL_ID = "us.anthropic.claude-haiku-4-5-20251001-v1:0" },
    { BROWSER_HEADLESS = "true" },
    { BROWSER_ENGINE = "camoufox" },
    { OUTPUT_DIR = "output" },
    { AWS_REGION = var.aws_region },
    { MCP_PORT = "8001" },
    { MCP_SERVER_URL = "https://${var.environment}-marketing-data-intel-mcp.theorchard.io/mcp" },
    { SENTRY_DSN = module.sentry.sentry_key_dsn_public_output },
  ]
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.3"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.2"

  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  critical_number_5xx               = var.critical_number_5xx
  critical_recovery_number_5xx      = var.critical_recovery_number_5xx
  warning_number_5xx                = var.warning_number_5xx
  warning_recovery_number_5xx       = var.warning_recovery_number_5xx
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
  service_4xx_monitor_enabled       = false
  service_cpu_monitor_enabled       = false
  teams                             = [var.application_family]
}