data "aws_iam_policy_document" "s3-bucket-policy-document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject"
    ]
    resources = [
      "arn:aws:s3:::${var.s3_bucket}/${var.s3_location}",
    ]
  }
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

resource "aws_iam_policy" "s3-bucket-policy" {
  name              = "S3-${var.environment}-${var.service_name}-RW"
  policy            = data.aws_iam_policy_document.s3-bucket-policy-document.json
}

# Jenkins agents will assume this role in order to access S3 bucket
resource "aws_iam_role" "assume_jenkins_role" {
  name               = "${var.environment}-${var.service_name}-jenkins-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach S3 RW policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "assume_jenkins_role_attachment" {
  role               = aws_iam_role.assume_jenkins_role.id
  policy_arn         = aws_iam_policy.s3-bucket-policy.arn
}