module "lambda-nr-ownership-ingest-ar-release-artist-filter" {
  source                      = "git@github.com:theorchard/terraform-lambda.git//?ref=4.0.1"
  environment                 = var.environment
  lambda_name                 = var.ar_release_artist_filter_lambda_name
  lambda_description          = "Consumes cdc art relation release_artist data."
  lambda_function_timeout     = "900"
  use_container_image         = true
  vpc_subnet_ids              = module.vpc_info.default_private_subnet_ids
  vpc_enabled                 = true
  vpc_id                      = module.vpc_info.vpc_id
  datadog_advanced_enabled    = true
  application_family          = var.application_family
  lambda_function_memory_size = var.lambda_memory_size
  splitio_enabled             = true

  msk_event_enabled                      = var.msk_event_enabled
  event_source_mapping_msk_cluster_name  = var.trigger_msk_cluster_name
  event_source_mapping_msk_cluster_uuid  = var.trigger_msk_cluster_uuid
  event_source_mapping_batch_size        = 50
  kafka_topics                           = [var.ar_release_artist_topic, var.ar_track_artist_topic, var.ows_track_performer_topic]
  event_source_mapping_starting_position = "LATEST"

  # TODO: we could add a filter once we've confirmed the CDC / event_source_mapping is working
  # event_source_mapping_filter_criteria_pattern = jsonencode()

  lambda_function_environment_variables = {
    Environment         = var.environment
    DD_LAMBDA_HANDLER   = "app.handler"
    SENTRY_DSN          = module.lambda_nr_ownership_ingest_ar_release_artist_filter_sentry_project.sentry_key_dsn_public_output
    SPLIT_API_KEY_PATH  = "${var.environment}/split/API_KEY"
    BUCKET_NAME         = data.aws_s3_bucket.s3_bucket.bucket
    KAFKAJS_LOG_LEVEL   = "nothing"
    KAFKA_BROKERS       = var.kafka_brokers
    SQS_QUEUE_URL       = module.sqs_filter_products_queue.queue_url
    OWNER_ACCEPTED_LIST = var.owner_accepted_list
    LOGGER_LEVEL        = "info"
    REGISTRY_CHECK      = false
    SEND_TO_SQS         = var.send_to_sqs
  }

  lambda_function_reserved_concurrent_executions = 1

  iam_managed_policy_attachments = [
    data.aws_iam_policy.ownership_ingestion_bucket_rw_policy.arn,
    module.sqs_filter_products_queue.sqs_minimal_policy_arn_output
  ]
}

module "lambda_nr_ownership_ingest_ar_release_artist_filter_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  # the lambda name exceeds Sentry's 50 character limit when the env is prefixed
  service_name                 = "lambda-nr-ownership-ingest-ar-r-artist-filter"
  secrets_manager_service_name = var.ar_release_artist_filter_lambda_name
  environment                  = var.environment
  platform                     = "node"
  application_family           = var.application_family
}

module "datadog_lambda_nr_ownership_ingest_ar_release_artist_filter_dashboards" {
  source                 = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.4"
  service_name           = var.ar_release_artist_filter_lambda_name
  environment            = var.environment
  notification_endpoints = var.notification_endpoints
  teams                  = [var.team_name]
}

locals {
  ar_release_artist_filter_consumer_group_ids = var.msk_event_enabled ? join(" OR ", [for c in module.lambda-nr-ownership-ingest-ar-release-artist-filter.msk_event_source_mapping_uuid : "consumer_group:${c}"]) : ""
}

locals {
  ar_release_artist_filter_quiet_topics = var.msk_event_enabled ? join(" OR ", [for topic in [var.ar_release_artist_topic,  var.ows_track_performer_topic] : "topic:${lower(topic)}"]) : ""
}

#### Offset lag monitoring is split into two monitors:
#### 1. High-volume topic (ar_track_artist) with 800k threshold
#### 2. Lower-volume topics (ar_release_artist, ows_track_performer) with 5k threshold
#### This separation prevents alert fatigue from the busier track artist topic
resource "datadog_monitor" "lambda_nr_ownership_ingest_ar_release_artist_filter_offset_lag_monitor" {
  count = var.msk_event_enabled ? 1 : 0
  name               = "${var.environment}-${var.ar_release_artist_filter_lambda_name}-offset-lag"
  type               = "metric alert"
  message            = "{{#is_alert}} The Lambda offset lag is too high {{/is_alert}} {{#is_alert_recovery}} Offset lag is recovering {{/is_alert_recovery}} in {{[aws.kafka.sum_offset_lag].topic}} \n Notify: ${var.notification_endpoints}"
  query              = "avg(last_3h):aws.kafka.sum_offset_lag{environment:${var.environment} AND ${local.ar_release_artist_filter_quiet_topics}  AND (${local.ar_release_artist_filter_consumer_group_ids})} by {topic} > 5000"

  monitor_thresholds {
    critical = 5000
    warning  = 3000
  }

  notify_no_data = true
  no_data_timeframe = 60
  notify_audit = false
  renotify_interval = 30
  timeout_h = 0
  require_full_window = false

  tags = ["team:${var.team_name}"]
}

#### Separate monitor for ar_track_artist_topic due to significantly higher 
#### traffic volume compared to other topics consumed by this lambda.
#### Higher thresholds (800k vs 5k) reflect normal operating conditions.
resource "datadog_monitor" "lambda_nr_ownership_ingest_ar_track_release_artist_filter_offset_lag_monitor" {
  count = var.msk_event_enabled ? 1 : 0
  name               = "${var.environment}-${var.ar_track_release_artist_filter_monitor}-offset-lag"
  type               = "metric alert"
  message            = "{{#is_alert}} The Lambda offset lag on cdc.artRelations.trackArtistis too high {{/is_alert}} {{#is_alert_recovery}} Offset lag is recovering {{/is_alert_recovery}} in ${var.ar_track_artist_topic} \n Notify: ${var.notification_endpoints}"
  query              = "avg(last_3h):aws.kafka.sum_offset_lag{environment:${var.environment} AND topic:${lower(var.ar_track_artist_topic)} AND (${local.ar_release_artist_filter_consumer_group_ids})} by {topic} > 800000"

  monitor_thresholds {
    critical = 800000
    warning  = 500000
  }

  notify_no_data = true
  no_data_timeframe = 60
  notify_audit = false
  renotify_interval = 30
  timeout_h = 0
  require_full_window = false

  tags = ["team:${var.team_name}"]
}