module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.1.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = "us-east-1"
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}


# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-grass/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_elasticache_replication_group" "private_grass_redis_cluster" {
  replication_group_id = "prod-ows-grass-public"
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.3.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "networking_zone" {
  provider = aws.networking

  name         = "theorchard.io."
  private_zone = false
}

data "aws_subnet" "prod_ows_grass01" {
  filter {
    name   = "tag:Name"
    values = ["prod_ows_grass01"]
  }
}

data "aws_subnet" "prod_ows_grass02" {
  filter {
    name   = "tag:Name"
    values = ["prod_ows_grass02"]
  }
}

data "aws_subnet" "prod_ows_grass03" {
  filter {
    name   = "tag:Name"
    values = ["prod_ows_grass03"]
  }
}

data "aws_iam_policy" "existing_policies" {
  for_each = toset(var.existing_iam_policies)

  name = each.value
}

module "ows_service_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.service_name
}

module "ows_grass_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment              = var.environment
  service_name             = var.service_name
  aws_region               = var.aws_region
  application_family       = var.application_family
  commit_sha               = "latest"
  container_port           = "8080"
  task_type                = "web_service"
  desired_task_count       = 5
  task_cpu                 = 4096
  task_memory              = 8192
  maximum_capacity         = 10
  minimum_capacity         = 5
  override_route53_zone_id = data.aws_route53_zone.networking_zone.zone_id

  vpc_id                          = module.vpc_info.vpc_id
  https_listener_certificate_id   = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  route53_record_creation_enabled = false

  iam_managed_policy_attachments = concat(
    [for policy in data.aws_iam_policy.existing_policies : policy.arn],
    [module.ows_service_owsrequest.policy_arn_output],
  )

  fargate_service_subnets = [
    data.aws_subnet.prod_ows_grass01.id,
    data.aws_subnet.prod_ows_grass02.id,
    data.aws_subnet.prod_ows_grass03.id,
  ]

  load_balancer_subnets = [
    data.aws_subnet.prod_ows_grass01.id,
    data.aws_subnet.prod_ows_grass02.id,
    data.aws_subnet.prod_ows_grass03.id,
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_HANDLER_ASYNC = "1"
    },
    {
      REDIS_HOST = data.aws_elasticache_replication_group.private_grass_redis_cluster.primary_endpoint_address
    },
    {
      REDIS_PORT = data.aws_elasticache_replication_group.private_grass_redis_cluster.port
    },
    {
      SEND_METRICS_TO_DD_ENABLED = "true"
    },
    {
      SESSION_DURATION = "1200"
    },
    {
      JWT_SERVICE_NAME = "lambda-jwt-refresh"
    },
    {
      JWT_SECRET_NAME = "jwt_enabled_services"
    },
    {
      JWT_REFRESH_INTERVAL = "43200"
    },
    {
      SENTRY_DSN = module.sentry_ows_grass_prod.sentry_key_dsn_public_output
    },
  ]

  secrets = [
    {
      AUTH0_API_AUDIENCE = "${var.environment}/ows-grass/AUTH0_API_AUDIENCE"
    },
    {
      AUTH0_DOMAIN = "${var.environment}/ows-grass/AUTH0_DOMAIN"
    },
    {
      DB_URL = "${var.environment}/ows-grass/DB_URL"
    },
  ]
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.6.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.19.0"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  critical_number_5xx               = var.critical_number_5xx
  critical_recovery_number_5xx      = var.critical_recovery_number_5xx
  warning_number_5xx                = var.warning_number_5xx
  warning_recovery_number_5xx       = var.warning_recovery_number_5xx
  notification_endpoints            = var.application_alert_channel
  escalation_notification_endpoints = var.application_alert_channel
  additional_tags                   = { service_type = "critical" }
  teams                             = [var.application_family]
  dependent_applications            = var.dependent_applications
}

module "sentry_ows_grass_prod" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.1.0"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.environment]
}