module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = "us-east-1"
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-analytics/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "analytics_metadata_dynamodb_table" {
  source = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"

  env                    = var.environment
  application_family     = var.application_family
  table_name             = "analytics_metadata"
  range_key_enabled      = true
  write_capacity         = var.write_capacity
  read_capacity          = var.read_capacity
  min_read_capacity      = "5"
  max_read_capacity      = "40000"
  min_write_capacity     = "5"
  max_write_capacity     = "40000"
  hash_key               = var.hash_key
  range_key              = var.range_key
  range_type             = var.range_type
  attribute              = var.attributes
  global_secondary_index = var.secondary_indices
}

module "ows_legacy_analytics_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = "ows-legacy-analytics"
}

module "ows_analytics_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.service_name
}

data "aws_iam_policy_document" "additional_secrets_policy" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:ListSecretVersionIds",
      "secretsmanager:GetSecretValue",
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:DescribeSecret",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/python-orchard-features/*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/python-orchard-features/"
    ]
  }
}

resource "aws_iam_policy" "additional_secrets_policy" {
  name   = "SecretsManager-${var.environment}-ows-analytics-additional-secrets-policy"
  policy = data.aws_iam_policy_document.additional_secrets_policy.json
}

module "legacy_elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"
  # checkov:skip=CKV_AWS_30:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit
  # checkov:skip=CKV_AWS_31:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit and has auth token

  providers = {
    aws.dns = aws.networking
  }

  environment                      = var.environment
  service_name                     = "${var.service_name}-legacy"
  cache_engine                     = "redis"
  cache_subnet_group_name          = "prod-vpc-orchard-subnet"
  cache_node_type                  = "cache.t4g.medium"
  cache_parameter_group_name       = "default.redis6.x"
  redis_engine_version             = "6.x"
  redis_snapshot_window            = "03:00-05:00"
  cache_maintenance_window         = "sun:05:00-sun:09:00"
  vpc_id                           = module.vpc_info.vpc_id
  route53_zone_id                  = data.aws_route53_zone.route53_zone.zone_id
  application_family               = var.application_family
  cache_transit_encryption_enabled = false
  cache_node_count                 = 2
}

# Secrets manager entry for legacy analytics vanity FQDN
resource "aws_secretsmanager_secret" "legacy_fqdn_cache_secret" {
  name        = "${var.environment}/ows-legacy-analytics/REDIS_HOST"
  description = "FQDN for ows-legacy-analytics redis cache"
}
resource "aws_secretsmanager_secret_version" "legacy_fqdn_cache_secret" {
  secret_id     = aws_secretsmanager_secret.legacy_fqdn_cache_secret.id
  secret_string = module.legacy_elasticache.redis_primary_endpoint_address
}

# Old ows-analytics, now known as ows-legacy-analytics
module "ows_legacy_analytics_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                       = var.environment
  application_family                = var.application_family
  service_name                      = "ows-legacy-analytics"
  aws_region                        = var.region
  commit_sha                        = "latest"
  container_port                    = "8080"
  task_type                         = "web_service"
  desired_task_count                = 2
  task_cpu                          = 1024
  task_memory                       = 2048
  maximum_capacity                  = 4
  minimum_capacity                  = 2
  route53_zone_id                   = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                            = module.vpc_info.vpc_id
  https_listener_certificate_id     = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled             = false
  health_check_grace_period_seconds = 300
  container_start_period_seconds    = 300
  blocking_waf_enabled              = false

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-prod-ows-analytics-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-ows-legacy-analytics-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-streams_vendor_totals-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-stream-wildcard-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-stream-wildcard-RW",
    "arn:aws:iam::437795906767:policy/prod-aggregate-analytics",
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.environment}-ows-legacy-analytics"
    },
    {
      DD_LOGS_INJECTION = "true"
    }
  ]
  secrets = [
    { APPLE_MUSIC_PRIVATE_KEY = "${var.environment}/ows-legacy-analytics/APPLE_MUSIC_PRIVATE_KEY" }
  ]
}

