# state machine initiated with this policy/role.
data "aws_iam_policy_document" "assume_role_for_state_machine_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.${var.region}.amazonaws.com",
      ]
    }
  }
}

resource "aws_iam_role" "state_machine_role" {
  name               = "${var.environment}-${var.state_machine_name}-state-machine-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_state_machine_policy.json
}

data "aws_lambda_function" "lambda_metadata_generator_metadata" {
  function_name = "${var.environment}-${var.metadata_generator_lambda_name}"
}

data "aws_iam_policy_document" "invoke_lambda_policy_for_state_machine" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      module.lambda-nr-ownership-delivery-order-populator.lambda_arn,
      module.lambda-nr-ownership-delivery-template-data-loader.lambda_arn,
      module.lambda-nr-ownership-delivery-order-finalizer.lambda_arn,
      module.lambda-nr-ownership-delivery-ddex-generator.lambda_arn,
      module.lambda-nr-ownership-delivery-contract-processor.lambda_arn,
      data.aws_lambda_function.lambda_metadata_generator_metadata.arn,
      module.lambda-nr-ownership-delivery-order-recorder.lambda_arn,
      module.lambda-nr-ownership-delivery-history-filter.lambda_arn,
    ]
  }
}

# Policy that gives the state machine role permission to start Distributed Map Executions
data "aws_iam_policy_document" "start_execution_state_machine_policy_doc" {
  statement {
    actions = [
      "states:StartExecution",
      "states:ListExecutions",
    ]

    resources = [
      aws_sfn_state_machine.state_machine.arn
    ]
  }
}


# Policy that gives the state machine role permission to run fargate tasks.
data "aws_iam_policy_document" "invoke_fargate_tasks_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "ecs:RunTask",
    ]
    resources = [
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.fargate_outputfilebuilder_name}:*",
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.fargate_ddex_compiler_name}:*",
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:StopTask"
    ]
    resources = [
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-${var.fargate_outputfilebuilder_name}/*",
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-${var.fargate_ddex_compiler_name}/*",
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:DescribeTasks"
    ]
    resources = [
      "*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "events:PutTargets",
      "events:PutRule",
      "events:DescribeRule"
    ]
    resources = [
      "arn:aws:events:${var.region}:${data.aws_caller_identity.current.account_id}:rule/StepFunctionsGetEventsForECSTaskRule"
    ]
  }

  statement {
    effect  = "Allow"
    actions = ["iam:PassRole"]
    resources = [
      "arn:aws:iam::*:role/${var.environment}-${var.fargate_outputfilebuilder_name}-task-role",
      "arn:aws:iam::*:role/${var.environment}-${var.fargate_ddex_compiler_name}-task-role",
      "arn:aws:iam::*:role/${var.environment}-${var.fargate_outputfilebuilder_name}-task-execution-role",
      "arn:aws:iam::*:role/${var.environment}-${var.fargate_ddex_compiler_name}-task-execution-role",

    ]
  }
}

resource "aws_iam_role_policy" "invoke_fargate_tasks_policy" {
  name   = "Fargate-${var.environment}-nr-fargate-tasks-invoke-policy"
  role   = aws_iam_role.state_machine_role.id
  policy = data.aws_iam_policy_document.invoke_fargate_tasks_policy_document.json
}

resource "aws_iam_policy" "start_execution_state_machine_policy" {
  name        = "StepFunctions-${var.environment}-${var.state_machine_name}-StartExecution"
  description = "Invoke Distributed Map Child State Machines"
  policy      = data.aws_iam_policy_document.start_execution_state_machine_policy_doc.json
}

# Policy that gives the state machine role permission to invoke lambdas
resource "aws_iam_role_policy" "invoke_lambda_role_policy" {
  name   = "${var.environment}-${var.state_machine_name}-invoke-lambda-role-policy"
  role   = aws_iam_role.state_machine_role.id
  policy = data.aws_iam_policy_document.invoke_lambda_policy_for_state_machine.json
}

resource "aws_iam_role_policy_attachment" "policy_attachments" {
  for_each = toset([
    aws_iam_policy.start_execution_state_machine_policy.arn,
    aws_iam_policy.ownership_delivery_s3_read.arn,
  ])
  role       = aws_iam_role.state_machine_role.id
  policy_arn = each.key
}

resource "aws_sfn_state_machine" "state_machine" {
  name     = "${var.environment}-${var.state_machine_name}"
  role_arn = aws_iam_role.state_machine_role.arn
  definition = templatefile("${path.module}/delivery_workflow.json", {
    # add all variables here that will be used by delivery_workflow.json.
    order_populator_arn              = module.lambda-nr-ownership-delivery-order-populator.lambda_arn
    template_data_loader_arn         = module.lambda-nr-ownership-delivery-template-data-loader.lambda_arn
    order_finalizer_arn              = module.lambda-nr-ownership-delivery-order-finalizer.lambda_arn
    ddex_generator_arn               = module.lambda-nr-ownership-delivery-ddex-generator.lambda_arn
    contract_processor_arn           = module.lambda-nr-ownership-delivery-contract-processor.lambda_arn
    metadata_generator_arn           = data.aws_lambda_function.lambda_metadata_generator_metadata.arn
    order_recorder_arn               = module.lambda-nr-ownership-delivery-order-recorder.lambda_arn
    orchard_history_filter_arn       = module.lambda-nr-ownership-delivery-history-filter.lambda_arn

    fargate_output_file_builder_name = var.fargate_outputfilebuilder_name
    output_file_builder_cluster_arn  = module.fargate_outputfilebuilder.fargate_cluster_arn
    output_file_builder_task_arn     = module.fargate_outputfilebuilder.fargate_task_definition_arn

    fargate_ddex_compiler_builder_name = var.fargate_ddex_compiler_name
    ddex_compiler_cluster_arn          = module.fargate_ddex_compiler.fargate_cluster_arn
    ddex_compiler_task_arn             = module.fargate_ddex_compiler.fargate_task_definition_arn

    subnet_id0 = module.vpc_info.default_private_subnet_ids[0]
    subnet_id1 = module.vpc_info.default_private_subnet_ids[1]

    bucket_name = data.aws_s3_bucket.s3_bucket.bucket
  })

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.state_machine_name
    terraformed        = true
  }

  tracing_configuration {
    enabled = true
  }
}

data "aws_iam_policy_document" "send_task_status_state_machine_policy_doc" {
  statement {
    actions = [
      "states:SendTaskHeartbeat",
      "states:SendTaskSuccess",
      "states:SendTaskFailure"
    ]

    resources = [
      "arn:aws:states:${var.region}:${data.aws_caller_identity.current.account_id}:stateMachine:${var.environment}-${var.state_machine_name}"
    ]
  }
}

resource "aws_iam_policy" "send_task_status_state_machine_policy" {
  name        = "StepFunctions-${var.environment}-${var.state_machine_name}-SendHeartbeat-Policy"
  description = "Send heartbeat and task success/failure to ownership delivery state machine"
  policy      = data.aws_iam_policy_document.send_task_status_state_machine_policy_doc.json
}