module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/orcd-public/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_cloudfront_origin_access_identity" "orcd_advertising_cloudfront_distribution" {
  id = "E3VIL3SVFA00VY"
}

data "aws_acm_certificate" "certificate" {
  domain   = "*.${var.domain_name}"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = false
}

data "aws_route53_zone" "domain_networking" {
  provider     = aws.networking
  name         = var.domain_name
  private_zone = false
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-orcd-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.13.0"

  env                 = var.environment
  bucket_name         = "orcd-public"
  custom_bucket_name  = "orcd-public"
  application_family  = var.application_family
  s3_read_only_policy = false
  block_public_access = true
  bucket_policy_overrides = [
    data.aws_iam_policy_document.bucket_policy_document.json,
  ]

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

data "aws_iam_policy_document" "bucket_policy_document" {
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/*",
    ]

    principals {
      type = "AWS"
      identifiers = [
        data.aws_cloudfront_origin_access_identity.orcd_advertising_cloudfront_distribution.iam_arn,
        aws_cloudfront_origin_access_identity.origin_access_identity_primary.iam_arn,
      ]
    }
  }
}

resource "aws_cloudfront_origin_access_identity" "origin_access_identity_primary" {
  comment = "${var.environment}-${var.service_name}-primary-origin-access-identity"
}

resource "aws_cloudfront_distribution" "distribution" {
  # checkov:skip=CKV_AWS_310: Ensure CloudFront distributions should have origin failover configured
  # checkov:skip=CKV_AWS_374: Ensure AWS CloudFront web distribution has geo restriction enabled

  aliases             = ["${var.service_name}.${var.domain_name}"]
  comment             = "${var.environment}-${var.service_name}"
  enabled             = true
  is_ipv6_enabled     = true
  http_version        = "http2"
  price_class         = "PriceClass_All"
  web_acl_id          = data.aws_wafv2_web_acl.waf.arn
  default_root_object = "index.html"

  origin {
    connection_attempts = 3
    connection_timeout  = 10
    domain_name         = module.s3_bucket.s3_bucket_domain_name_output
    origin_id           = var.service_name

    s3_origin_config {
      origin_access_identity = aws_cloudfront_origin_access_identity.origin_access_identity_primary.cloudfront_access_identity_path
    }
  }

  custom_error_response {
    error_caching_min_ttl = 300
    error_code            = 403
    response_code         = 403
    response_page_path    = "/403.png"
  }

  default_cache_behavior {
    allowed_methods            = var.allowed_methods
    cached_methods             = var.cached_methods
    default_ttl                = var.default_ttl
    min_ttl                    = 0
    max_ttl                    = 31536000
    compress                   = true
    target_origin_id           = var.service_name
    viewer_protocol_policy     = "redirect-to-https"
    response_headers_policy_id = aws_cloudfront_response_headers_policy.response_headers_policy.id

    forwarded_values {
      query_string = false

      cookies {
        forward = "none"
      }
    }
  }

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  viewer_certificate {
    acm_certificate_arn      = data.aws_acm_certificate.certificate.arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = var.cloudfront_minimum_protocol_version
  }

  logging_config {
    include_cookies = true
    bucket          = var.cloudfront_logging_bucket
    prefix          = "${var.environment}-${var.service_name}"
  }

  tags = {
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = true
    application_family = var.application_family
  }
}

resource "aws_cloudfront_response_headers_policy" "response_headers_policy" {
  name    = "${var.environment}-${var.service_name}"
  comment = "${var.environment}-${var.service_name}"

  security_headers_config {
    content_type_options {
      override = true
    }

    frame_options {
      frame_option = "DENY"
      override     = true
    }

    referrer_policy {
      referrer_policy = "strict-origin-when-cross-origin"
      override        = true
    }

    strict_transport_security {
      access_control_max_age_sec = 365 * 24 * 60 * 60
      override                   = true
    }

    xss_protection {
      protection = true
      mode_block = true
      override   = true
    }
  }
}

resource "aws_route53_record" "route53_record" {
  name    = var.service_name
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.distribution.domain_name]
}

resource "aws_route53_record" "route53_record_networking" {
  provider = aws.networking

  name    = var.service_name
  zone_id = data.aws_route53_zone.domain_networking.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.distribution.domain_name]
}