provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/orcd-mezzanine-assets/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

# Note: the module can create a policy
module "orcd_mezzanine_assets_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.10.3"

  env                             = var.environment
  bucket_name                     = var.service_name
  s3_custom_read_only_policy_name = "S3-prod-orcd-mezzanine-assets-RO"
  application_family              = var.application_family

  lifecycle_rules_options_current_version_transition = [
    {
      prefix        = ""
      enabled       = true
      days          = 0
      storage_class = "INTELLIGENT_TIERING"
    }
  ]

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  apply_replication_configuration = [{
    prefix                            = ""
    destination_bucket                = "${var.environment}-${var.service_name}-replica"
    storage_class                     = "GLACIER_IR"
    enabled                           = true
    delete_marker_replication_enabled = false
    replication_time_control_enabled  = true
  }]

  storage_lens_configuration = {
    enabled = true
  }
}

data "aws_lambda_function" "datadog_s3_event_forwarder" {
  function_name = "${var.environment}-lambda-datadog-s3-event-forwarder"
}

resource "aws_s3_bucket_notification" "event_notification_configuration" {
  bucket = module.orcd_mezzanine_assets_bucket.s3_bucket_name_output

  lambda_function {
    lambda_function_arn = data.aws_lambda_function.datadog_s3_event_forwarder.arn
    events              = ["s3:Replication:OperationFailedReplication"]
  }
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/s3?ref=6.10.5"

  environment                       = var.environment
  service_name                      = var.service_name
  application_family                = var.application_family
  teams                             = ["devops"]
  notification_endpoints            = "@slack-backup-alerts"
  escalation_notification_endpoints = "@slack-backup-alerts"

  dashboard_configuration = {
    enabled                       = true
    show_advanced_storage_metrics = true
    show_replication_metrics      = true
    show_activity_metrics         = true
  }
  replication_failures_monitor_configuration = {
    enabled = true
  }
  replication_latency_monitor_configuration = {
    enabled = true
  }
}