module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.application_family
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/neo4j-cluster/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy" "prod_kms_backup_policy" {
  name = "${var.environment}-${var.service_name}-backup-policy"
}

data "aws_iam_policy" "prod_s3_backup_policy" {
  name = "${var.environment}-${var.service_name}-s3-readonly-backup-policy"
}

data "aws_security_group" "backup_host" {
  name = "prod-neo4j-backup-security-group"
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

# Create a role that can be assumed only by the dev cluster role to access prod backups
data "aws_iam_policy_document" "dev_cluster_access_prod_backups_assume_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::103233932089:role/service-role/StepFunctions-MyStateMachine-yxmps9rat-role-q4mc9xpx9",
        "arn:aws:iam::103233932089:role/dev-neo4j-5-cluster-debian-asg-role",
      ]
    }
    condition {
      test     = "StringEquals"
      values   = [var.external_id]
      variable = "sts:ExternalId"
    }
  }
}

# Create a role that can be assumed only by the dev cluster role to access prod backups
resource "aws_iam_role" "dev_cluster_read_backups_role" {
  name                 = "dev-${var.service_name}-access-${var.environment}-${var.service_name}-backups-role"
  assume_role_policy   = data.aws_iam_policy_document.dev_cluster_access_prod_backups_assume_role.json
  max_session_duration = 14400

  tags = {
    terraformed = "true"
  }
}

# Allow dev cluster to read Prod KMS key to pull backups
resource "aws_iam_role_policy_attachment" "dev_cluster_read_kms_backup_policy_attachment" {
  role       = aws_iam_role.dev_cluster_read_backups_role.name
  policy_arn = data.aws_iam_policy.prod_kms_backup_policy.arn
}

# Allow dev cluster to read Prod S3 backup location to pull backups
resource "aws_iam_role_policy_attachment" "dev_cluster_read_s3_backup_readonly_policy_attachment" {
  role       = aws_iam_role.dev_cluster_read_backups_role.name
  policy_arn = data.aws_iam_policy.prod_s3_backup_policy.arn
}

# Backup monitor
resource "datadog_monitor" "backup_monitor" {
  name               = "${var.environment}-${var.service_name}-backup-monitor"
  type               = "metric alert"
  message            = "Neo4j cluster backup has either not started or succeeded. Notify: @slack-monitoring @slack-neo4j-db"
  escalation_message = "Neo4j cluster backup has still either not started or succeeded. Notify: @slack-monitoring @slack-neo4j-db"

  query = "sum(last_2d):sum:neo4j_cluster_backup.backup_attempt{environment:${var.environment}}.as_count() + sum:neo4j_cluster_backup.backup_success{environment:${var.environment}}.as_count() < 1.7"

  monitor_thresholds {
    ok                = 2
    warning           = 1.8
    warning_recovery  = 1.9
    critical          = 1.7
    critical_recovery = 2
  }

  require_full_window = false
  notify_no_data      = true
  notify_audit        = false
  no_data_timeframe   = 1440
  renotify_interval   = 720
  include_tags        = true
  timeout_h           = 0

  tags = [
    "environment:${var.environment}",
    "service_name:${var.service_name}",
  ]
}

# KMS key for backups, both dbms and data backups
# manually extracted from neo4j 3.5 module
resource "aws_kms_key" "kms_key" {
  description             = "${var.environment}-${var.service_name}-backup"
  deletion_window_in_days = 14
  enable_key_rotation     = true

  tags = {
    environment  = var.environment
    service_name = var.service_name
    terraformed  = "true"
  }
}

resource "aws_kms_alias" "kms_alias" {
  name          = "alias/${var.environment}-${var.service_name}-orchard-backup"
  target_key_id = aws_kms_key.kms_key.key_id
}

resource "aws_kms_key_policy" "backup" {
  key_id = aws_kms_key.kms_key.key_id
  policy = data.aws_iam_policy_document.kms_key_policy_document.json
}

