terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-pricing/fivetran/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "fivetran_group" "prod_warehouse" {
  id = "gentry_invitro"
}

/* data "aws_rds_cluster" "rds_cluster" {
  cluster_identifier = "${var.environment}-ows-pricing-01"
} */

data "aws_db_instance" "rds_cluster_instance" {
  db_instance_identifier = "${var.environment}-ows-pricing-0"
}

resource "fivetran_connector" "rds_cluster_connector" {
  group_id          = data.fivetran_group.prod_warehouse.id
  service           = "aurora"
  networking_method = "SshTunnel"

  destination_schema {
    prefix = "prod_ows_pricing"
  }

  config {
    host        = data.aws_db_instance.rds_cluster_instance.address
    port        = data.aws_db_instance.rds_cluster_instance.port
    user        = "fivetran"
    database    = "pricing"
    tunnel_host = "fivetran.theorchard.io"
    tunnel_port = "2222"
    tunnel_user = "fivetran"
  }
}

resource "fivetran_connector_schedule" "rds_cluster_schedule" {
  connector_id      = fivetran_connector.rds_cluster_connector.id
  sync_frequency    = 5
  pause_after_trial = false
}

resource "fivetran_connector_schema_config" "rds_cluster_schema_config" {
  connector_id           = fivetran_connector.rds_cluster_connector.id
  schema_change_handling = "ALLOW_ALL"
  schemas = {
    film_transparency = {
      enabled = false
    }
    pricing = {
      enabled = true
      tables = { for table in var.pricing_tables_to_sync_to_snowflake : table => {
        enabled = true
      } }
    }
    sys = {
      enabled = true
      tables = { for table in var.sys_tables_to_sync_to_snowflake : table => {
        enabled = true
      } }
    }
  }
}