module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/orchardgo/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}

resource "aws_iam_user" "jenkins_mac_mini_agent_user" {
  name = "jenkins-mac-mini-agent"

  tags = {
    role = "service-user"
  }
}

data "aws_iam_policy_document" "jenkins_mac_mini_agent_assume_role_policy" {
  version = "2012-10-17"
  statement {
    effect = "Allow"
    actions = [
      "sts:AssumeRole"
    ]
    resources = [
      "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/jenkins-mac-mini-agent"
    ]
  }
}

resource "aws_iam_user_policy" "jenkins_mac_mini_agent_policy" {
  policy = data.aws_iam_policy_document.jenkins_mac_mini_agent_assume_role_policy.json
  user   = aws_iam_user.jenkins_mac_mini_agent_user.name
}

data "aws_iam_policy_document" "jenkins_mac_mini_agent_role_assume_policy" {
  version = "2012-10-17"
  statement {
    effect = "Allow"
    actions = [
      "sts:AssumeRole"
    ]
    principals {
      type        = "AWS"
      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:user/jenkins-mac-mini-agent"
      ]
    }
  }
}

resource "aws_iam_role" "jenkins_mac_mini_agent_role" {
  name               = "jenkins-mac-mini-agent"
  assume_role_policy = data.aws_iam_policy_document.jenkins_mac_mini_agent_role_assume_policy.json
}

module "secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.3.0"

  secrets      = [for secret in module.secrets : secret.secret_name]
  action_types = ["read"]

  depends_on = [module.secrets]
}

resource "aws_iam_role_policy" "secrets_manager_policy" {
  policy = module.secrets_manager_policy.policy.json
  role   = aws_iam_role.jenkins_mac_mini_agent_role.id
}