data "aws_iam_policy_document" "kms_key_policy_document" {
  # checkov:skip=CKV_AWS_109:It is a KMS key policy, so it applies only to a specific key.
  # checkov:skip=CKV_AWS_111:Same as above.
  statement {
    sid    = "Enable IAM User Permissions"
    effect = "Allow"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::437795906767:root"
      ]
    }

    actions = [
      "kms:*"
    ]
    resources = [
      "*"
    ]
  }

    statement {
    sid    = "DEV Neo4j refresh backup download access"
    effect = "Allow"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::103233932089:role/dev-neo4j-5-cluster-debian-asg-role",
      ]
    }

    actions = [
      "kms:Decrypt",
      "kms:DescribeKey",
    ]
    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "neo4j_kms_backup_policy" {
  name   = "${var.environment}-${var.service_name}-backup-policy"
  policy = data.aws_iam_policy_document.backup_kms_key_policy_document.json
}

data "aws_iam_policy_document" "backup_kms_key_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "kms:Encrypt",
      "kms:Decrypt",
      "kms:ReEncrypt*",
      "kms:GenerateDataKey*",
      "kms:DescribeKey"
    ]
    resources = [
      aws_kms_key.kms_key.arn
    ]
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "networking_route53_zone" {
  provider = aws.networking

  name = "theorchard.io"
}

module "neo4j_5_debian_environment" {
  source = "git@github.com:theorchard/terraform-neo4j-cluster.git//debian?ref=1.1.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                       = var.environment
  service_name                      = "${var.service_name_v5}-debian"
  vpc_id                            = module.vpc_info.vpc_id
  vpc_private_subnet_ids            = module.vpc_info.default_private_subnet_ids
  data_volume_device_name           = "/dev/sdb"
  data_volume_device_type           = "io2"
  data_volume_iops                  = 30000
  data_volume_size                  = 3000
  data_volume_throughput            = null
  desired_capacity                  = 0
  min_size                          = 0
  max_size                          = 0
  ssh_keypair_name                  = "orchard_admin"
  route53_zone_id                   = var.route53_hosted_zone
  dbms_backup_s3_bucket             = "prod-orcdbucket"
  data_volume_delete_on_termination = false
  aws_instance_type                 = "r6idn.8xlarge"
  user_data                         = module.chef_bootstrap_neo4j_debian.user_data_output

  bolt_ingress_cidr_blocks = [
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
  ]
}

module "chef_bootstrap_neo4j_debian" {
  source = "git@github.com:theorchard/terraform-chef-bootstrap.git//?ref=3.3.0"

  chef_role         = "prod_neo4j_5_debian_cluster"
  chef_environment  = var.environment
  aws_iam_role_id   = module.neo4j_5_debian_environment.instance_iam_role_name_output
  aws_instance_name = "${var.environment}-${var.service_name_v5}"
}

data "aws_iam_role" "cross_account_neo4j_dns_update_role" {
  provider = aws.networking

  name = "cross-account-neo4j-dns-update"
}

data "aws_iam_policy_document" "assume_cross_account_neo4j_dns_update_role_policy_document" {
  statement {
    effect    = "Allow"
    actions   = ["sts:AssumeRole"]
    resources = [data.aws_iam_role.cross_account_neo4j_dns_update_role.arn]
  }
}

resource "aws_iam_policy" "assume_cross_account_neo4j_dns_update_role_policy" {
  name        = "STS-${var.environment}-${var.service_name}-assume-role-policy"
  description = "Policy to allow the cross-account role to assume the Neo4j Debian cluster role for DNS updates"
  policy      = data.aws_iam_policy_document.assume_cross_account_neo4j_dns_update_role_policy_document.json
}

resource "aws_iam_role_policy_attachment" "qa_neo4j_debian_assume_role_policy" {
  role       = module.neo4j_5_debian_environment.instance_iam_role_name_output
  policy_arn = aws_iam_policy.assume_cross_account_neo4j_dns_update_role_policy.arn
}

