module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = "content-creation-management"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-product-staging/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_lambda_function" "export_catalog_lambda" {
  function_name = "${var.environment}-${var.export_catalog_lambda_function_name}"
}

data "aws_lambda_function" "trigger_ingest_lambda" {
  function_name = "${var.environment}-${var.trigger_ingest_lambda_function_name}"
}

data "aws_sfn_state_machine" "bulk_session_ingest_sfn" {
  name = "${var.environment}-${var.bulk_session_ingest_sfn_name}"
}

data "aws_sfn_state_machine" "bulk_session_ingest_queue_sfn" {
  name = "${var.environment}-${var.bulk_session_ingest_queue_sfn_name}"
}

data "aws_iam_policy_document" "invoke_lambda_policy" {
  statement {
    actions = [
      "lambda:InvokeFunction"
    ]

    resources = [
      "${data.aws_lambda_function.export_catalog_lambda.arn}",
      "${data.aws_lambda_function.export_catalog_lambda.arn}:*",
      "${data.aws_lambda_function.trigger_ingest_lambda.arn}",
      "${data.aws_lambda_function.trigger_ingest_lambda.arn}:*"
    ]
  }
}

resource "aws_iam_policy" "invoke_lambda_policy" {
  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = "true"
  }

  name   = "${var.environment}-ows-product-staging-invoke-lambda-policy"
  policy = data.aws_iam_policy_document.invoke_lambda_policy.json
}

data "aws_secretsmanager_secret" "splitio_api_key" {
  name = "${var.environment}/split/API_KEY"
}

data "aws_iam_policy" "bulk_session_ingest_start_execution" {
  name = "StepFunctions-${var.environment}-sfn-bulk-session-ingest-StartExecution"
}

data "aws_iam_policy" "bulk_session_ingest_queue_start_execution" {
  name = "StepFunctions-${var.environment}-sfn-bulk-session-ingest-queue-StartExecution"
}

data "aws_sqs_queue" "finalize_bulk_session_queue" {
  name = "${var.environment}-${var.finalize_sqs_queue_name}-queue"
}

data "aws_iam_policy_document" "sqs_finalize_bulk_session_send_message" {
  statement {
    effect = "Allow"
    actions = [
      "sqs:SendMessage",
      "sqs:GetQueueUrl",
    ]
    resources = [
      data.aws_sqs_queue.finalize_bulk_session_queue.arn
    ]
  }
}

resource "aws_iam_policy" "sqs_finalize_bulk_session_send_message_policy" {
  name   = "SQS-${var.environment}-finalize-bulk-session-ows-product-staging-send-message"
  policy = data.aws_iam_policy_document.sqs_finalize_bulk_session_send_message.json
}

module "product_staging_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=8.0.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  rds_master_username = "product_staging_admin"
  rds_master_password = "s0mePass!changme"

  rds_cluster_instance_class                = "db.t4g.medium"
  rds_cluster_instance_count                = "1"
  rds_db_cluster_parameter_group_name       = "aurora-mysql80sync"
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  rds_engine                                = "aurora-mysql"
  rds_engine_version                        = "8.0"
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_performance_insights_enabled          = false
  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]

  custom_kms_key_enabled = false
  vpc_id                 = module.vpc_info.vpc_id
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io."
}

module "ows_product_staging_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  application_family = var.application_family
}

module "ows_product_staging_fargate_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  critical_number_5xx               = var.critical_number_5xx
  critical_recovery_number_5xx      = var.critical_recovery_number_5xx
  warning_number_5xx                = var.warning_number_5xx
  warning_recovery_number_5xx       = var.warning_recovery_number_5xx
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
  additional_tags                   = { service_type : "critical" }
  teams                             = [var.application_family]
}

module "ows_product_staging_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  application_family                       = var.application_family
  desired_task_count                       = 2
  minimum_capacity                         = 2
  maximum_capacity                         = 4
  task_cpu                                 = 4096
  task_memory                              = 8192
  commit_sha                               = "latest"
  container_port                           = 8080
  task_type                                = "web_service"
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled                    = false
  fargate_service_subnets                  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                    = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    aws_iam_policy.ows_product_staging_s3_bucket_rw_policy.arn,
    data.aws_iam_policy.bulk_session_ingest_start_execution.arn,
    data.aws_iam_policy.bulk_session_ingest_queue_start_execution.arn,
    aws_iam_policy.sqs_finalize_bulk_session_send_message_policy.arn,
    aws_iam_policy.invoke_lambda_policy.arn,
    aws_iam_policy.ingestion_execution_queue_policy.arn,
    aws_iam_policy.task_kms_policy.arn,
    aws_iam_policy.run_task_policy.arn
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      MYSQL_DB_USER = var.db_user
    },
    {
      MYSQL_DB_HOST = var.db_host
    },
    {
      MYSQL_DB_NAME = var.db_name
    },
    {
      MYSQL_DB_PORT = var.db_port
    },
    {
      NEO4J_URL = var.neo4j_url
    },
    {
      NEO4J_USERNAME = var.neo4j_user
    },
    {
      SENTRY_DSN = module.ows_product_staging_sentry_project.sentry_key_dsn_public_output
    },
    {
      OWS_PRODUCT_STAGING_S3_BUCKET = module.ows_product_staging_s3_bucket.s3_bucket_name_output
    },
    {
      BULK_SESSION_INGEST_SFN_ARN = data.aws_sfn_state_machine.bulk_session_ingest_sfn.arn
    },
    {
      BULK_SESSION_INGEST_QUEUE_SFN_ARN = data.aws_sfn_state_machine.bulk_session_ingest_queue_sfn.arn
    },
    {
      EXPORT_CATALOG_LAMBDA_ARN = data.aws_lambda_function.export_catalog_lambda.arn
    },
    {
      TRIGGER_INGEST_LAMBDA_ARN = data.aws_lambda_function.trigger_ingest_lambda.arn
    },
    {
      INGESTION_SQS_QUEUE_URL = module.ingestion_execution_queue.queue_url
    },
    {
      FINALIZE_SQS_QUEUE_URL = data.aws_sqs_queue.finalize_bulk_session_queue.url
    },
    {
      KMS_KEY_ID = "alias/${var.environment}-${var.service_name}-data-key"
    },
    {
      DYNAMODB_TABLE_NAME = module.ows_product_staging_google_auth_dynamodb_table.aws_dynamodb_table_id
    },
    {
      GOOGLE_CLIENT_ID = var.google_client_id
    },
    {
      SPOTIFY_API_CLIENT_ID = var.spotify_api_client_id
    },
    {
      REDIS_HOST = module.redis_elasticache.redis_primary_endpoint_address
    },
    {
      REDIS_PORT = "6379"
    },
    {
      CACHE_USE_REDIS = "true"
    }
  ]
  secrets = [
    {
      SPLITIO_API_KEY = "${var.environment}/split/API_KEY"
    }
  ]
}

