module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-account/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_caller_identity" "current" {}

module "ows_service_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name   = var.environment
  service_name       = var.service_name
  policy_description = "A policy to access dynamo owsrequest table"
}


data "aws_iam_policy_document" "secretsmanager_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetSecretValue"
    ]
    resources = [
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:prod/python-orchard-features/*",
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:prod/python-orchard-features/"
    ]
  }
}

resource "aws_iam_policy" "secretsmanager_policy" {
  name   = "${var.environment}-secretsmanager-ows-account-policy"
  policy = data.aws_iam_policy_document.secretsmanager_policy_document.json
}


module "ows_account_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.3"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  commit_sha         = "latest"
  container_port     = "8080"
  task_type          = "web_service"
  desired_task_count = 10
  task_cpu           = 2048
  task_memory        = 4096
  maximum_capacity   = 20
  minimum_capacity   = 3

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  application_family            = var.application_family
  # overriding here to add in the graphql_switchboard_vpc (10.110.0.0/16) private subnets
  prod_https_listener_allow_cidr_blocks = [
    "192.168.31.0/24",
    "10.40.0.0/22",
    "10.10.40.0/22",
    "10.120.0.0/24",
    "10.120.1.0/24",
  ]

  iam_managed_policy_attachments = [
    "arn:aws:iam::aws:policy/CloudWatchFullAccess",
    "arn:aws:iam::aws:policy/AmazonS3ReadOnlyAccess",
    module.ows_service_owsrequest.policy_arn_output,
    aws_iam_policy.secretsmanager_policy.arn,

  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      SENTRY_DSN = var.SENTRY_DSN
    },
    {
      KAFKA_BOOTSTRAP_SERVERS = var.kafka_bootstrap_servers
    },
    {
      KAFKA_OWS_ACCOUNT_ACCOUNTS_TOPIC = var.kafka_ows_account_accounts_topic
    },
    {
      KAFKA_OWS_ACCOUNT_SUBACCOUNTS_TOPIC = var.kafka_ows_account_subaccounts_topic
    },
    {
      KAFKA_SECURITY_PROTOCOL = var.kafka_security_protocol
    },
    {
      SPLITIO_USE_PREFORKED_INITIALIZATION = var.splitio_preforked
    },
    {
      NEO4J_URL = "neo4j+s://prod-neo4j-cluster.theorchard.io:7687"
    },
    {
      NEO4J_AURA_URL = "neo4j+s://prod-neo4j-cluster.theorchard.io:7687"
    },
    {
      NEO4J_USERNAME = "ows-account"
    },
    {
      NEO4J_AURA_USERNAME = "ows-account"
    }
  ]
  secrets = [
    {
      DB_URL = "${var.environment}/${var.service_name}/DB_URL"
    },
    {
      NEO4J_PASSWORD = "${var.environment}/${var.service_name}/NEO4J_PASSWORD"
    },
    {
      NEO4J_AURA_PASSWORD = "${var.environment}/${var.service_name}/NEO4J_AURA_PASSWORD"
    }
  ]
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.1"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  service_4xx_monitor_enabled       = false
  application_family                = var.application_family
  critical_number_5xx               = var.critical_number_5xx
  critical_recovery_number_5xx      = var.critical_recovery_number_5xx
  warning_number_5xx                = var.warning_number_5xx
  warning_recovery_number_5xx       = var.warning_recovery_number_5xx
  notification_endpoints            = var.application_alert_channel
  escalation_notification_endpoints = var.application_alert_channel
  additional_tags                   = { service_type : "critical" }
  teams                             = [var.application_family]
  dependent_applications            = var.dependent_applications
}


# Get the ec2 prefix list for permissions-platform-prod AWS account
data "aws_ec2_managed_prefix_list" "permissions_platform_prod" {
  name = "${var.environment}-permissions-platform-private-subnet-prefix-list"
}

# Allow prod-ows-pdp (which is in permissions-platform-prod AWS account)
# interact with prod-ows-account
resource "aws_security_group_rule" "allow_permissions_platform_prod" {
  type              = "ingress"
  from_port         = 443
  to_port           = 443
  protocol          = "TCP"
  security_group_id = module.ows_account_fargate_environment.fargate_load_balancer_security_group_id
  prefix_list_ids = [
    data.aws_ec2_managed_prefix_list.permissions_platform_prod.id
  ]
  depends_on = [module.ows_account_fargate_environment]
}


data "aws_ec2_managed_prefix_list" "fansifter_prefix_list" {
  name = "${var.environment}-fansifter-private-subnet-prefix-list"
}

# Allow services in fansifter-prod AWS account
# interact with prod-ows-account
resource "aws_security_group_rule" "allow_fansifter_ingress" {
  type              = "ingress"
  from_port         = 443
  to_port           = 443
  protocol          = "TCP"
  security_group_id = module.ows_account_fargate_environment.fargate_load_balancer_security_group_id
  prefix_list_ids = [
    data.aws_ec2_managed_prefix_list.fansifter_prefix_list.id
  ]
}