resource "aws_route53_record" "prod_networking_route53_record" {
  provider = aws.networking

  name    = "prod-neo4j-cluster"
  zone_id = data.aws_route53_zone.networking_route53_zone.zone_id
  type    = "A"
  ttl     = 60
  # Record value itself is a placeholder
  records = [
    "10.100.47.84",
    "10.100.30.142",
    "10.100.31.161",
  ]

  # Allow DNS record updates via lifecycle hooks without Terraform trying to change things.
  lifecycle {
    ignore_changes = [
      records
    ]
  }
}

resource "aws_route53_record" "production_networking_route53_record" {
  provider = aws.networking

  name    = "${var.environment}-${var.service_name_v5}"
  zone_id = data.aws_route53_zone.networking_route53_zone.zone_id
  type    = "A"
  ttl     = 60
  # Record value itself is a placeholder
  records = [
    "10.100.13.186",
    "10.100.44.17",
    "10.100.47.27",
  ]

  # Allow DNS record updates via lifecycle hooks without Terraform trying to change things.
  lifecycle {
    ignore_changes = [
      records
    ]
  }
}

resource "aws_route53_record" "cluster_discovery_networking" {
  provider = aws.networking

  name    = "${var.environment}-${var.service_name_v5}-discovery"
  zone_id = data.aws_route53_zone.networking_route53_zone.zone_id
  type    = "A"
  ttl     = 60
  records = [
    "10.100.13.186",
    "10.100.44.17",
    "10.100.47.27",
  ]

  # Allow DNS record updates via lifecycle hooks without Terraform trying to change things.
  lifecycle {
    ignore_changes = [
      records
    ]
  }
}

# Allow permissions-platform AWS PROD access
# Get the ec2 prefix list for permissions-platform-prod AWS account
data "aws_ec2_managed_prefix_list" "permissions_platform_prod" {
  name = "${var.environment}-permissions-platform-private-subnet-prefix-list"
}

data "aws_ec2_managed_prefix_list" "vpn_sme_internal_primary" {
  name = "vpn-sme-internal-primary"
}

resource "aws_security_group_rule" "allow_permissions_platform_prod_deb" {
  type              = "ingress"
  from_port         = 7687
  to_port           = 7687
  protocol          = "TCP"
  security_group_id = module.neo4j_5_debian_environment.instance_security_group_id_output
  prefix_list_ids = [
    data.aws_ec2_managed_prefix_list.permissions_platform_prod.id,
    data.aws_ec2_managed_prefix_list.vpn_sme_internal_primary.id,
  ]
  depends_on = [module.neo4j_5_debian_environment]
}

resource "aws_security_group_rule" "allow_backup_host" {
  type                     = "ingress"
  from_port                = 6362
  to_port                  = 6362
  protocol                 = "TCP"
  security_group_id        = module.neo4j_5_debian_environment.instance_security_group_id_output
  source_security_group_id = data.aws_security_group.backup_host.id
  depends_on               = [module.neo4j_5_debian_environment]
}


module "neo4j_user" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.neo4j_user_secrets_manager)

  environment        = var.environment
  service_name       = var.service_name_v5
  secret_name        = each.value
  application_family = var.application_family
}

resource "aws_iam_policy" "neo4j_s3_readonly_backup_policy" {
  name   = "${var.environment}-${var.service_name}-s3-readonly-backup-policy"
  policy = data.aws_iam_policy_document.s3_backup_read_only_policy.json
}

data "aws_iam_policy_document" "s3_backup_read_only_policy" {
  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject"
    ]

    resources = [
      "arn:aws:s3:::prod-orcdbucket/backup/neo4j/*"
    ]
  }

  statement {
    actions = [
      "s3:ListBucket"
    ]

    resources = ["arn:aws:s3:::prod-orcdbucket"]

    condition {
      test     = "StringLike"
      values   = ["backup/neo4j/*"]
      variable = "s3:prefix"
    }
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListAllMyBuckets"
    ]

    resources = [
      "*"
    ]
  }
}

import {
  id = "arn:aws:iam::437795906767:policy/prod-neo4j-cluster-s3-readonly-backup-policy"
  to = aws_iam_policy.neo4j_s3_readonly_backup_policy
}