module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-project-manager/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

data "aws_iam_policy_document" "secrets_manager_policy" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetSecretValue"
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/python-orchard-features/*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/python-orchard-features/"
    ]
  }
}

data "aws_iam_policy" "dynamodb_owsrequest_policy" {
  name = "Dynamo-${var.environment}-${var.service_name}-owsrequest"
}

data "aws_iam_policy" "dynamodb_owsrequest_public_policy" {
  name = "Dynamo-${var.environment}-${var.service_name}-public-owsrequest"
}

data "aws_iam_policy" "s3_label_copy_export_policy" {
  name = "S3-${var.environment}-label-copy-export-RW"
}

data "aws_iam_policy" "sqs_label_copy_export_policy" {
  name = "SQS-${var.environment}-label-copy-export-RW"
}

resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "${var.environment}-ows-project-manager-secret-manager-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy.json

  tags = {
    environment        = var.environment
    service_name       = var.service_name
    application_family = var.application_family
    terraformed        = true
  }
}

module "ows_project_manager_owsrequest" {
  source           = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"
  environment_name = var.environment
  service_name     = var.service_name
}

module "ows_project_manager_owsrequest_public" {
  source             = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"
  policy_description = "Dynamo-${var.environment}-${var.service_name}-owsrequest-public"
  environment_name   = var.environment
  service_name       = "${var.service_name}-public"
}

module "ows_project_manager_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=6.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  rds_master_username = "ows_project_manager_admin"
  rds_master_password = "s0mePass!changme"

  rds_cluster_instance_class                = "db.t4g.medium"
  rds_cluster_instance_count                = "1"
  rds_db_cluster_parameter_group_name       = "aurora-mysql80sync"
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  rds_engine                                = "aurora-mysql"
  rds_engine_version                        = "8.0.mysql_aurora.3.10.3"
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_performance_insights_enabled          = true
  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.zone_id
}

module "ows_project_manager_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family
  commit_sha         = "latest"
  container_port     = "8080"
  task_type          = "web_service"
  desired_task_count = 2
  task_cpu           = 1024
  task_memory        = 2048
  maximum_capacity   = 4
  minimum_capacity   = 2
  route53_zone_id    = data.aws_route53_zone.route53_zone.zone_id

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled         = false
  blocking_waf_enabled          = false
  health_check_path             = "/hello"

  iam_managed_policy_attachments = [
    data.aws_iam_policy.dynamodb_owsrequest_policy.arn,
    data.aws_iam_policy.dynamodb_owsrequest_public_policy.arn,
    data.aws_iam_policy.s3_label_copy_export_policy.arn,
    data.aws_iam_policy.sqs_label_copy_export_policy.arn,
    aws_iam_policy.secrets_manager_policy.arn
  ]

  fargate_service_subnets = concat(["subnet-043d235081c966332", "subnet-067a6b45b079d7296"], module.vpc_info.default_private_subnet_ids)

  load_balancer_subnets = concat(["subnet-043d235081c966332", "subnet-067a6b45b079d7296"], module.vpc_info.default_private_subnet_ids)

  https_listener_allow_prefix_list_names = ["shared-orcd-jump-box-private-subnet-prefix-list"]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      AR_MYSQL_DATABASE = "art_relations"
    },
    {
      AR_MYSQL_HOST = "ar-db.theorchard.com"
    },
    {
      AR_MYSQL_USER = "ows-proj-manager"
    },
    {
      LCE_MYSQL_DATABASE = "label_copy_export"
    },
    {
      LCE_MYSQL_HOST = module.ows_project_manager_rds.rds_cluster_endpoint
    },
    {
      LCE_MYSQL_USER = "ows_proj_manager"
    },
    {
      LCE_MYSQL_PORT = "3306"
    },
    {
      OWS_ACCOUNT_URL = "https://ows-account.theorchard.io"
    },
    {
      OWS_MARKETING_URL = "https://ows-marketing.theorchard.io"
    },
    {
      SPLITIO_USE_PREFORKED_INITIALIZATION = var.splitio_preforked
    },
    {
      PDP_DISABLED = "true"
    }
  ]
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"

  environment                             = var.environment
  environment_type                        = "fargate"
  service_name                            = var.service_name
  application_family                      = var.application_family
  critical_number_5xx                     = var.critical_number_5xx
  critical_recovery_number_5xx            = var.critical_recovery_number_5xx
  warning_number_5xx                      = var.warning_number_5xx
  warning_recovery_number_5xx             = var.warning_recovery_number_5xx
  notification_endpoints                  = var.notification_endpoints
  escalation_notification_endpoints       = var.escalation_notification_endpoints
  service_cpu_monitor_evaluation_function = "avg"
  service_cpu_time_window                 = "last_10m"
  additional_tags                         = { service_type : "critical" }
  teams                                   = [var.application_family]
  service_4xx_monitor_enabled             = false
  service_cpu_monitor_enabled             = false
  dependent_applications                  = var.dependent_applications
}

module "ows_project_manager_rds_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/rds?ref=6.13.4"

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name

  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}