provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/nickelback/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.10.3"

  env                = var.environment
  bucket_name        = var.bucket_name
  custom_bucket_name = var.bucket_name
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_noncurrent_version_transition = [
    {
      prefix        = "cucumber-configs"
      enabled       = true
      days          = 60
      storage_class = "STANDARD_IA"
    }
  ]

  apply_replication_configuration = [{
    prefix                            = ""
    destination_bucket                = "smashmouth"
    storage_class                     = "INTELLIGENT_TIERING"
    enabled                           = true
    delete_marker_replication_enabled = true
    replicate_kms_encrypted_objects   = true
    replica_kms_key_arn               = var.replica_kms_key_arn
    source_kms_key_arns               = var.source_kms_key_arns
  }]

  storage_lens_configuration = {
    enabled = true
  }
}

data "aws_lambda_function" "datadog_s3_event_forwarder" {
  function_name = "${var.environment}-lambda-datadog-s3-event-forwarder"
}

resource "aws_s3_bucket_notification" "event_notification_configuration" {
  bucket = module.s3_bucket.s3_bucket_name_output

  lambda_function {
    lambda_function_arn = data.aws_lambda_function.datadog_s3_event_forwarder.arn
    events              = ["s3:Replication:OperationFailedReplication"]
  }
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/s3?ref=6.10.2"

  environment                       = var.environment
  service_name                      = var.bucket_name
  bucket_name                       = var.bucket_name
  application_family                = var.application_family
  teams                             = ["devops"]
  notification_endpoints            = "@slack-backup-alerts"
  escalation_notification_endpoints = "@slack-backup-alerts"

  dashboard_configuration = {
    enabled                       = true
    show_advanced_storage_metrics = true
    show_replication_metrics      = true
    show_activity_metrics         = true
  }
  replication_failures_monitor_configuration = {
    enabled = true
  }
  replication_latency_monitor_configuration = {
    enabled = true
  }
}