module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-accounting/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "ows_accounting_owsrequest" {
  source           = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"
  environment_name = var.environment
  service_name     = var.service_name
}

module "ows_accounting_fargate_environment" {
  # checkov:skip=CKV2_AWS_76:Ensure AWS ALB attached WAFv2 WebACL is configured with AMR for Log4j Vulnerability
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                   = var.environment
  service_name                  = var.service_name
  aws_region                    = var.aws_region
  commit_sha                    = "latest"
  container_port                = "8080"
  task_type                     = "web_service"
  desired_task_count            = 2
  task_cpu                      = 512
  task_memory                   = 1024
  maximum_capacity              = 4
  minimum_capacity              = 2
  route53_zone_id               = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  application_family            = var.application_family

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/S3-prod-orcdbucket_prod-statement-attachments-RW",
    "arn:aws:iam::437795906767:policy/S3-prod-statement-detail-exports-RW",
    "arn:aws:iam::437795906767:policy/S3-prod-orcdbucket-prod-per-label-statement-attachments-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-prod_accounting_statement_export-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-ows-accounting-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-prod_statement_attachments_success-RW",
    "arn:aws:iam::437795906767:policy/SWF-fullaccess",
    "arn:aws:iam::437795906767:policy/s3-cucumbers-bulk-payment-holds-RW"
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      AWS_DEFAULT_REGION = "us-east-1"
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      ACCOUNTING_STATEMENT_EXPORT_TABLE = "prod_accounting_statement_export"
    },
    {
      ACTIVE_ACCOUNTING_PERIOD = "317"
    },
    {
      MYSQL_DATABASE = "art_relations"
    },
    {
      MYSQL_HOST = "ar-db.theorchard.com"
    },
    {
      MYSQL_USER = "ows-accounting"
    },
    {
      REDIS_HOST = module.ows_accounting_elasticache.redis_primary_endpoint_address
    },
    {
      REDIS_PORT = "6379"
    },
    {
      SNOWFLAKE_ACCOUNT = "delphi.us-east-1"
    },
    {
      SNOWFLAKE_DATABASE = "facts"
    },
    {
      SNOWFLAKE_ROLE = "prod_ows_accounting"
    },
    {
      SNOWFLAKE_SCHEMA = "prod",
    },
    {
      SNOWFLAKE_USER = "prod_ows_accounting"
    },
    {
      SNOWFLAKE_WAREHOUSE = "prod_ows_warehouse"
    }
  ]
  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      SNOWFLAKE_PASSWORD = "${var.environment}/${var.service_name}/SNOWFLAKE_PASSWORD"
    },
    {
      PAYMENT_HOLDS_DB_URL = "${var.environment}/${var.service_name}/PAYMENT_HOLDS_DB_URL"
    },
    {
      MYSQL_PASSWORD = "${var.environment}/${var.service_name}/MYSQL_PASSWORD"
    }
  ]
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  service_4xx_monitor_enabled       = false
  application_family                = var.application_family
  critical_number_5xx               = var.critical_number_5xx
  critical_recovery_number_5xx      = var.critical_recovery_number_5xx
  warning_number_5xx                = var.warning_number_5xx
  warning_recovery_number_5xx       = var.warning_recovery_number_5xx
  notification_endpoints            = var.application_alert_channel
  escalation_notification_endpoints = var.application_alert_channel
  additional_tags                   = { service_type = "critical" }
  dependent_applications            = var.dependent_applications
}

module "ows_accounting_elasticache" {
  # checkov:skip=CKV_AWS_30:ElastiCache encryption in transit requires client library update.
  # checkov:skip=CKV_AWS_31:ElastiCache encryption in transit requires client library update.
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                      = var.environment
  service_name                     = var.service_name
  application_family               = var.application_family
  cache_engine                     = "redis"
  cache_subnet_group_name          = "${var.environment}-elasticache-subnet-group"
  cache_transit_encryption_enabled = false
  cache_node_type                  = "cache.t4g.small"
  cache_parameter_group_name       = "default.redis5.0"
  redis_engine_version             = "5.0.6"
  vpc_id                           = module.vpc_info.vpc_id
  route53_zone_id                  = data.aws_route53_zone.route53_zone.zone_id
  redis_snapshot_window            = "08:30-09:30"
  cache_maintenance_window         = "wed:06:00-wed:07:00"
}

module "ows_accounting_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=6.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  rds_master_username = "ows_accounting_admin"
  rds_master_password = "s0mePass!changme"

  rds_cluster_instance_class                = "db.t4g.medium"
  rds_cluster_instance_count                = "1"
  rds_db_cluster_parameter_group_name       = "aurora-mysql80sync"
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  rds_engine                                = "aurora-mysql"
  rds_engine_version                        = "8.0.mysql_aurora.3.10.3"
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_performance_insights_enabled          = true
  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]

  custom_kms_key_enabled = false

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.zone_id
}

module "datadog_ows_accounting_rds" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/rds?ref=6.13.4"

  environment                       = var.environment
  application_family                = var.application_family
  service_name                      = var.service_name
  notification_endpoints            = "@abacus-monitoring"
  escalation_notification_endpoints = "@slack-monitoring @abacus-monitoring"
}