module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-payment/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_s3_bucket" "abacus_payments_bucket" {
  bucket = var.s3_payments_bucket_name
}

data "aws_iam_policy_document" "abacus_payments_bucket_read_write_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject*",
      "s3:PutObject*",
      "s3:DeleteObject*"
    ]

    resources = [
      "${data.aws_s3_bucket.abacus_payments_bucket.arn}/",
      "${data.aws_s3_bucket.abacus_payments_bucket.arn}/*",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket"
    ]

    resources = [
      data.aws_s3_bucket.abacus_payments_bucket.arn
    ]
  }
}

resource "aws_iam_policy" "abacus_payments_bucket_read_write_policy" {
  name   = "S3-${var.environment}-abacus-payments-bucket-read-write-policy"
  policy = data.aws_iam_policy_document.abacus_payments_bucket_read_write_policy_document.json
}

module "ows_payment_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.service_name
}

module "ows_payment_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  commit_sha         = "latest"
  container_port     = "8080"
  task_type          = "web_service"
  desired_task_count = 2
  minimum_capacity   = 2
  maximum_capacity   = 4
  task_cpu           = 1024
  task_memory        = 2048
  route53_zone_id    = data.aws_route53_zone.route53_zone.zone_id

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  blocking_waf_enabled          = true
  application_family            = var.application_family

  iam_managed_policy_attachments = [
    module.ows_payment_owsrequest.policy_arn_output,
    aws_iam_policy.abacus_payments_bucket_read_write_policy.arn
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      MYSQL_DB_HOST = var.mysql_db_host
    },
    {
      MYSQL_DB_USER = var.mysql_db_user
    },
    {
      HISTORICAL_ISO_CODES = "BYR,EEK,LTL,LVL,MRO,SKK,STD,TMM,VEF,ZWD"
    },
    {
      S3_PAYMENTS_BUCKET_NAME = var.s3_payments_bucket_name
    },
    {
      SPLITIO_USE_PREFORKED_INITIALIZATION = "false"
    },
    {
      PAYMENT_ALLOCATION_IDENTITIES = join(
        ",",
        [
          var.documents_payoneer_webhooks_lambda_m2m_uuid,
          var.documents_generate_payments_lambda_m2m_uuid,
          var.documents_calculate_payments_lambda_m2m_uuid,
          var.abacus_payoneer_payments_payout_lambda_m2m_uuid
        ]
      )
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_CORTEX_SEARCH_SERVICE_NAME = var.snowflake_cortex_search_service_name
    },
  ]

  secrets = [
    {
      SNOWFLAKE_KEY_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY_PASSPHRASE"
    },
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
  ]
}

module "ows_payment_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"

  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
  dependent_applications            = var.dependent_applications
}

module "sentry-ows-payment" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = "ows-payment"
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "ows_payment_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = var.secret_name
}

module "snowflake_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.snowflake_secrets_manager_secret_names)

  application_family             = var.application_family
  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  secret_recovery_window_in_days = 7
}