module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-dmp/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io."
}

data "aws_route53_zone" "networking_route53_zone" {
  provider = aws.networking

  name = "theorchard.io."
}

# IAM policy to make M2M API calls to other OWS services.
data "aws_iam_policy" "ows_machine_to_machine_policy" {
  name = "SecretsManager-${var.environment}-ows-machine-to-machine-policy"
}

data "aws_ec2_managed_prefix_list" "fansifter_prefix_list" {
  name = "${var.environment}-fansifter-private-subnet-prefix-list"
}

module "ows_dmp_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=8.0.0"

  providers = {
    aws.dns = aws.networking
  }

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name

  rds_cluster_instance_class                = var.rds_cluster_instance_class
  rds_cluster_instance_count                = "1"
  rds_cluster_instance_parameter_group_name = aws_db_parameter_group.ows_pdp_aurora_postgresql16.name
  rds_db_cluster_parameter_group_name       = aws_rds_cluster_parameter_group.ows_pdp_aurora_postgresql16_replication.name
  rds_engine                                = "aurora-postgresql"
  rds_engine_version                        = "16"
  rds_master_username                       = "ows_postgres"
  rds_master_password                       = "s0mePass!chang3me"
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  enabled_cloudwatch_logs_exports           = ["postgresql"]

  vpc_id          = module.vpc_info.vpc_id

  rds_ingress_prefix_list_names = [
    data.aws_ec2_managed_prefix_list.fansifter_prefix_list.name,
  ]

  custom_kms_key_enabled = false
}

