module "ows_payee_s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.1"

  env                = var.environment
  bucket_name        = "abacus-${var.service_name}"
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix  = "${var.s3_bucket_pdf_files_folder}/"
      enabled = true
      days    = var.temporary_files_expiration_time
    }
  ]

  lifecycle_rules_options_current_version_expiration = [
    {
      prefix  = "${var.s3_bucket_pdf_files_folder}/"
      enabled = true
      days    = var.temporary_files_expiration_time
    }
  ]

}

data "aws_iam_policy_document" "ows_payee_s3_bucket_rw_policy_document" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject",
    ]

    resources = [
      "${module.ows_payee_s3_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "ows_payee_s3_bucket_rw_policy" {
  name        = "S3-${var.environment}-ows-payee-bucket-RW"
  description = "Read, Write, Delete access to ows-payee bucket"
  policy      = data.aws_iam_policy_document.ows_payee_s3_bucket_rw_policy_document.json
  tags = {
    environment        = var.environment
    service_name       = var.service_name
    application_family = var.application_family
    terraformed        = true
  }
}