module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name         = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-sound-recordings/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "s3_sr_versions_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.13.0"

  application_family = var.application_family
  env                = var.environment
  bucket_name        = var.sr_versions_bucket

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

data "aws_iam_policy_document" "s3_sr_versions_ows_policy_document" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion"
    ]

    resources = [
      "${module.s3_sr_versions_bucket.s3_bucket_arn_output}/*",
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
      "s3:ListBucketVersions"
    ]

    resources = [
      module.s3_sr_versions_bucket.s3_bucket_arn_output,
    ]
  }
}

data "aws_iam_policy" "s3_sr_delivery_audit_bucket_read_only_policy" {
  name = "S3-${var.environment}-${var.sr_delivery_audit_bucket}-read-only"
}

resource "aws_iam_policy" "s3_sr_versions_ows_policy" {
  name   = "S3-${var.environment}-${var.sr_versions_bucket}-R-policy"
  policy = data.aws_iam_policy_document.s3_sr_versions_ows_policy_document.json
}

module "ows_sound_recordings_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  application_family = var.application_family
  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  teams              = [var.environment]
}

module "ows_sound_recordings_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.service_name
}

data "aws_iam_policy_document" "secretsmanager_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetSecretValue"
    ]
    resources = [
      "arn:aws:secretsmanager:*:*:secret:prod/python-orchard-features/*",
      "arn:aws:secretsmanager:*:*:secret:prod/python-orchard-features/"
    ]
  }
}

resource "aws_iam_policy" "secretsmanager_policy" {
  name   = "${var.environment}-secretsmanager-ows-sound-recordings-policy"
  policy = data.aws_iam_policy_document.secretsmanager_policy_document.json
}

module "ows_sound_recordings_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.7.0"

  providers = {
    aws.dns = aws.networking
  }

  application_family                            = var.application_family
  environment                                   = var.environment
  service_name                                  = var.service_name
  aws_region                                    = var.aws_region
  desired_task_count                            = 10
  minimum_capacity                              = 10
  maximum_capacity                              = 35
  task_cpu                                      = 8192
  task_memory                                   = 16384
  route53_zone_id                               = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name      = "orch-elb-logs"
  vpc_id                                        = module.vpc_info.vpc_id
  fargate_service_subnets                       = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                         = module.vpc_info.default_private_subnet_ids
  https_listener_certificate_id                 = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  blocking_waf_enabled                          = true
  health_check_grace_period_seconds             = 120
  container_start_period_seconds                = 120
  autoscaling_active_connections_policy_enabled = true
  target_deregistration_delay                   = 120

  iam_managed_policy_attachments = [
    module.ows_sound_recordings_owsrequest.policy_arn_output,
    aws_iam_policy.s3_sr_versions_ows_policy.arn,
    data.aws_iam_policy.s3_sr_delivery_audit_bucket_read_only_policy.arn,
    aws_iam_policy.secretsmanager_policy.arn,
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      S3_VERSION_BUCKET = module.s3_sr_versions_bucket.s3_bucket_name_output
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_HOME = "/var/.snowflake"
    },
    {
      NEO4J_MAX_CONN_POOLSIZE = 25
    },
    {
      ACKS_FILTER_AWAITED_HOURS = 336  # Two weeks
    }
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      SNOWFLAKE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY"
    }
  ]
}

# Configure alarm based on response time
resource "aws_cloudwatch_metric_alarm" "ows_sound_recordings_response_time" {
  alarm_name        = "${var.environment}-${var.service_name}-response-time-alarm"
  alarm_description = "${var.environment}-${var.service_name}-response-time-alarm"

  namespace          = "AWS/ApplicationELB"
  metric_name        = "TargetResponseTime"
  extended_statistic = "p90"

  comparison_operator = "GreaterThanThreshold"
  threshold           = 5
  period              = 60
  evaluation_periods  = 1

  alarm_actions             = [aws_appautoscaling_policy.scale_up_policy.arn]
  insufficient_data_actions = []

  dimensions = {
    LoadBalancer = module.ows_sound_recordings_fargate_environment.fargate_load_balancer_arn_suffix
  }
}

# Scale up policy (scale down handled by ECS CPU policy)
resource "aws_appautoscaling_policy" "scale_up_policy" {
  name               = "${var.environment}-${var.service_name}-scale-up-policy"
  policy_type        = "StepScaling"
  service_namespace  = "ecs"
  resource_id        = "service/${var.environment}-${var.service_name}/${var.environment}-${var.service_name}"
  scalable_dimension = "ecs:service:DesiredCount"

  step_scaling_policy_configuration {
    adjustment_type         = "ChangeInCapacity"
    cooldown                = var.scaling_cooldown_period
    metric_aggregation_type = "Maximum"

    step_adjustment {
      metric_interval_lower_bound = 0
      scaling_adjustment          = var.scale_up_adjustment
    }
  }

  depends_on = [module.ows_sound_recordings_fargate_environment]
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "ows_sound_recordings_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.6"

  application_family = var.application_family
  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name

  notification_endpoints            = "@slack-collections-prod-alarms"
  escalation_notification_endpoints = "@slack-collections-prod-alarms"

  service_4xx_monitor_enabled  = false
  ok_number_5xx                = 0
  warning_number_5xx           = 1
  warning_recovery_number_5xx  = 0
  critical_number_5xx          = 2
  critical_recovery_number_5xx = 1
  dependent_applications       = var.dependent_applications
  service_cpu_time_window      = "last_10m"
}