module "default_tags" {
  # checkov:skip=ORCD_AWS_2: Avoid using old terraform module versions that are non Checkov compliant
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/orcd-cdn/us-east-1/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_canonical_user_id" "current" {}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = false
}

data "aws_route53_zone" "domain_networking" {
  provider     = aws.networking

  name         = var.domain_name
  private_zone = false
}

data "aws_acm_certificate" "certificate" {
  domain   = "*.${data.aws_route53_zone.domain.name}"
  statuses = ["ISSUED"]
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-orcd-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

data "aws_iam_role" "s3_replication_role" {
  name = "${var.environment}-${var.service_name}-${var.environment}-${var.service_name}-us-west01-s3-repl-role"
}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.14.1"

  env                 = var.environment
  bucket_name         = var.service_name
  application_family  = "cdn"
  s3_read_only_policy = false
  block_public_access = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

   bucket_policy_overrides = [
    data.aws_iam_policy_document.cdn_s3_policy_document.json,
  ]

  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["GET"]
      allowed_origins = ["*"]
      expose_headers  = []
      max_age_seconds = 3000
    },
  ]

  apply_replication_configuration = [
    {
      prefix             = ""
      enabled            = true
      delete_marker_replication_enabled = false
      destination_bucket = "${var.environment}-${var.service_name}-us-west01"
      storage_class      = "STANDARD"
      role               = data.aws_iam_role.s3_replication_role.arn
    }
  ]

  lifecycle_rules_options_noncurrent_version_transition = [
    {
      prefix = "frontend-podcast/"
      enabled = true
      days = 180
      storage_class = "DEEP_ARCHIVE"
    }
  ]

  lifecycle_rules_options_current_version_transition = [
    {
      prefix = "frontend-podcast/"
      enabled = true
      days = 180
      storage_class = "DEEP_ARCHIVE"
    }
  ]
}

resource "aws_cloudfront_origin_access_identity" "cdn_origin_access_identity" {
  comment = "access-identity-prod-orcd-cdn.s3.amazonaws.com"
}

data "aws_ec2_managed_prefix_list" "route53_health_check" {
  name           = "com.amazonaws.${var.aws_region}.route53-healthchecks"
}


