module "neo4j_5_debian_environment_debian_13" {
  source = "git@github.com:theorchard/terraform-neo4j-cluster.git//debian?ref=1.1.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                       = var.environment
  service_name                      = "${var.service_name_v5}-debian-13"
  vpc_id                            = module.vpc_info.vpc_id
  vpc_private_subnet_ids            = module.vpc_info.default_private_subnet_ids
  data_volume_device_name           = "/dev/sdb"
  data_volume_device_type           = "io2"
  data_volume_iops                  = 30000
  data_volume_size                  = 3000
  data_volume_throughput            = null
  desired_capacity                  = 3
  ami_id                            = data.aws_ami.debian_13_arm64.id
  min_size                          = 3
  max_size                          = 3
  ssh_keypair_name                  = "orchard_admin"
  route53_zone_id                   = var.route53_hosted_zone
  dbms_backup_s3_bucket             = "prod-orcdbucket"
  data_volume_delete_on_termination = false
  aws_instance_type                 = "r8g.16xlarge"
  user_data                         = module.chef_bootstrap_neo4j_debian_13.user_data_output

  bolt_ingress_cidr_blocks = [
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
  ]
}

module "chef_bootstrap_neo4j_debian_13" {
  source = "git@github.com:theorchard/terraform-chef-bootstrap.git//?ref=4.0.1"

  chef_role                    = "prod_neo4j_5_debian_13_cluster"
  chef_environment             = var.environment
  aws_iam_role_id              = module.neo4j_5_debian_environment_debian_13.instance_iam_role_name_output
  aws_instance_name            = "${var.environment}-${var.service_name_v5}-debian-13"
  ebs_data_mount_point         = "/var/lib/neo4j"
  block_device_filesystem_type = "xfs"
}

data "aws_ami" "debian_13_arm64" {
  most_recent = true
  owners      = ["086679231553"]
  filter {
    name   = "name"
    values = ["debian-13-arm64-*"]
  }
}

resource "aws_iam_role_policy_attachment" "neo4j_debian_assume_role_policy" {
  role       = module.neo4j_5_debian_environment_debian_13.instance_iam_role_name_output
  policy_arn = aws_iam_policy.assume_cross_account_neo4j_dns_update_role_policy.arn
}

resource "aws_security_group_rule" "allow_ingres_pls" {
  type              = "ingress"
  from_port         = 7687
  to_port           = 7687
  protocol          = "TCP"
  security_group_id = module.neo4j_5_debian_environment_debian_13.instance_security_group_id_output
  prefix_list_ids = [
    data.aws_ec2_managed_prefix_list.permissions_platform_prod.id,
    data.aws_ec2_managed_prefix_list.vpn_sme_internal_primary.id,
  ]
  depends_on = [module.neo4j_5_debian_environment_debian_13]
}

resource "aws_security_group_rule" "allow_backup_host_deb_13" {
  type                     = "ingress"
  from_port                = 6362
  to_port                  = 6362
  protocol                 = "TCP"
  security_group_id        = module.neo4j_5_debian_environment_debian_13.instance_security_group_id_output
  source_security_group_id = data.aws_security_group.backup_host.id
  depends_on               = [module.neo4j_5_debian_environment_debian_13]
}

# The following two rules are temporary and will be removed once the migration is complete.
resource "aws_security_group_rule" "asg_debian13" {
  from_port                = 5000
  protocol                 = "TCP"
  to_port                  = 8000
  type                     = "ingress"
  security_group_id        = module.neo4j_5_debian_environment_debian_13.instance_security_group_id_output
  source_security_group_id = module.neo4j_5_debian_environment.instance_security_group_id_output
}
resource "aws_security_group_rule" "asg_neo4j_5" {
  from_port                = 5000
  protocol                 = "TCP"
  to_port                  = 8000
  type                     = "ingress"
  security_group_id        = module.neo4j_5_debian_environment.instance_security_group_id_output
  source_security_group_id = module.neo4j_5_debian_environment_debian_13.instance_security_group_id_output
}

resource "aws_security_group_rule" "allow_ssh_debian_13" {
  type      = "ingress"
  from_port = 22
  to_port   = 22
  protocol  = "TCP"
  prefix_list_ids = [
    data.aws_ec2_managed_prefix_list.vpn_sme_internal_primary.id,
  ]
  security_group_id = module.neo4j_5_debian_environment_debian_13.instance_security_group_id_output
}