module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/neighbouring-rights/graphql/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_s3_bucket" "s3_bucket" {
  bucket = "${var.environment}-neighbouring-rights"
}

data "aws_iam_policy" "input_bucket_readonly_policy" {
  name = "S3-${var.environment}-neighbouring-rights-RO"
}

data "aws_iam_policy" "invoke_claiming_state_machine_policy" {
  name = "StepFunctions-${var.environment}-nr-cmo-claiming-InvokeOnly"
}

data "aws_iam_policy" "invoke_nr_ownership_delivery_state_machine_policy" {
  name = "StepFunctions-${var.environment}-nr-ownership-delivery-StartExecution"
}

data "aws_iam_role" "neighbouring_rights_browser_upload_role" {
  name = "${var.environment}-neighbouring-rights-browser-upload-role"
}

data "aws_sfn_state_machine" "claiming_state_machine" {
  name = "${var.environment}-nr-cmo-claiming"
}

data "aws_sfn_state_machine" "nr_ownership_delivery_state_machine" {
  name = "${var.environment}-nr-ownership-delivery"
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "graphql_neighbouring_rights_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
  splitio_enabled    = true

  aws_region                    = var.region
  commit_sha                    = "latest"
  container_port                = "8080"
  task_type                     = "web_service"
  desired_task_count            = 2
  task_cpu                      = 2048
  task_memory                   = var.task_memory
  datadog_task_memory           = var.datadog_memory
  maximum_capacity              = 4
  minimum_capacity              = 2
  route53_zone_id               = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  blocking_waf_enabled          = true

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    data.aws_iam_policy.input_bucket_readonly_policy.arn,
    data.aws_iam_policy.invoke_claiming_state_machine_policy.arn,
    data.aws_iam_policy.invoke_nr_ownership_delivery_state_machine_policy.arn,
  ]


  environment_variables = [
    {
      NODE_OPTIONS = "--max-old-space-size=${var.task_memory - var.datadog_memory}"
    },
    {
      Environment = var.environment
    },
    {
      NODE_ENV = var.environment
    },
    {
      APOLLO_ENGINE_SCHEMA_TAG = var.environment
    },
    {
      APOLLO_GRAPH_VARIANT = var.environment
    },
    {
      APOLLO_INTROSPECTION = var.introspection
    },
    {
      APOLLO_PLAYGROUND = var.playground
    },
    {
      DD_LOGS_INJECTION = true
    },
    {
      SENTRY_DSN = module.graphql_neighbouring_rights_sentry_project.sentry_key_dsn_public_output
    },
    {
      OWS_REQUEST_TRACING = true
    },
    {
      NEO4J_URL = var.NEO4J_URL
    },
    {
      NEO4J_AURA_URL = var.NEO4J_AURA_URL
    },
    {
      UPLOAD_BUCKET = data.aws_s3_bucket.s3_bucket.bucket
    },
    {
      UPLOAD_ROLE_ARN = data.aws_iam_role.neighbouring_rights_browser_upload_role.arn
    },
    {
      UPLOAD_TOKEN_DURATION = 3600
    },
    {
      NR_DELIVERY_HOSTNAME = "${var.environment}-neighbouring-rights-delivery-db.theorchard.io"
    },
    {
      NR_DELIVERY_RW_MAX_CONNECTIONS = var.max_rw_connections
    },
    {
      NR_DELIVERY_USERNAME = "graphql-neighbouring-rights"
    },
    {
      NR_DELIVERY_DB_NAME = "neighbouring_rights_delivery"
    },
    {
      NR_DELIVERY_SALESFORCE_DB_NAME = "salesforce"
    },
    {
      NR_OWNERSHIP_DELIVERY_HOSTNAME = "${var.environment}-neighbouring-rights-ownership-delivery-db.theorchard.io"
    },
    {
      NR_OWNERSHIP_DELIVERY_RW_MAX_CONNECTIONS = var.max_rw_connections
    },
    {
      NR_OWNERSHIP_DELIVERY_USERNAME = "graphql-nr"
    },
    {
      NR_OWNERSHIP_DELIVERY_DB_NAME = "neighbouring_rights_ownership_delivery"
    },
    {
      SFORCE_DOMAIN = "login"
    },
    {
      S3_SIGNED_URL_EXPIRY = 1200
    },
    {
      INGESTION_FOLDER = "ingestion/"
    },
    {
      KAFKA_BROKERS = var.kafka_brokers
    },
    {
      KAFKA_FILE_INGESTION_TOPIC = var.kafka_file_ingestion_topic
    },
    {
      SCHEMA_REGISTRY_URL = var.schema_registry_url
    },
    {
      CMO_CLAIMING_STEPFN_ARN = data.aws_sfn_state_machine.claiming_state_machine.arn
    },
    {
      KSQL_URL = var.ksql_url
    },
    {
      OWNERSHIP_DELIVERY_STEPFN_ARN = data.aws_sfn_state_machine.nr_ownership_delivery_state_machine.arn
    },
  ]

  secrets = [
    {
      NEO4J_USER = "${var.environment}/${var.service_name}/NEO4J_USERNAME"
    },
    {
      NEO4J_PASSWORD = "${var.environment}/${var.service_name}/NEO4J_PASSWORD"
    },
    {
      NEO4J_AURA_USERNAME = "${var.environment}/${var.service_name}/NEO4J_AURA_USERNAME"
    },
    {
      NEO4J_AURA_PASSWORD = "${var.environment}/${var.service_name}/NEO4J_AURA_PASSWORD"
    },
    {
      SPLIT_API_KEY = "prod/split/API_KEY"
    },
    {
      NR_DELIVERY_PASSWORD = "${var.environment}/${var.service_name}/NR_DELIVERY_PASSWORD"
    },
    {
      NR_OWNERSHIP_DELIVERY_PASSWORD = "${var.environment}/${var.service_name}/NR_OWNERSHIP_DELIVERY_PASSWORD"
    },
    {
      KSQL_CREDS = "${var.environment}/${var.service_name}/KSQL_CREDS"
    },
    {
      SFORCE_REFRESH_TOKEN = "${var.environment}/${var.service_name}/SFORCE_REFRESH_TOKEN"
    },
    {
      SFORCE_CLIENT_ID = "${var.environment}/${var.service_name}/SFORCE_CLIENT_ID"
    },
    {
      SFORCE_CLIENT_SECRET = "${var.environment}/${var.service_name}/SFORCE_CLIENT_SECRET"
    }
  ]
}

module "graphql_neighbouring_rights_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.service_name
  application_family = var.application_family
}

module "graphql_neighbouring_rights_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"

  environment                            = var.environment
  service_name                           = var.service_name
  environment_type                       = "fargate"
  application_family                     = var.application_family
  notification_endpoints                 = var.notification_endpoints
  escalation_notification_endpoints      = var.escalation_notification_endpoints
  datadog_service_type                   = "${var.service_name}-graphql"
  datadog_service_name                   = "graphql.execute"
  healthy_tasks_critical_number          = "1.8"
  healthy_tasks_critical_recovery_number = "1.9"
  healthy_tasks_warning_number           = "1.9"
  healthy_tasks_warning_recovery_number  = "2"
  healthy_tasks_ok_number                = "2"
  dependent_applications                 = var.dependent_applications
  teams                                  = concat([var.team_name], var.additional_teams)
}