module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = "us-east-1"
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-payee/lambda-rotate-payoneer-auth-token/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_subnets" "private" {
  filter {
    name   = "vpc-id"
    values = [module.vpc_info.vpc_id]
  }

  filter {
    name = "tag:Name"
    values = [
      "prod_private_subnet_2",
      "prod_private_subnet_3",
    ]
  }
}

module "lambda_rotate_payoneer_auth_token" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"

  environment              = var.environment
  application_family       = var.application_family
  lambda_name              = var.service_name
  lambda_description       = "Rotates Payoneer auth token in AWS Secrets Manager"
  lambda_function_timeout  = 300
  vpc_id                   = module.vpc_info.vpc_id
  vpc_subnet_ids           = module.vpc_info.default_private_subnet_ids
  use_container_image      = true
  datadog_advanced_enabled = true
  iam_managed_policy_attachments = [
    aws_iam_policy.lambda_rotate_payoneer_auth_token_policy.arn
  ]

  lambda_function_environment_variables = {
    Environment       = var.environment
    PAYONEER_AUTH_URL = var.payoneer_auth_url
    PAYONEER_API_URL  = var.payoneer_api_url
  }
}

resource "aws_lambda_permission" "allow_secrets_manager_trigger" {
  statement_id   = "allow-secrets-manager-trigger"
  action         = "lambda:InvokeFunction"
  function_name  = module.lambda_rotate_payoneer_auth_token.lambda_name
  principal      = "secretsmanager.amazonaws.com"
  source_account = data.aws_caller_identity.current.account_id
}

data "aws_secretsmanager_secret" "payoneer_token_secret" {
  name = "${var.environment}/${var.ows_payee_service_name}/${var.payoneer_token_secret_name}"
}

data "aws_iam_policy_document" "lambda_rotate_payoneer_auth_token_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      data.aws_secretsmanager_secret.payoneer_token_secret.arn,
    ]

    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
      "secretsmanager:UpdateSecret",
      "secretsmanager:UpdateSecretVersionStage",
      "secretsmanager:PutSecretValue",
    ]
  }
}

# Give the lambda permission to update the Payoneer secret of ows-payee
resource "aws_iam_policy" "lambda_rotate_payoneer_auth_token_policy" {
  name        = "${var.environment}-${var.service_name}-policy"
  description = "rotate_payoneer_auth_token lambda policy"
  policy      = data.aws_iam_policy_document.lambda_rotate_payoneer_auth_token_policy_document.json
}

module "datadog_lambda_rotate_payoneer_auth_token" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"

  environment            = var.environment
  service_name           = var.service_name
  notification_endpoints = var.datadog_notification_endpoints
}

module "sentry_lambda_rotate_payoneer_auth_token" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "lambda_rotate_payoneer_auth_token_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}