data "aws_iam_policy_document" "cdn_s3_policy_document" {
  # CDN Origin Access Identity
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      module.s3_bucket.s3_bucket_arn_output,
      "${module.s3_bucket.s3_bucket_arn_output}/*",
    ]

    principals {
      type        = "AWS"
      identifiers = [aws_cloudfront_origin_access_identity.cdn_origin_access_identity.iam_arn]
    }
  }

  # frontend-content
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-content/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_content_origin_access_identity_arns
    }
  }

  # frontend-publishing
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-publishing/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_publishing_origin_access_identity_arns
    }
  }

  # frontend-documents
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-documents/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_documents_origin_access_identity_arns
    }
  }

  # frontend-settings
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-settings/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_settings_origin_access_identity_arns
    }
  }

  # frontend-collaborator-suite
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-collaborator-suite/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_collaborator-suite_origin_access_identity_arns
    }
  }

  # frontend-insights
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-insights/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_insights_origin_access_identity_arns
    }
  }

  # frontend-royalties
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-royalties/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_royalties_origin_access_identity_arns
    }
  }

  # frontend-moneyhub
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-moneyhub/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_moneyhub_origin_access_identity_arns
    }
  }

  # frontend-solfege
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-solfege/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_solfege_origin_access_identity_arns
    }
  }

  # frontend-workstation
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-workstation/*",
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-workstation-dev/*", # Temporary until WIZ-496 is fully implemented
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_workstation_origin_access_identity_arns
    }
  }

  # frontend-audience-development
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-audience-development/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_audience_development_origin_access_identity_arns
    }
  }

  # frontend-distribution-suite
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-distribution-suite/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_distribution_suite_origin_access_identity_arns
    }
  }

  # frontend-account360
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-account360/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_account360_origin_access_identity_arns
    }
  }

  # frontend-songwhip
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-songwhip/*",
    ]

    principals {
      type        = "AWS"
      identifiers = [data.aws_cloudfront_origin_access_identity.frontend_songwhip_origin_access_identity.iam_arn]
    }
  }

  # route53 health check for robots.txt
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/robots.txt",
    ]

    principals {
      identifiers = ["*"]
      type = "*"
    }

    condition {
      test     = "IpAddress"
      values = [for entry in data.aws_ec2_managed_prefix_list.route53_health_check.entries : entry.cidr]
      variable = "aws:SourceIp"
    }
  }
}

resource "aws_cloudfront_distribution" "distribution" {
  # checkov:skip=CKV2_AWS_32:Cloudfront Distribution strict security headers policy
  # checkov:skip=ORCD_AWS_3:Cloudfront Distribution response headers policy
  # checkov:skip=CKV2_AWS_47:Cloudfront Distribution response headers policy
  # checkov:skip=CKV_AWS_305:Cloudfront Distribution default root object config
  # checkov:skip=CKV_AWS_310:Cloudfront Distribution origin failover config
  # checkov:skip=CKV_AWS_374:Ensure AWS CloudFront web distribution has geo restriction enabled

  aliases = [
    "cdn.${var.domain_name}",
    "cdn-east01.${var.domain_name}",
  ]
  comment         = "${var.environment}-${var.service_name}"
  enabled         = true
  is_ipv6_enabled = true
  http_version    = "http2"
  price_class     = "PriceClass_All"
  web_acl_id      = data.aws_wafv2_web_acl.waf.arn

  origin {
    domain_name = module.s3_bucket.s3_bucket_domain_name_output
    origin_id   = "S3-${var.environment}-orcd-cdn"

    s3_origin_config {
      origin_access_identity = aws_cloudfront_origin_access_identity.cdn_origin_access_identity.cloudfront_access_identity_path
    }
  }

  ordered_cache_behavior {
    path_pattern     = "frontend-distribution/*"
    allowed_methods  = ["GET", "HEAD", "OPTIONS"]
    cached_methods   = ["GET", "HEAD"]
    target_origin_id = "S3-${var.environment}-orcd-cdn"

    forwarded_values {
      query_string = false

      cookies {
        forward = "none"
      }
    }

    min_ttl                = 0
    default_ttl            = 86400
    max_ttl                = 31536000
    compress               = false
    viewer_protocol_policy = "redirect-to-https"
  }

  ordered_cache_behavior {
    path_pattern     = "frontend-homepage/dml.json"
    allowed_methods  = var.allowed_methods
    cached_methods   = var.cached_methods
    target_origin_id = "S3-${var.environment}-orcd-cdn"

    forwarded_values {
      query_string = false

      cookies {
        forward = "none"
      }
    }

    min_ttl                = 0
    default_ttl            = 1
    max_ttl                = 1
    compress               = false
    viewer_protocol_policy = "redirect-to-https"
  }

  default_cache_behavior {
    allowed_methods        = var.allowed_methods
    cached_methods         = var.cached_methods
    default_ttl            = var.default_ttl
    min_ttl                = 0
    max_ttl                = 31536000
    compress               = true
    target_origin_id       = "S3-${var.environment}-orcd-cdn"
    viewer_protocol_policy = "redirect-to-https"

    forwarded_values {
      query_string = false
      headers = [
        "Origin",
        "Access-Control-Request-Method",
        "Access-Control-Request-Headers",
      ]

      cookies {
        forward = "none"
      }
    }
  }

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  viewer_certificate {
    acm_certificate_arn      = data.aws_acm_certificate.certificate.arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = var.cloudfront_minimum_protocol_version
  }

  logging_config {
    include_cookies = true
    bucket          = var.cloudfront_logging_bucket
  }

  tags = {
    environment  = var.environment
    service_name = var.service_name
    terraformed  = true
  }
}

resource "aws_route53_record" "route53_record" {
  name    = "cdn-east01"
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.distribution.domain_name]
}

resource "aws_route53_record" "route53_record_networking" {
  provider = aws.networking

  name    = "cdn-east01"
  zone_id = data.aws_route53_zone.domain_networking.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.distribution.domain_name]
}

resource "aws_route53_health_check" "cdn_route53_record" {
  fqdn               = module.s3_bucket.s3_bucket_domain_name_output
  port               = 443
  type               = "HTTPS"
  resource_path      = "/robots.txt"
  failure_threshold  = "3"
  request_interval   = "30"
  enable_sni         = true
  measure_latency    = false
  invert_healthcheck = false
  regions = [
    "ap-northeast-1",
    "ap-southeast-1",
    "ap-southeast-2",
    "eu-west-1",
    "sa-east-1",
    "us-east-1",
    "us-west-1",
    "us-west-2"
  ]

  tags = {
    Name = "cdn-east01-healthcheck"
  }
}

resource "aws_route53_record" "cdn_route53_record" {
  name            = "cdn"
  zone_id         = data.aws_route53_zone.domain.zone_id
  type            = "CNAME"
  ttl             = "60"
  set_identifier  = "cdn-Primary"
  records         = [aws_route53_record.route53_record.fqdn]
  health_check_id = aws_route53_health_check.cdn_route53_record.id

  failover_routing_policy {
    type = "PRIMARY"
  }
}

resource "aws_route53_health_check" "cdn_route53_record_networking" {
  provider = aws.networking

  fqdn               = module.s3_bucket.s3_bucket_domain_name_output
  port               = 443
  type               = "HTTPS"
  resource_path      = "/robots.txt"
  failure_threshold  = "3"
  request_interval   = "30"
  enable_sni         = true
  measure_latency    = false
  invert_healthcheck = false
  regions = [
    "ap-northeast-1",
    "ap-southeast-1",
    "ap-southeast-2",
    "eu-west-1",
    "sa-east-1",
    "us-east-1",
    "us-west-1",
    "us-west-2"
  ]

  tags = {
    Name = "cdn-east01-healthcheck"
  }
}

resource "aws_route53_record" "cdn_route53_record_networking" {
  provider = aws.networking

  name            = "cdn"
  zone_id         = data.aws_route53_zone.domain_networking.zone_id
  type            = "CNAME"
  ttl             = "60"
  set_identifier  = "cdn-Primary"
  records         = [aws_route53_record.route53_record_networking.fqdn]
  health_check_id = aws_route53_health_check.cdn_route53_record_networking.id

  failover_routing_policy {
    type = "PRIMARY"
  }
}