# NR CMO Claiming Step Function.
data "aws_caller_identity" "current" {}

# reference to metadata generator lambda.
data "aws_lambda_function" "lambda_metadata_generator_metadata" {
  function_name = "${var.environment}-${var.metadata_generator_lambda_name}"
}


# Assume role policy for state machine.
data "aws_iam_policy_document" "assume_role_for_claiming_state_machine_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.${var.region}.amazonaws.com",
      ]
    }
  }
}

# States role for lambda invocation.
resource "aws_iam_role" "invoke_claiming_lambdas_from_state_machine" {
  name               = "${var.environment}-nr-cmo-claiming-invoke-lambdas-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_claiming_state_machine_policy.json
}

# Policy that gives the state machine role permission to invoke lambdas.
data "aws_iam_policy_document" "invoke_claiming_lambdas_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_nr_claim_create_jobs.lambda_arn,
      data.aws_lambda_function.lambda_metadata_generator_metadata.arn,
      module.lambda_nr_claim_job_finalizer.lambda_arn,
      module.lambda_nr_claim_finalizer.lambda_arn,
    ]
  }
}

resource "aws_iam_policy" "invoke_claiming_lambdas_policy" {
  name   = "Lambda-${var.environment}-nr-cmo-claiming-invoke-lambdas-policy"
  policy = data.aws_iam_policy_document.invoke_claiming_lambdas_policy_document.json
}


# Policy that gives the state machine role permission to run fargate tasks.
data "aws_iam_policy_document" "invoke_claiming_fargate_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "ecs:RunTask",
    ]
    resources = [
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.fargate_claimorizer_name}:*",
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.fargate_job_combiner_name}:*",
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:StopTask"
    ]
    resources = [
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-${var.fargate_claimorizer_name}/*",
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-${var.fargate_job_combiner_name}/*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:DescribeTasks"
    ]
    resources = [
      "*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "events:PutTargets",
      "events:PutRule",
      "events:DescribeRule"
    ]
    resources = [
      "arn:aws:events:${var.region}:${data.aws_caller_identity.current.account_id}:rule/StepFunctionsGetEventsForECSTaskRule"
    ]
  }

  statement {
    effect  = "Allow"
    actions = ["iam:PassRole"]
    resources = [
      "arn:aws:iam::*:role/${var.environment}-${var.fargate_claimorizer_name}-task-role",
      "arn:aws:iam::*:role/${var.environment}-${var.fargate_claimorizer_name}-task-execution-role",
      "arn:aws:iam::*:role/${var.environment}-${var.fargate_job_combiner_name}-task-role",
      "arn:aws:iam::*:role/${var.environment}-${var.fargate_job_combiner_name}-task-execution-role",

    ]
  }
}

resource "aws_iam_policy" "invoke_claiming_fargate_tasks_policy" {
  name   = "Fargate-${var.environment}-nr-claim-invoke-policy"
  policy = data.aws_iam_policy_document.invoke_claiming_fargate_policy_document.json
}


resource "aws_iam_role_policy_attachment" "invoke_claiming_lambdas_role_policy_attachment" {
  for_each = toset([
    aws_iam_policy.invoke_claiming_lambdas_policy.arn,
    aws_iam_policy.invoke_claiming_state_machine_policy.arn,
    aws_iam_policy.invoke_claiming_fargate_tasks_policy.arn,
    data.aws_iam_policy.delivery_bucket_rw_policy.arn,
  ])
  role       = aws_iam_role.invoke_claiming_lambdas_from_state_machine.id
  policy_arn = each.key

}

# State machine.
resource "aws_sfn_state_machine" "claiming_state_machine" {
  name     = "${var.environment}-${var.claiming_state_machine_name}"
  role_arn = aws_iam_role.invoke_claiming_lambdas_from_state_machine.arn
  definition = templatefile("${path.module}/cmo_claiming_workflow.json", {
    # add all lambda variables here.
    create_jobs_lambda_arn        = module.lambda_nr_claim_create_jobs.lambda_arn,
    order_finalizer_lambda_arn    = module.lambda_nr_claim_finalizer.lambda_arn,
    metadata_generator_lambda_arn = data.aws_lambda_function.lambda_metadata_generator_metadata.arn,
    job_finalizer_lambda_arn      = module.lambda_nr_claim_job_finalizer.lambda_arn

    # fargate variables
    fargate_claimorizer_name = var.fargate_claimorizer_name,
    fargate_claimorizer_arn  = module.fargate_claimorizer.fargate_cluster_arn,
    // not using module.fargate_claimorizer.fargate_task_definition_arn because we dont want the tag. that will make it use latest version.
    fargate_claimorizer_task_arn = "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.fargate_claimorizer_name}",

    fargate_job_combiner_name     = var.fargate_job_combiner_name,
    fargate_job_combiner_arn      = module.fargate_job_combiner.fargate_cluster_arn,
    fargate_job_combiner_task_arn = "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.fargate_job_combiner_name}",

    subnet_id0 = module.vpc_info.default_private_subnet_ids[0],
    subnet_id1 = module.vpc_info.default_private_subnet_ids[1],

    bucket_name = data.aws_s3_bucket.s3_bucket.bucket,
  })

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.claiming_state_machine_name
    terraformed        = true
  }

  tracing_configuration {
    enabled = true
  }
}

# Invoke Step Function Policy
data "aws_iam_policy_document" "invoke_claiming_state_machine_policy_doc" {
  statement {
    actions = [
      "states:StartExecution",
      "states:ListExecutions",
    ]

    resources = [
      aws_sfn_state_machine.claiming_state_machine.arn
    ]
  }
}

resource "aws_iam_policy" "invoke_claiming_state_machine_policy" {
  name        = "StepFunctions-${var.environment}-${var.claiming_state_machine_name}-InvokeOnly"
  description = "Invoke CMO claiming state machine"
  policy      = data.aws_iam_policy_document.invoke_claiming_state_machine_policy_doc.json
}

data "aws_iam_policy_document" "send_heartbeat_claiming_state_machine_policy_doc" {
  statement {
    actions = [
      "states:SendTaskHeartbeat",
      "states:SendTaskSuccess",
      "states:SendTaskFailure"
    ]

    resources = [
      "arn:aws:states:${var.region}:${data.aws_caller_identity.current.account_id}:stateMachine:${var.environment}-${var.claiming_state_machine_name}"
    ]
  }
}

resource "aws_iam_policy" "send_heartbeat_claiming_state_machine_policy" {
  name        = "StepFunctions-${var.environment}-${var.claiming_state_machine_name}-SendHeartbeat"
  description = "Send heartbeat to CMO claiming state machine"
  policy      = data.aws_iam_policy_document.send_heartbeat_claiming_state_machine_policy_doc.json
}