module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = "us-east-1"
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-product-physical/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each           = toset(var.secrets_manager_secret_names)
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

# Setup fargate environment.
module "ows_product_physical_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family
  commit_sha         = "latest"
  container_port     = "8080"
  task_type          = "web_service"
  desired_task_count = 2
  task_cpu           = 512
  task_memory        = 1024
  maximum_capacity   = 4
  minimum_capacity   = 2
  health_check_path  = "/hello"

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  blocking_waf_enabled          = false
  splitio_enabled               = true

  # overriding here to add in the graphql_switchboard_vpc (10.110.0.0/16) private subnets
  prod_https_listener_allow_cidr_blocks = [
    "192.168.31.0/24",
    "10.40.0.0/22",
    "10.30.0.0/22",
    "10.10.40.0/22",
    "10.120.0.0/24",
    "10.120.1.0/24",
  ]

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-prod-ows-product-physical-owsrequest",
    "arn:aws:iam::437795906767:policy/SQS-cloudsearch-etl-releases-update-q-RW",
    "arn:aws:iam::437795906767:policy/SQS-prod-upc_repository-minimal-policy",
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_PATCH_MODULES = "requests:true"
    },
    {
      DD_APM_ANALYZED_SPANS = "flask|flask.request=1,requests|requests.request=1,aws.dynamodb|dynamodb.command=1,aws.secretsmanager|secretsmanager.command=1"
    },
    {
      OWS_PRODUCT_URL = "https://ows-product.theorchard.io"
    },
    {
      OWS_MARKETING_URL = "https://ows-marketing.theorchard.io"
    },
    {
      OWS_PROJECT_URL = "https://ows-project-manager.theorchard.io"
    },
    {
      MYSQL_PORT = "3306"
    },
    {
      MYSQL_HOST = "ar-db.theorchard.com"
    },
    {
      MYSQL_DATABASE = "art_relations"
    },
    {
      MYSQL_USER = "ows-product-phys"
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_HOME = "/var/.snowflake"
    },
    {
      MYSQL_DELIVERY_HOST = "prod-product-physical-delivery-db.theorchard.io"
    },
    {
      MYSQL_DELIVERY_DATABASE = "product_physical_delivery"
    },
    {
      MYSQL_DELIVERY_USER = "ows-product-physical"
    },
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      LOGGER_DSN = "${var.environment}/${var.service_name}/LOGGER_DSN"
    },
    {
      MYSQL_PASSWORD = "${var.environment}/${var.service_name}/MYSQL_PASSWORD"
    },
    {
      SNOWFLAKE_PASSWORD = "${var.environment}/${var.service_name}/SNOWFLAKE_PASSWORD"
    },
    {
      MYSQL_DELIVERY_PASSWORD = "${var.environment}/${var.service_name}/MYSQL_DELIVERY_PASSWORD"
    },
    {
      SPLITIO_API_KEY = "${var.environment}/split/API_KEY"
    },
  ]
}

# Setup datadog dashboards.
module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.2"

  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  critical_number_5xx               = var.critical_number_5xx
  critical_recovery_number_5xx      = var.critical_recovery_number_5xx
  warning_number_5xx                = var.warning_number_5xx
  warning_recovery_number_5xx       = var.warning_recovery_number_5xx
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
  additional_tags                   = { service_type : "critical" }
  teams                             = [var.application_family]
  service_4xx_monitor_enabled       = false
  service_cpu_monitor_enabled       = false
  dependent_applications            = var.dependent_applications
}