# New ows-analytics (FKA bff-mobile)
module "ows_analytics_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                       = var.environment
  application_family                = var.application_family
  service_name                      = var.service_name
  aws_region                        = var.region
  commit_sha                        = "latest"
  container_port                    = "8080"
  task_type                         = "web_service"
  desired_task_count                = 5
  task_cpu                          = 4096
  task_memory                       = 8192
  maximum_capacity                  = 8
  minimum_capacity                  = 5
  route53_zone_id                   = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                            = module.vpc_info.vpc_id
  https_listener_certificate_id     = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled             = false
  health_check_grace_period_seconds = 300
  container_start_period_seconds    = 300
  blocking_waf_enabled              = false

  prod_https_listener_allow_cidr_blocks = [
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.40.0/22",
    "10.40.0.0/22",
    "10.30.0.0/22",
    "10.10.40.0/22",
    "10.120.0.0/24",
    "10.120.1.0/24",
  ]

  iam_managed_policy_attachments = [
    # May use bff-mobile or ows-analytics
    "arn:aws:iam::437795906767:policy/Dynamo-prod-mobile_metadata-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-prod_analytics_metadata-RO",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-bff-mobile-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-ows-analytics-owsrequest",
    "arn:aws:iam::437795906767:policy/SecretsManager-prod-bff-mobile-policy",
    "arn:aws:iam::437795906767:policy/SecretsManager-prod-ows-analytics-policy",
    aws_iam_policy.additional_secrets_policy.arn,
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      ANALYTICS_METADATA_TABLE = "prod_analytics_metadata"
    },
    {
      AWS_DEFAULT_REGION = "us-east-1"
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      DYNAMO_TABLE = "prod-mobile_metadata"
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      SNOWFLAKE_OWS_PODCAST_DB_SCHEMA = var.snowflake_ows_podcast_db_schema
    },
    {
      SPLITIO_USE_PREFORKED_INITIALIZATION = var.splitio_preforked
    }
  ]
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"
  # checkov:skip=CKV_AWS_30:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit
  # checkov:skip=CKV_AWS_31:Handle checkov findings Ensure all data stored in the Elasticache Replication Group is securely encrypted at transit and has auth token

  providers = {
    aws.dns = aws.networking
  }

  environment                      = var.environment
  service_name                     = var.service_name
  cache_engine                     = "redis"
  cache_subnet_group_name          = "prod-vpc-orchard-subnet"
  cache_node_type                  = "cache.t4g.micro"
  cache_parameter_group_name       = "default.redis5.0"
  redis_snapshot_window            = "03:00-05:00"
  redis_engine_version             = "5.0.6"
  cache_maintenance_window         = "sun:05:00-sun:09:00"
  vpc_id                           = module.vpc_info.vpc_id
  route53_zone_id                  = data.aws_route53_zone.route53_zone.zone_id
  application_family               = var.application_family
  cache_transit_encryption_enabled = false
  cache_node_count                 = 2
}

module "datadog_elasticache" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/elasticache?ref=6.13.4"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
  teams              = var.teams

  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}

# Secrets manager entry for analytics vanity FQDN
resource "aws_secretsmanager_secret" "ows_analytics_cache_fqdn_secret" {
  name        = "${var.environment}/${var.service_name}/REDIS_HOST"
  description = "FQDN for ows-analytics redis cache"
}
resource "aws_secretsmanager_secret_version" "ows_analytics_cache_fqdn_secret" {
  secret_id     = aws_secretsmanager_secret.ows_analytics_cache_fqdn_secret.id
  secret_string = module.elasticache.redis_primary_endpoint_address
}


module "fargate_ows_legacy_analytics_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.environment
  application_family                = var.application_family
  environment_type                  = "fargate"
  service_name                      = "ows-legacy-analytics"
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
  dependent_applications            = var.dependent_applications
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.environment
  application_family                = var.application_family
  environment_type                  = "fargate"
  service_name                      = var.service_name
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
  dependent_applications            = var.dependent_applications
}

# Create IAM user for elasticsearch cache warm jenkins job."
resource "aws_iam_user" "cache_prewarm_user" {
  name = "prod-${var.service_name}-cache-prewarm-user"
  tags = {
    terraformed = true
    role        = "service-user"
  }
}

# Attach iam policies to cache-prewarm iam user.
resource "aws_iam_user_policy_attachment" "iam-user-policy-attachment" {
  user       = aws_iam_user.cache_prewarm_user.name
  count      = length(var.iam_policy_arn)
  policy_arn = var.iam_policy_arn[count.index]
}

module "ows_analytics_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}


module "ows_legacy_analytics_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_legacy_secret_names)

  environment                    = var.environment
  service_name                   = "ows-legacy-analytics"
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}