module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = "us-east-1"
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/monty-feed-status/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_route53_zone" "networking_route53_zone" {
  provider = aws.networking

  name = "theorchard.io"
}

data "aws_iam_policy_document" "additional_dynamo_policy" {
  statement {
    effect = "Allow"
    actions = [
      "dynamodb:BatchGetItem",
      "dynamodb:DescribeStream",
      "dynamodb:DescribeTable",
      "dynamodb:GetItem",
      "dynamodb:GetRecords",
      "dynamodb:ListStreams",
      "dynamodb:Query",
      "dynamodb:Scan"
    ]

    resources = [
      "arn:aws:dynamodb:us-east-1:437795906767:table/prod_sql2sf_table_sync_status",
      "arn:aws:dynamodb:us-east-1:437795906767:table/prod_feed_sender_status",
      "arn:aws:dynamodb:us-east-1:437795906767:table/prod_feed_ingestion_status",
      "arn:aws:dynamodb:us-east-1:437795906767:table/prod_activity_detector_status"
    ]
  }
}

resource "aws_iam_policy" "additional_dynamo_policy" {
  name   = "Dynamo-${var.environment}-monty-feed-status-RO"
  policy = data.aws_iam_policy_document.additional_dynamo_policy.json
}

module "monty_feed_status_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.7.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                   = var.environment
  service_name                  = var.service_name
  application_family            = var.application_family
  aws_region                    = var.aws_region
  commit_sha                    = "latest"
  container_port                = "8080"
  task_type                     = "web_service"
  health_check_path             = "/static/feed_ingestion_dashboard.html"
  desired_task_count            = 2
  task_cpu                      = 512
  task_memory                   = 1024
  maximum_capacity              = 2
  minimum_capacity              = 1
  route53_zone_id               = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/S3-qa-cucumbers-RW",
    aws_iam_policy.additional_dynamo_policy.arn
  ]

  prod_https_listener_allow_cidr_blocks = [
    "192.168.32.0/24",
    "192.168.40.0/22",
  ]

  https_listener_allow_prefix_list_names = [
    "vpn-ny-users",
  ]

  fargate_service_subnets = ["subnet-098b89d0c58c5693a", "subnet-067a6b45b079d7296", "subnet-043d235081c966332"]

  load_balancer_subnets = ["subnet-098b89d0c58c5693a", "subnet-067a6b45b079d7296", "subnet-043d235081c966332"]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      SQL2SF_STATUS_TABLE = "prod_sql2sf_table_sync_status"
    },
    {
      SNOWFLAKE_USER = var.snowflake_service_account_user
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      S3_BUCKET_NAME = var.s3_bucket_name
    },
    {
      DELPHI_SLZ_DATABASE = var.delphi_slz_database
    },
    {
      DELPHI_SLZ_HOST = var.delphi_slz_host
    },
    {
      DELPHI_SLZ_USER = var.delphi_slz_user
    }
  ]

  secrets = [
    {
      LogETL_DB_URL = "${var.environment}/${var.service_name}/LogETL_DB_URL"
    },
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      SNOWFLAKE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY"
    },
    {
      DELPHI_SLZ_PASSWORD = "${var.environment}/${var.service_name}/DELPHI_SLZ_PASSWORD"
    }
  ]
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.2"
  application_family                = var.application_family
  environment                       = var.environment
  notification_endpoints            = "@slack-data-alerts"
  escalation_notification_endpoints = "@slack-data-alarm"
  environment_type                  = "fargate"
  service_name                      = var.service_name
  service_cpu_critical_number       = 95

  # Overrids for 5xx alerts
  notification_overrides_5xx = {
    endpoints            = "@slack-data-alerts"
    escalation_endpoints = "@slack-data-alerts"
  }
}

# create multiple secrets
module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

resource "aws_route53_record" "monty_route53_record" {
  name    = "monty.theorchard.io"
  type    = "CNAME"
  zone_id = data.aws_route53_zone.route53_zone.zone_id
  ttl     = 300
  records = [module.monty_feed_status_fargate_environment.fargate_load_balancer_dns_name]
}

resource "aws_route53_record" "monty_networking_route53_record" {
  provider = aws.networking

  name    = "monty.theorchard.io"
  type    = "CNAME"
  zone_id = data.aws_route53_zone.networking_route53_zone.zone_id
  ttl     = 300
  records = [module.monty_feed_status_fargate_environment.fargate_load_balancer_dns_name]
}