module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-royalties-workflows/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "aws_accounts" {
  source = "git@github.com:theorchard/terraform-aws-accounts-map.git//modules/read_accounts_map?ref=3.0.3"
}

data "aws_iam_policy_document" "cross_account_accounting_prod_policy" {
  statement {
    sid = "AccountingProdBucketTrustRelationship"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-prod"]}:role/prod-statementdb-instance-role"
      ]
    }

    actions = [
      "s3:ListBucket",
      "s3:ListBucketVersions",
      "s3:ListBucketMultipartUploads"
    ]

    resources = [
      module.s3_prod_royalties_sales_files_bucket.s3_bucket_arn_output
    ]
  }

  statement {
    sid = "AccountingProdPathTrustRelationship"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["accounting-prod"]}:role/prod-statementdb-instance-role"
      ]
    }

    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion",
      "s3:PutObject",
      "s3:ListMultipartUploadParts",
      "s3:AbortMultipartUpload"
    ]

    resources = [
      "${module.s3_prod_royalties_sales_files_bucket.s3_bucket_arn_output}/*"
    ]
  }
}

module "s3_prod_royalties_sales_files_bucket" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.1"
  env                = var.environment
  bucket_name        = var.bucket_name
  application_family = var.application_family
  kms_key_enabled    = false

  bucket_policy_overrides = [
    data.aws_iam_policy_document.cross_account_accounting_prod_policy.json,
  ]

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

module "s3_prod_abacus_payments_bucket" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.1"
  env                = var.environment
  bucket_name        = "abacus-payments"
  application_family = var.application_family
  kms_key_enabled    = false
  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # CORS Rules
  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = [
        "https://abacus.theorchard.com",
      ]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    }
  ]
}

# Create IAM service user for snowflake stage
resource "aws_iam_user" "iam_user" {
  name = "${var.environment}-${var.service_name}"

  tags = {
    terraformed = true
    role        = "service-user"
  }
}

########################
## abacus-adjustments ##
########################

module "s3_prod_abacus_adjustments_bucket" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.1"
  env                = var.environment
  bucket_name        = "abacus-adjustments"
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # CORS Rules
  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = [
        "https://abacus.theorchard.com",
      ]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    }
  ]
}

resource "aws_iam_policy" "abacus_adjustments_usage_policy" {
  name   = "S3-prod-abacus-adjustments-usage-policy"
  policy = data.aws_iam_policy_document.abacus_adjustments_usage_policy.json
}

data "aws_iam_policy_document" "abacus_adjustments_usage_policy" {
  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket",
      "s3:GetBucketLocation"
    ]
    resources = [module.s3_prod_abacus_adjustments_bucket.s3_bucket_arn_output]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject"
    ]
    resources = ["${module.s3_prod_abacus_adjustments_bucket.s3_bucket_arn_output}/*"]
  }
}

#########
## M2M ##
#########

module "m2m_secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"
  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
}