provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/orcd-tax-id-export/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.1.3"

  env                = var.environment
  bucket_name        = var.service_name
  application_family = var.application_family

  kms_key_enabled  = true
  kms_key_name     = var.kms_key_name
  kms_key_required = true

  s3_read_only_policy = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "aws:kms"
  }
}

data "aws_iam_policy_document" "tax_id_export_kms_policy_document" {
  statement {
    actions = [
      "kms:Decrypt",
      "kms:Encrypt",
      "kms:ReEncrypt*",
      "kms:GenerateDataKey*",
      "kms:DescribeKey",
    ]

    resources = [
      module.s3_bucket.s3_kms_encryption_key_arn_output,
    ]
  }

  statement {
    actions = [
      "kms:ListKeys",
      "kms:GenerateRandom",
      "kms:ListAliases",
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "tax_id_export_kms_policy" {
  name   = "KMS-${var.environment}-tax-id-export-policy"
  policy = data.aws_iam_policy_document.tax_id_export_kms_policy_document.json
}

data "aws_iam_policy_document" "tax_id_export_s3_policy_document" {
  statement {
    actions = [
      "s3:DeleteObject",
      "s3:GetObject",
      "s3:PutObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/*"
    ]
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListAllMyBuckets",
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "tax_id_export_s3_policy" {
  name   = "S3-${var.environment}-orcd-tax-id-export-RW"
  policy = data.aws_iam_policy_document.tax_id_export_s3_policy_document.json
}