module "ows_dmp_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.1"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  desired_task_count = 2
  minimum_capacity   = 2
  maximum_capacity   = 4
  task_cpu           = 1024
  task_memory        = 2048

  vpc_id                        = module.vpc_info.vpc_id
  fargate_service_subnets       = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets         = module.vpc_info.default_private_subnet_ids
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  application_family            = var.application_family
  custom_waf_arn                = module.custom_waf.waf_blocking_arn_output

  iam_managed_policy_attachments = [
    data.aws_iam_policy.ows_machine_to_machine_policy.arn,
    aws_iam_policy.ows_dmp_kms_policy.arn,
    aws_iam_policy.s3_audience_export_files_bucket_rw_policy.arn,
    aws_iam_policy.campaign_assets_s3_write_only_policy.arn,
  ]

  https_listener_allow_prefix_list_names = [
    "${var.environment}-fansifter-private-subnet-prefix-list",
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      SENTRY_DSN = module.sentry-ows-dmp.sentry_key_dsn_public_output
    },
    {
      POSTGRES_HOST = module.ows_dmp_rds.rds_cluster_endpoint
    },
    {
      POSTGRES_PORT = module.ows_dmp_rds.rds_cluster_port
    },
    {
      POSTGRES_NAME = module.ows_dmp_rds.rds_cluster_database_name
    },
    {
      NEO4J_URL = var.neo4j_url
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      REDIS_HOST = module.ows_dmp_redis_elasticache.redis_primary_endpoint_address
    },
    {
      SONGWHIP_DATA_KMS_KEY_ID = aws_kms_alias.songwhip_data_kms_alias.name
    },
    {
      SONGWHIP_SPOTIFY_CLIENT_ID = var.songwhip_spotify_client_id
    },
    {
      DMP_KMS_KEY_ID = aws_kms_alias.ows_dmp_kms_alias.name
    },
    {
      SYSTEM_USER_IDENTITY_ID = var.system_user_identity_id
    },
    {
      SYSTEM_USER_PROFILE_ID = var.system_user_profile_id
    },
    {
      FIVETRAN_SHOPIFY_GROUP_ID = var.fivetran_shopify_group_id
    },
    {
      FIVETRAN_REPORTING_GROUP_ID = var.fivetran_reporting_group_id
    },
    {
      SNOWFLAKE_SHOPIFY_INTEGRATIONS_DATABASE = local.snowflake_shopify_integrations_database
    },
    {
      SNOWFLAKE_SHOPIFY_SCHEMA = local.snowflake_shopify_schema
    },
    {
      AUDIENCE_EXPORT_BUCKET_NAME = module.audience_export_s3_bucket.s3_bucket_name_output
    },
    {
      CAMPAIGN_ASSETS_BUCKET_NAME = module.audience_campaign_assets_s3_bucket.s3_bucket_name_output
    },
    {
      FACEBOOK_APP_ID = var.facebook_app_id
    },
    {
      TIKTOK_APP_ID = var.tiktok_app_id
    },
    {
      GOOGLE_APP_ID = var.google_app_id
    },
    {
      ASSETS_CDN_DOMAIN = local.assets_cdn_domain
    },
    {
      SONGWHIP_URL = var.songwhip_url
    },
  ]

  secrets = [
    {
      POSTGRES_USER = "${var.environment}/${var.service_name}/RDS_DMP_USERNAME"
    },
    {
      POSTGRES_PASSWORD = "${var.environment}/${var.service_name}/RDS_DMP_PASSWORD"
    },
    {
      NEO4J_USERNAME = "${var.environment}/${var.service_name}/NEO4J_USERNAME"
    },
    {
      NEO4J_PASSWORD = "${var.environment}/${var.service_name}/NEO4J_PASSWORD"
    },
    {
      SNOWFLAKE_PASSWORD = "${var.environment}/${var.service_name}/SNOWFLAKE_DELPHI_PASSWORD"
    },
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
    {
      SNOWFLAKE_KEY_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY_PASSPHRASE"
    },
    {
      SONGWHIP_SPOTIFY_CLIENT_SECRET = "${var.environment}/${var.service_name}/SONGWHIP_SPOTIFY_CLIENT_SECRET"
    },
    {
      FIVETRAN_API_KEY = "${var.environment}/${var.service_name}/FIVETRAN_API_KEY"
    },
    {
      FIVETRAN_API_SECRET = "${var.environment}/${var.service_name}/FIVETRAN_API_SECRET"
    },
    {
      SPLIT_IO_API_KEY = "${var.environment}/split/API_KEY"
    },
    {
      FACEBOOK_APP_SECRET = "${var.environment}/${var.service_name}/FACEBOOK_APP_SECRET"
    },
    {
      TIKTOK_APP_SECRET = "${var.environment}/${var.service_name}/TIKTOK_APP_SECRET"
    },
    {
      GOOGLE_APP_SECRET = "${var.environment}/${var.service_name}/GOOGLE_APP_SECRET"
    },
    {
      GOOGLE_DEVELOPER_TOKEN = "${var.environment}/${var.service_name}/GOOGLE_DEVELOPER_TOKEN"
    },
    {
      AWS_LOCATION_API_KEY = "${var.environment}/${var.service_name}/AWS_LOCATION_API_KEY"
    },
  ]
}

module "ows_dmp_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.16.2"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name
  application_family = var.application_family
  teams              = ["fansifter"]

  dependent_applications = var.dependent_applications

  ok_number_5xx                = 2
  warning_number_5xx           = 3
  warning_recovery_number_5xx  = 2
  critical_number_5xx          = 5
  critical_recovery_number_5xx = 3

  service_cpu_monitor_evaluation_function = "avg"
  service_cpu_time_window                 = "last_10m"


  notification_endpoints            = "@slack-fansifter-alerts @oncall-fansifter"
  escalation_notification_endpoints = "@slack-fansifter"
}

module "sentry-ows-dmp" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.environment]
}

module "ows_dmp_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}

module "ows_dmp_redis_elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=4.0.2"

  providers = {
    aws.dns = aws.networking
  }

  application_family         = var.application_family
  environment                = var.environment
  service_name               = var.service_name
  cache_engine               = "redis"
  redis_engine_version       = "6.x"
  cache_parameter_group_name = "default.redis6.x"
  cache_node_type            = "cache.t4g.micro"
  cache_node_count           = 2
  cache_subnet_group_name    = "${var.environment}-elasticache-subnet-group"
  vpc_id                     = module.vpc_info.vpc_id
}