module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-moneyhub/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_sqs_queue" "custom_reports_queue" {
  name = "${var.environment}-sqs-moneyhub-custom-reports-queue"
}

data "aws_sqs_queue" "generate_attachments_queue" {
  name = "${var.environment}-sqs-moneyhub-generate-attachments-queue"
}

data "aws_sfn_state_machine" "dbt_refresh_state_machine" {
  name = "${var.environment}-dbt-accounting-sm"
}

data "aws_iam_policy" "dbt_refresh_state_machine_start_execution_policy" {
  arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:policy/${var.environment}-dbt-accounting-ecs-service-start-sf-policy"
}

module "ows_moneyhub_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.environment]
}

module "ows_moneyhub_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.service_name
}

data "aws_iam_policy_document" "sqs_generate_attachments_policy" {
  statement {
    actions = [
      "sqs:SendMessageBatch",
      "sqs:SendMessage",
      "sqs:GetQueueUrl",
      "sqs:GetQueueAttributes"
    ]

    resources = [
      data.aws_sqs_queue.custom_reports_queue.arn,
      data.aws_sqs_queue.generate_attachments_queue.arn
    ]
  }
}

resource "aws_iam_policy" "sqs_generate_attachments_policy" {
  name   = "SQS-${var.environment}-${var.service_name}-generate-attachments-RW"
  policy = data.aws_iam_policy_document.sqs_generate_attachments_policy.json
}

resource "aws_elasticache_parameter_group" "moneyhub_redis_custom_config" {
  name   = var.elasticache_param_group_name
  family = "redis5.0"

  parameter {
    name  = "maxmemory-policy"
    value = "allkeys-lfu"
  }
}

resource "aws_elasticache_parameter_group" "moneyhub_redis_custom_config_version_seven" {
  name   = var.elasticache_param_group_name_version_seven
  family = "redis7"

  parameter {
    name  = "maxmemory-policy"
    value = "allkeys-lfu"
  }
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                      = var.environment
  service_name                     = var.service_name
  application_family               = var.application_family
  redis_engine_version             = "5.0.6"
  cache_engine                     = "redis"
  cache_subnet_group_name          = "${var.environment}-vpc-orchard-subnet"
  cache_node_type                  = "cache.m6g.large"
  cache_transit_encryption_enabled = true
  vpc_id                           = module.vpc_info.vpc_id
  route53_zone_id                  = data.aws_route53_zone.route53_zone.zone_id
  additional_cidr_blocks_enabled   = true
  additional_cidr_blocks = [
    "162.49.75.0/24", # Allow access from SME VPN
  ]
  cache_parameter_group_name       = var.elasticache_param_group_name_version_seven
}

