module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-assets/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

locals {
  match_audio_dynamodb_table_name = "${var.environment}_content_review_match_audio_match"
}

data "aws_caller_identity" "current" {}

data "aws_dynamodb_table" "match_audio_dynamodb_table" {
  name = local.match_audio_dynamodb_table_name
}

data "aws_iam_policy_document" "match_audio_dynamodb_table_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      data.aws_dynamodb_table.match_audio_dynamodb_table.arn
    ]
    actions = [
      "dynamodb:BatchGetItem"
    ]
  }
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

resource "aws_iam_policy" "match_audio_dynamodb_table_policy" {
  name        = "${var.environment}-${var.service_name}-match-audio-dynamodb-table-policy"
  description = "Give ows-assets read access to the DynamoDB table where audio matching results are stored."
  policy      = data.aws_iam_policy_document.match_audio_dynamodb_table_policy_document.json
}

module "ows_assets_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  application_family = var.application_family
  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  teams              = [var.environment]
}

module "ows_assets_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name   = var.environment
  service_name       = var.service_name
  policy_description = "Dynamo-${var.environment}-ows-assets-owsrequest"
}

data "aws_secretsmanager_secret" "rds_master_username" {
  name = "${var.environment}/${var.service_name}/rds_master_username"
}

data "aws_secretsmanager_secret_version" "rds_master_username" {
  secret_id = data.aws_secretsmanager_secret.rds_master_username.id
}

data "aws_secretsmanager_secret" "rds_master_password" {
  name = "${var.environment}/${var.service_name}/rds_master_password"
}

data "aws_secretsmanager_secret_version" "rds_master_password" {
  secret_id = data.aws_secretsmanager_secret.rds_master_password.id
}

module "ows_assets_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.8.0"

  providers = {
    aws.dns = aws.networking
  }

  application_family                = var.application_family
  environment                       = var.environment
  service_name                      = var.service_name
  aws_region                        = var.aws_region
  commit_sha                        = "latest"
  container_port                    = "8080"
  task_type                         = "web_service"
  desired_task_count                = 6
  task_cpu                          = 1024
  task_memory                       = 2048
  maximum_capacity                  = 24
  minimum_capacity                  = 4
  route53_zone_id                   = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                            = module.vpc_info.vpc_id
  https_listener_certificate_id     = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  autoscaling_memory_policy_enabled = true
  scaling_memory_target_value       = 60

  https_listener_allow_prefix_list_names = [
    "shared-orcd-jump-box-private-subnet-prefix-list",
  ]

  iam_managed_policy_attachments = [
    module.ows_assets_owsrequest.policy_arn_output,
    "arn:aws:iam::437795906767:policy/Cloudfront-ows-assets-CreateInvalidation",
    "arn:aws:iam::437795906767:policy/STS-prod-ows-assets-AssumeRole",
    "arn:aws:iam::437795906767:policy/S3-prod-asset-storage-RW",
    "arn:aws:iam::437795906767:policy/S3-prod-asset-storage-images-RO",
    "arn:aws:iam::437795906767:policy/S3-prod-orcd-mezzanine-assets-RW",
    "arn:aws:iam::437795906767:policy/S3-prod-orcd-raw-assets-Read-Get",
    "arn:aws:iam::437795906767:policy/S3-prod-orcd-raw-assets-PutItem",
    aws_iam_policy.match_audio_dynamodb_table_policy.arn,
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_PATCH_MODULES = "requests:true"
    },
    {
      DD_APM_ANALYZED_SPANS = "flask|flask.request=1,requests|requests.request=1,aws.dynamodb|dynamodb.command=1,aws.secretsmanager|secretsmanager.command=1"
    },
    {
      IAM_ROLE = var.IAM_ROLE
    },
    {
      REDIS_HOST = module.elasticache.redis_primary_endpoint_address
    },
    {
      REDIS_PORT = var.REDIS_PORT
    },
    {
      SENTRY_DSN = module.ows_assets_sentry_project.sentry_key_dsn_public_output
    },
    {
      SERVER_LOCATION_AVL = var.SERVER_LOCATION_AVL
    },
    {
      STREAM_URL = var.STREAM_URL
    },
    {
      STS_TOKEN_DURATION = var.STS_TOKEN_DURATION
    },
    {
      WOWZA_PATH_PREFIX = var.WOWZA_PATH_PREFIX
    },
    {
      WOWZA_PATH_PREFIX_V2 = var.WOWZA_PATH_PREFIX_V2
    },
    {
      WOWZA_URL = var.WOWZA_URL
    },
    {
      WOWZA_URL_V2 = var.WOWZA_URL_V2
    },
    {
      MATCH_AUDIO_DYNAMODB_TABLE_NAME = local.match_audio_dynamodb_table_name
    },
    {
      UWSGI_WORKERS = var.UWSGI_WORKERS
    },
    {
      UWSGI_CHEAPER_RSS_LIMIT_SOFT = tostring(floor(pow(10, 9) * var.UWSGI_CHEAPER_RSS_LIMIT_SOFT_GB))
    },
    {
      IS_REDIS_SSL_ENABLED = "true"
    },
    {
      RDS_DB_HOST = module.ows_assets_rds.rds_cluster_endpoint
    },
    {
      RDS_DB_NAME = module.ows_assets_rds.rds_cluster_database_name
    },
    {
      RDS_DB_USER = var.rds_db_user
    },
    {
      RDS_DB_CONNECTION_CHARSET = var.rds_db_connection_charset
    },
    {
      AR_DB_HOST = var.ar_db_host
    },
    {
      AR_DB_NAME = var.ar_db_name
    },
    {
      AR_DB_USER = var.ar_db_user
    },
    {
      AR_DB_CONNECTION_CHARSET = var.ar_db_connection_charset
    },
  ]
}