module "ows_product_staging_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 30
}

module "ows_product_staging_google_auth_dynamodb_table" {
  source = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"
  env                            = var.environment
  table_name                     = "${var.service_name}-google-auth"
  hash_key                       = "user_id"
  server_side_encryption_enabled = true
  application_family             = var.application_family
  use_on_demand                  = true

  attribute = [
    {
      name = "user_id"
      type = "S"
    },
  ]
}

resource "aws_kms_key" "ows_product_staging_data_key" {
  description             = "${var.environment}-${var.service_name}-data-key"
  enable_key_rotation     = true
  deletion_window_in_days = 30
  tags = {
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = "true"
    application_family = var.application_family
  }
}

resource "aws_kms_alias" "ows_product_staging_kms_key_alias" {
  name          = "alias/${var.environment}-${var.service_name}-data-key"
  target_key_id = aws_kms_key.ows_product_staging_data_key.key_id
}

data "aws_iam_policy_document" "task_kms_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      aws_kms_key.ows_product_staging_data_key.arn
    ]
    actions = [
      "kms:DescribeKey",
      "kms:GenerateDataKey",
      "kms:Decrypt"
    ]
  }

  statement {
    effect = "Allow"
    resources = [
      module.ows_product_staging_google_auth_dynamodb_table.aws_dynamodb_table_arn
    ]
    actions = [
      "dynamodb:BatchGetItem",
      "dynamodb:BatchWriteItem",
      "dynamodb:DescribeTable",
      "dynamodb:GetItem",
      "dynamodb:PutItem",
      "dynamodb:Query",
      "dynamodb:Scan",
      "dynamodb:UpdateItem",
      "dynamodb:DeleteItem",
    ]
  }
}

resource "aws_iam_policy" "task_kms_policy" {
  name        = "KMS-${var.environment}-${var.service_name}-kms_policy"
  policy      = data.aws_iam_policy_document.task_kms_policy_document.json
}

data "aws_iam_policy_document" "run_task_policy_document" {
  # checkov:skip=CKV_AWS_111
  statement {
    effect = "Allow"
    actions = [
      "ec2:DescribeSecurityGroups",
      "ec2:DescribeSubnets",
      "ec2:DescribeVpcs",
      "ecs:DescribeTasks",
      "ecs:DescribeTaskDefinition",
    ]
    resources = ["*"]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:RunTask"
    ]
    resources = [
      "${module.ows_product_staging_fargate_environment.fargate_task_definition_arn_without_revision}:*",
      module.ows_product_staging_fargate_environment.fargate_cluster_arn,
      "arn:aws:ecs:*:*:task-definition/${var.environment}-google-drive-asset-transfer",
      "arn:aws:ecs:*:*:task-definition/${var.environment}-dropbox-asset-transfer",
      "arn:aws:ecs:*:*:task-definition/${var.environment}-export-spotify-catalog"
    ]
  }

  statement {
    effect  = "Allow"
    actions = ["iam:PassRole"]
    condition {
      test     = "StringLike"
      variable = "iam:PassedToService"
      values   = ["ecs-tasks.amazonaws.com"]
    }
    resources = [
      module.ows_product_staging_fargate_environment.fargate_task_iam_role_arn,
      module.ows_product_staging_fargate_environment.fargate_task_iam_execution_role_arn,
      "arn:aws:iam::*:role/${var.environment}-google-drive-asset-transfer-task-execution-role",
      "arn:aws:iam::*:role/${var.environment}-google-drive-asset-transfer-task-role",
      "arn:aws:iam::*:role/${var.environment}-dropbox-asset-transfer-task-execution-role",
      "arn:aws:iam::*:role/${var.environment}-dropbox-asset-transfer-task-role",
      "arn:aws:iam::*:role/${var.environment}-export-spotify-catalog-task-execution-role",
      "arn:aws:iam::*:role/${var.environment}-export-spotify-catalog-task-role"
    ]
  }
}

resource "aws_iam_policy" "run_task_policy" {
  name        = "${var.environment}-${var.service_name}-run_task_policy"
  policy      = data.aws_iam_policy_document.run_task_policy_document.json
}