module "ows_moneyhub_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.8.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                                   = var.environment
  service_name                                  = var.service_name
  application_family                            = var.application_family
  aws_region                                    = var.aws_region
  desired_task_count                            = 2
  minimum_capacity                              = 2
  maximum_capacity                              = 6
  task_cpu                                      = 1024
  task_memory                                   = 2048
  route53_zone_id                               = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name      = "orch-elb-logs"
  vpc_id                                        = module.vpc_info.vpc_id
  fargate_service_subnets                       = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                         = module.vpc_info.default_private_subnet_ids
  https_listener_certificate_id                 = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  autoscaling_active_connections_policy_enabled = true
  autoscaling_cpu_policy_enabled                = false
  custom_waf_arn                                = module.custom_waf.waf_blocking_arn_output

  https_listener_allow_prefix_list_names = [
    "vpn-ny-users",
  ]

  iam_managed_policy_attachments = [
    module.ows_moneyhub_owsrequest.policy_arn_output,
    module.s3_moneyhub_attachments_bucket.s3_read_only_policy_arn_output,
    module.s3_moneyhub_custom_reports_bucket.s3_read_only_policy_arn_output,
    module.s3_moneyhub_vat_summary_bucket.s3_read_only_policy_arn_output,
    aws_iam_policy.sqs_generate_attachments_policy.arn,
    aws_iam_policy.internal_attachments_bucket_read_access_policy.arn,
    data.aws_iam_policy.dbt_refresh_state_machine_start_execution_policy.arn,
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      DD_PROFILING_ENABLED = var.datadog_profiling_enabled
    },
    {
      DD_PROFILING_TIMELINE_ENABLED = var.datadog_profiling_timeline_enabled
    },
    {
      DD_RUNTIME_METRICS_ENABLED = var.datadog_runtime_metrics_enabled
    },
    {
      DD_TRACE_SNOWFLAKE_ENABLED = var.datadog_trace_snowflake_enabled
    },
    {
      MYSQL_DB_HOST = "${var.environment}-royalty-accounting-db.theorchard.io"
    },
    {
      MYSQL_DB_USER = var.mysql_db_user
    },
    {
      MYSQL_DB_PORT = var.mysql_db_port
    },
    {
      MYSQL_DB_NAME = var.mysql_db_name
    },
    {
      SENTRY_DSN = module.ows_moneyhub_sentry_project.sentry_key_dsn_public_output
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      REDIS_HOST = module.elasticache.redis_cluster_cname_output[0]
    },
    {
      REDIS_PORT = var.redis_port
    },
    {
      REDIS_USE_SSL = var.redis_use_ssl
    },
    {
      REDIS_ENABLED = var.redis_enabled
    },
    {
      DBT_REFRESH_STATE_MACHINE_ARN = data.aws_sfn_state_machine.dbt_refresh_state_machine.arn
    },
  ]

  secrets = [
    {
      MYSQL_DB_PASS = "${var.environment}/${var.service_name}/MYSQL_DB_PASS"
    },
    {
      SLACK_WEBHOOK_URL = "${var.environment}/${var.service_name}/SLACK_WEBHOOK_URL"
    },
    {
      SNOWFLAKE_KEY_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY_PASSPHRASE"
    },
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
  ]
}

# Attachments S3 bucket

module "s3_moneyhub_attachments_bucket" {
  source              = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.14.1"
  env                 = var.environment
  bucket_name         = var.attachments_bucket_name
  application_family  = var.application_family
  s3_read_only_policy = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 1
    }
  ]
}

# Custom reports S3 bucket

module "s3_moneyhub_custom_reports_bucket" {
  source              = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.14.1"
  env                 = var.environment
  bucket_name         = var.custom_reports_bucket_name
  application_family  = var.application_family
  s3_read_only_policy = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 1
    }
  ]
}

# Vat summary bucket

module "s3_moneyhub_vat_summary_bucket" {
  source              = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.14.1"
  env                 = var.environment
  bucket_name         = var.vat_summary_bucket_name
  application_family  = var.application_family
  s3_read_only_policy = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 1
    }
  ]
}

#Internal attachments bucket AKA orcdbucket
data "aws_s3_bucket" "internal_attachments_bucket" {
  bucket = "${var.environment}-orcdbucket"
}

data "aws_iam_policy_document" "internal_attachments_bucket_read_access_document" {
  statement {
    resources = [
      data.aws_s3_bucket.internal_attachments_bucket.arn,
      "${data.aws_s3_bucket.internal_attachments_bucket.arn}/*"
    ]

    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket"
    ]
  }

  statement {
    resources = [
      "${data.aws_s3_bucket.internal_attachments_bucket.arn}/${var.environment}-statement-attachments/",
      "${data.aws_s3_bucket.internal_attachments_bucket.arn}/${var.environment}-statement-attachments/*",
      "${data.aws_s3_bucket.internal_attachments_bucket.arn}/${var.environment}-per-label-statement-attachments/",
      "${data.aws_s3_bucket.internal_attachments_bucket.arn}/${var.environment}-per-label-statement-attachments/*",
    ]
    actions = [
      "s3:GetObject",
      "s3:ListBucket"
    ]
  }
}

resource "aws_iam_policy" "internal_attachments_bucket_read_access_policy" {
  name        = "S3-${var.environment}-internal-attachments-bucket-read-access-policy"
  description = "Policy for read permissions to internal attachments buckets"
  policy      = data.aws_iam_policy_document.internal_attachments_bucket_read_access_document.json
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}