module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-payee/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "ows_payee_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  policy_description = "A policy to access dynamo owsrequest table"
  environment_name   = var.environment
  service_name       = var.service_name
}


module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "ows_payee_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  desired_task_count = 2
  minimum_capacity   = 2
  maximum_capacity   = 8
  task_cpu           = 1024
  task_memory        = 2048
  route53_zone_id    = data.aws_route53_zone.route53_zone.zone_id

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  iam_policy_file_enabled       = true
  application_family            = var.application_family
  fargate_service_subnets       = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets         = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    module.ows_payee_owsrequest.policy_arn_output,
    aws_iam_policy.task_kms_policy.arn,
    aws_iam_policy.ows_payee_s3_bucket_rw_policy.arn,
  ]

  https_listener_allow_prefix_list_names = [
    "shared-orcd-jump-box-private-subnet-prefix-list",
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DD_REMOTE_CONFIGURATION_ENABLED = "false"
    },
    {
      DD_RUNTIME_METRICS_ENABLED = var.datadog_runtime_metrics_enabled
    },
    {
      DD_DYNAMIC_INSTRUMENTATION_REDACTED_IDENTIFIERS = var.datadog_runtime_redacted_identifiers
    },
    {
      MYSQL_DB_HOST = var.mysql_db_host
    },
    {
      MYSQL_DB_USER = var.mysql_db_user
    },
    {
      HISTORICAL_ISO_CODES = "BYR,EEK,LTL,LVL,MRO,SKK,STD,TMM,VEF,ZWD"
    },
    {
      KMS_KEY_ID = "alias/${var.environment}-${var.service_name}-data-key"
    },
    {
      DYNAMODB_TABLE_NAME = module.ows_payee_dynamodb_table.aws_dynamodb_table_id_with_sort_key
    },
    {
      OWS_PAYEE_S3_BUCKET = module.ows_payee_s3_bucket.s3_bucket_name_output
    },
    {
      PDF_FILES_FOLDER = var.s3_bucket_pdf_files_folder
    },
    {
      S3_PRESIGNED_URL_EXPIRATION_TIME = var.s3_presigned_url_expiration_time
    },
    {
      PAYONEER_API_URL = var.payoneer_api_url
    },
    {
      PAYONEER_REDIRECT_URL_ORCHARD = var.payoneer_redirect_url_orchard
    },
    {
      PAYONEER_REDIRECT_URL_AWAL = var.payoneer_redirect_url_awal
    },
    {
      PAYONEER_REDIRECT_URL_ALTAFONTE = var.payoneer_redirect_url_altafonte
    },
    {
      PAYONEER_API_AUTH_URL = var.payoneer_api_base_auth_url
    },
    {
      PAYONEER_AUTH_TOKEN_ARN = module.ows_abacus_payee_payoneer_token_secret.secret_arn
    },
    {
      HMRC_API_URL = var.hmrc_api_url
    },
    {
      SENTRY_DSN = module.sentry_ows_payee.sentry_key_dsn_public_output
    },
    {
      SCHEMA_REGISTRY_URL = var.schema_registry_url
    },
    {
      KAFKA_BOOTSTRAP_SERVERS = var.kafka_bootstrap_servers
    },
    {
      SPLITIO_USE_PREFORKED_INITIALIZATION = "false"
    },
    {
      BANK_DETAILS_SERVICE_IDENTITIES = join(
        ",",
        [
          var.load_from_s3_lambda_m2m_uuid,
          var.lambda_moneyhub_generate_attachments_m2m_uuid
        ]
      )
    },
    {
      TAX_FORM_SERVICE_IDENTITIES = join(
        ",",
        [
          var.load_from_s3_lambda_m2m_uuid,
          var.lambda_moneyhub_generate_attachments_m2m_uuid
        ]
      )
    },
    {
      PAYONEER_SERVICE_IDENTITIES = var.payoneer_program_move_lambda_m2m_uuid
    }
  ]
}

module "ows_payee_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name
  application_family = var.application_family

  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints

  service_cpu_time_window = "last_15m"
  dependent_applications  = var.dependent_applications
}

module "sentry_ows_payee" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "ows_abacus_payee_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}

data "aws_lambda_function" "lambda_rotate_payoneer_auth_token" {
  function_name = "${var.environment}-${var.payoneer_token_rotation_lambda_function_name}"
}

module "ows_abacus_payee_payoneer_token_secret" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = var.payoneer_token_secret_name

  secret_rotation_enabled          = true
  secret_rotation_lambda_arn       = data.aws_lambda_function.lambda_rotate_payoneer_auth_token.arn
  secret_rotation_interval_in_days = 25
}

module "ows_payee_dynamodb_table" {
  source = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"

  env                            = var.environment
  table_name                     = "${var.service_name}-payee-info"
  hash_key                       = var.hash_key
  range_key_enabled              = true
  range_key                      = var.range_key
  server_side_encryption_enabled = true
  application_family             = var.application_family
  use_on_demand                  = true

  attribute = [
    {
      name = var.hash_key
      type = "S"
    },
    {
      name = var.range_key
      type = "S"
    }
  ]
}

resource "aws_kms_key" "prod_ows_payee_data_key" {
  description             = "${var.environment}-${var.service_name}-data-key"
  enable_key_rotation     = true
  deletion_window_in_days = 30
  tags = {
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = "true"
    application_family = var.application_family
  }
}

resource "aws_kms_alias" "prod_ows_payee_kms_key_alias" {
  name          = "alias/${var.environment}-${var.service_name}-data-key"
  target_key_id = aws_kms_key.prod_ows_payee_data_key.key_id
}

data "aws_iam_policy_document" "task_kms_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      aws_kms_key.prod_ows_payee_data_key.arn
    ]
    actions = [
      "kms:DescribeKey",
      "kms:GenerateDataKey",
      "kms:Decrypt"
    ]
  }

  statement {
    effect = "Allow"
    resources = [
      module.ows_payee_dynamodb_table.aws_dynamodb_table_arn_with_sort_key
    ]
    actions = [
      "dynamodb:BatchGetItem",
      "dynamodb:BatchWriteItem",
      "dynamodb:DescribeTable",
      "dynamodb:GetItem",
      "dynamodb:PutItem",
      "dynamodb:Query",
      "dynamodb:Scan",
      "dynamodb:UpdateItem",
      "dynamodb:DeleteItem",
    ]
  }
}

resource "aws_iam_policy" "task_kms_policy" {
  name        = "KMS-${var.environment}-${var.service_name}-kms_policy"
  description = "Payee service access to secure document resources"
  policy      = data.aws_iam_policy_document.task_kms_policy_document.json
}

resource "aws_iam_group_policy_attachment" "team_prod_dynamo_policy_attachment" {
  group      = "royalty-accounting-more"
  policy_arn = aws_iam_policy.task_kms_policy.arn
}