module "ows_assets_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=6.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                               = var.environment
  service_name                              = var.service_name
  application_family                        = var.application_family
  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_engine_version                        = "8.0"
  rds_cluster_instance_class                = "db.r6g.2xlarge"
  rds_cluster_instance_count                = "2"
  rds_master_username                       = data.aws_secretsmanager_secret_version.rds_master_username.secret_string
  rds_master_password                       = data.aws_secretsmanager_secret_version.rds_master_password.secret_string
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_db_cluster_parameter_group_name       = "aurora-mysql80sync"
  rds_performance_insights_enabled          = true
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  custom_kms_key_enabled                    = false
  route53_zone_id                           = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                                    = module.vpc_info.vpc_id
}

module "fargate_service_dashboard" {
  source             = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.7"
  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name
  application_family = var.application_family

  critical_number_4xx          = 350
  critical_recovery_number_4xx = 251
  warning_number_4xx           = 250
  warning_recovery_number_4xx  = 125
  ok_number_4xx                = 240
  service_4xx_monitor_enabled  = false

  critical_number_5xx          = var.critical_number_5xx
  critical_recovery_number_5xx = var.critical_recovery_number_5xx
  warning_number_5xx           = var.warning_number_5xx
  warning_recovery_number_5xx  = var.warning_recovery_number_5xx

  service_cpu_time_window              = var.cpu_time_window
  service_cpu_critical_number          = var.cpu_critical_number
  service_cpu_critical_recovery_number = var.cpu_critical_recovery_number
  service_cpu_warning_number           = var.cpu_warning_number
  service_cpu_warning_recovery_number  = var.cpu_warning_recovery_number

  notification_endpoints            = var.application_alert_channel
  escalation_notification_endpoints = var.application_alert_channel
  additional_tags                   = { service_type = "critical" }
  dependent_applications            = var.dependent_applications

  healthy_tasks_notification_overrides = {
    endpoints            = var.healthy_tasks_notification_endpoints
    escalation_endpoints = var.healthy_tasks_notification_endpoints
  }
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=4.0.0"

  providers = {
    aws.dns = aws.networking
  }

  environment              = var.environment
  service_name             = "${var.service_name}-cache"
  application_family       = var.application_family
  cache_engine             = "redis"
  redis_engine_version     = "7.1"
  cache_node_type          = "cache.t4g.micro"
  cache_subnet_group_name  = "${var.environment}-elasticache-subnet-group"
  cache_node_count         = 2
  vpc_id                   = module.vpc_info.vpc_id
  override_route53_zone_id = data.aws_route53_zone.route53_zone.zone_id
}

module "raw_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.7"

  env                                 = var.environment
  bucket_name                         = "orcd-raw-assets"
  application_family                  = var.application_family
  acceleration_status                 = "Enabled"
  enable_guardduty_malware_protection = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_current_version_transition = [
    {
      prefix        = ""
      enabled       = true
      days          = 0
      storage_class = "INTELLIGENT_TIERING"
    }
  ]

  lifecycle_rules_options_noncurrent_version_transition = [
    {
      prefix        = ""
      enabled       = true
      days          = 30
      storage_class = "GLACIER"
    }
  ]
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/s3?ref=6.16.2"

  environment                       = var.environment
  service_name                      = var.service_name
  bucket_name                       = "prod-orcd-raw-assets"
  application_family                = var.application_family
  teams                             = ["content-delivery-asset-management"]
  notification_endpoints            = var.application_alert_channel
  escalation_notification_endpoints = var.application_alert_channel

  dashboard_configuration = {
    enabled                       = false
    show_advanced_storage_metrics = false
    show_replication_metrics      = false
    show_standard_storage_metrics = false
  }

  guardduty_malware_monitor_configuration = {
    enabled = true
  }
}