module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  profile = "networking"
  alias   = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/martech-snowflake-salesforce-node/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "service_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.service_name
  application_family = var.application_family
}

module "services_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "service_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  aws_region                = var.region
  commit_sha                = "latest"
  container_port            = "8080"
  task_type                 = "web_service"
  desired_task_count        = 1
  task_cpu                  = 512
  task_memory               = 1024
  maximum_capacity          = 1
  minimum_capacity          = 1
  route53_zone_id           = data.aws_route53_zone.theorchard_io.zone_id
  load_balancer_is_internal = "false"
  vpc_id                    = module.vpc_info.vpc_id
  non_ecr_image             = "086679231553.dkr.ecr.${var.region}.amazonaws.com/${var.application_family}-${var.service_name}:latest"
  custom_waf_arn            = module.custom_waf.waf_blocking_arn_output

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_public_subnet_ids

  prod_https_listener_allow_cidr_blocks = data.cloudflare_ip_ranges.cloudflare.ipv4_cidrs

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      AUTH0_DOMAIN = "workstation.auth0.com"
    },
    {
      AUTH0_API_AUDIENCE = "https://prod-martech-snowflake-salesforce-node"
    },
    {
      NODE_ENV = "production"
    },
    {
      DD_LOGS_INJECTION = true
    },
    {
      SENTRY_DSN = module.service_sentry_project.sentry_key_dsn_public_output
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    }
  ]
  secrets = [
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
    {
      SNOWFLAKE_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_PASSPHRASE"
    },
    {
      AES_KEY = "${var.environment}/${var.service_name}/AES_KEY"
    },
  ]
}

module "service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"

  environment  = var.environment
  service_name = var.service_name

  environment_type                  = "fargate"
  notification_endpoints            = var.alert_channel
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  application_family                = var.application_family
  escalation_notification_endpoints = var.alert_channel
}

resource "cloudflare_dns_record" "service_lb_cname_record" {
  zone_id = data.cloudflare_zone.cloudflare_domain.zone_id
  name    = var.service_name
  content = module.service_fargate_environment.fargate_load_balancer_dns_name
  type    = "CNAME"
  proxied = true
  ttl     = 1
}