module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/orcd-sftp/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_route53_zone" "networking_route53_zone" {
  provider = aws.networking

  name = "theorchard.io"
}

module "aws_transfer_family" {
  # checkov:skip=CKV_AWS_380: Ensure AWS Transfer Server uses latest Security Policy.
  source                                            = "git@github.com:theorchard/terraform-aws-transfer-family.git//?ref=1.0.1"
  service_name                                      = var.service_name
  environment                                       = var.environment
  aws_transfer_server_api_gateway_lambda_arn        = module.lambda_aws_ftp.lambda_arn
  aws_transfer_server_api_gateway_lambda_invoke_arn = module.lambda_aws_ftp.lambda_invoke_arn
  vpc_id                                            = data.aws_vpc.vpc.id
  block_waf_enabled                                 = true
}

module "lambda_aws_ftp" {
  source                   = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.3"
  application_family       = var.application_family
  environment              = var.environment
  lambda_name              = var.service_name
  lambda_description       = "A function to lookup and return user data from AWS Secrets Manager."
  lambda_function_handler  = "index.lambda_handler"
  lambda_runtime           = "python3.10"
  vpc_enabled              = true
  vpc_id                   = data.aws_vpc.vpc.id
  vpc_subnet_ids           = data.aws_subnets.private_subnets.ids
  datadog_advanced_enabled = false

  lambda_function_environment_variables = {
    ENVIRONMENT            = var.environment
    SERVICE_NAME           = var.service_name
    SECRETS_MANAGER_REGION = var.aws_region
  }
}

data "aws_vpc" "vpc" {
  tags = {
    Name = var.environment
  }
}

data "aws_subnets" "private_subnets" {
  filter {
    name   = "vpc-id"
    values = [data.aws_vpc.vpc.id]
  }

  tags = {
    Name = "prod_private_subnet_*"
    tier = "private"
  }
}

resource "aws_route53_record" "sftp_cname_record" {
  name    = "ftp.${data.aws_route53_zone.route53_zone.name}"
  type    = "CNAME"
  zone_id = data.aws_route53_zone.route53_zone.zone_id
  ttl     = "300"
  records = [module.aws_transfer_family.aws_transfer_server_endpoint_output]
}

resource "aws_route53_record" "sftp_cname_networking_record" {
  provider = aws.networking

  name    = "ftp.${data.aws_route53_zone.networking_route53_zone.name}"
  type    = "CNAME"
  zone_id = data.aws_route53_zone.networking_route53_zone.zone_id
  ttl     = "300"
  records = [module.aws_transfer_family.aws_transfer_server_endpoint_output]
}