data "aws_iam_policy_document" "copy-podcasts-assets-invoke-policy" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:ListBucket"
    ]
    resources = [
      "arn:aws:s3:::prod-orcd-asset-transcoder-input",
      "arn:aws:s3:::prod-orcd-asset-transcoder-input/*",
      "arn:aws:s3:::prod-orcd-podcast-output-assets",
      "arn:aws:s3:::prod-orcd-podcast-output-assets/*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:CopyObject",
      "s3:ListBucket"
    ]
    resources = [
      "arn:aws:s3:::prod-podcasting-assets",
      "arn:aws:s3:::prod-podcasting-assets/*"
    ]
  }
}

data "aws_caller_identity" "current" {}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

# Jenkins agents will assume this role in order to invoke the machine
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-copy-podcasts-assets-jenkins-invoke-role"
  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
  max_session_duration = 43200
}

resource "aws_iam_role_policy" "copy_podcasts_assets_invoke_policy" {
  name = "S3-${var.environment}-copy-podcasts-assets-invoke-policy"
  role = aws_iam_role.jenkins_invoke_role.id

  policy = data.aws_iam_policy_document.copy-podcasts-assets-invoke-policy.json
}