module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-ledger/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_caller_identity" "current" {}

module "ows_ledger_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.service_name
}

module "ows_ledger_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                                                            = var.environment
  service_name                                                           = var.service_name
  aws_region                                                             = var.aws_region
  desired_task_count                                                     = 2
  minimum_capacity                                                       = 3
  maximum_capacity                                                       = 8
  task_cpu                                                               = 2048
  task_memory                                                            = 4096
  route53_zone_id                                                        = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name                               = "orch-elb-logs"
  vpc_id                                                                 = module.vpc_info.vpc_id
  https_listener_certificate_id                                          = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  application_family                                                     = var.application_family
  autoscaling_active_connections_policy_enabled                          = true
  autoscaling_cpu_policy_enabled                                         = false
  scaling_active_connection_count_scale_out_threshold                    = 25
  scaling_active_connection_count_scale_out_number_of_evaluation_periods = 1
  scaling_active_connection_count_scale_in_threshold                     = 5

  iam_managed_policy_attachments = [
    module.ows_ledger_owsrequest.policy_arn_output
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  https_listener_allow_prefix_list_names = [
    "shared-orcd-jump-box-private-subnet-prefix-list",
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      DD_REMOTE_CONFIGURATION_ENABLED = "false"
    },
    {
      MYSQL_DB_HOST = var.my_sql_db_host
    },
    {
      MYSQL_DB_USER = var.my_sql_db_user
    },
    {
      SPLITIO_USE_PREFORKED_INITIALIZATION = "false"
    },
    {
      UWSGI_WORKERS = var.UWSGI_WORKERS
    },
    {
      UWSGI_CHEAPER_RSS_LIMIT_SOFT = var.UWSGI_CHEAPER_RSS_LIMIT_SOFT
    },
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      MYSQL_DB_PASS = "${var.environment}/${var.service_name}/MYSQL_DB_PASS"
    }
  ]
}

module "ows_ledger_fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.2"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
  teams                             = [var.application_family]
  healthy_tasks_monitor_enabled     = true
  failed_tasks_monitor_enabled      = true
  dependent_applications            = var.dependent_applications

  additional_tags = {
    service_type   = "critical"
    provisioned_by = "terraform"
  }

  # Warn for at least 5 events and alert for more than 15 events over a 5m window
  service_5xx_monitor_enabled  = true
  warning_number_5xx           = 5
  warning_recovery_number_5xx  = 0
  critical_number_5xx          = 15
  critical_recovery_number_5xx = 0.1
  ok_number_5xx                = 0

  # Warn for 10 events or more and alert for 20 events or more over a 5m window
  service_4xx_monitor_enabled  = true
  warning_number_4xx           = 10
  warning_recovery_number_4xx  = 0
  critical_number_4xx          = 20
  critical_recovery_number_4xx = 10
  ok_number_4xx                = 0

  # Notifications for 5xx events
  notification_overrides_5xx = {
    endpoints            = var.notification_endpoints
    alert_endpoints      = var.pagerduty_alert_channel
    escalation_endpoints = "${var.notification_endpoints} ${var.pagerduty_alert_channel}"
  }

  notification_overrides_failed_tasks = {
    endpoints            = "${var.notification_endpoints} ${var.pagerduty_alert_channel}"
    escalation_endpoints = "${var.notification_endpoints} ${var.pagerduty_alert_channel}"
  }

  healthy_tasks_notification_overrides = {
    endpoints            = "${var.notification_endpoints} ${var.pagerduty_alert_channel}"
    escalation_endpoints = "${var.notification_endpoints} ${var.pagerduty_alert_channel}"
  }
}

module "sentry-ows-ledger" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = "ows-ledger"
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "ows_ledger_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}